gentoo resync : 22.01.2021

4 files changed, 332 insertions, 7 deletions

diff --git a/mail-mta/postfix/Manifest b/mail-mta/postfix/Manifest
index 2296aa2e6bf0..5f4d80393cc9 100644
--- a/mail-mta/postfix/Manifest
+++ b/mail-mta/postfix/Manifest
@@ -5,7 +5,9 @@ AUX postfix.service 662 BLAKE2B dcf9ceb71ad483b580d126fcb5ac68889cdeb898df3333d3
 AUX smtp.pass 29 BLAKE2B 589915bd2856fa64e22caa12fca54ef342eb07606de38d3879c13ac395413c84de6c3b733c83cc0625a4433167efcc7d504b2f87fa26c05b2facde9c3d103021 SHA512 a8a940099a77ea0547004daf5392a6efc0cd643f10072803d65e37763012464ad25b1b925ae9e32bffb3c3e8a5d4b2d3bb5619a174d58fdc4ea5d4090db0d365
 AUX smtp.sasl 42 BLAKE2B 67e9108101779b6027fa1e5cc7c9256a606d440e15bb037a0da186e6b4983ab26e88ede2f0604737c78144c03e182f66005062f1d49e10443d1ddb9757461d1f SHA512 a48e2bd173c4443dd2c389f6973a541dbcba4223b52b42b409a68d934a7fc82a98d4027267befcd5db6ec628cce6a9dffdf044e6fbd774b6e748f07f4106db47
 DIST postfix-3.5.8.tar.gz 4614733 BLAKE2B 13166e854f70987f981bb5e7e5dabfaa73b3170ab16fc1ff8f70f6b98a0697ac980bdf74bbfb39fdfd1972f922a31a28882b1575b79fd8f01d81e08e68d756bc SHA512 0abb07d99e343b76e6a26b4a090af9d592f4dfd03c8c737cc72bfb0f4267dafcbb0cb0aa7b6255f8b834c9289d89a5c47b167be3758239309937cb77e0d9464b
-DIST postfix-3.6-20201212.tar.gz 4683741 BLAKE2B 9c6f1e4488c955d5760cd921a546e2f2add363c70fbca7aede45721bfb16f00dc246ad887945054f0e047c49c17a5d4390a826ca4d357c452390e1da88366397 SHA512 2473a5542189a7973a8cdb767552c1cc819607674c0bf29358adef5fd8d7b19010bd4af62e24f061c5deed8feb787962f4827ceb6958bf93437f179332cdeb83
-EBUILD postfix-3.5.8.ebuild 8839 BLAKE2B fbc10db39b42d0c3ea8467955d2bf9eb74991d74ad25276049f589cec8e8b72896fcc9b71893e0f33e0a5af1625dc08cbd3c6362f01275ec04bc39c14207fddb SHA512 c5f7d03a4ca987e097fe9a34b42dba4485a1e44b781f0c49ffebe70b23c5d0c3067f5652e7bcd16b29114ae7713f72088ff50b9526cb213d0272d3a76bf4aded
-EBUILD postfix-3.6_pre20201212.ebuild 8097 BLAKE2B fa8fa8284cfb06bced6c30bda5f7874b00d63552b0541e88b78b909e4a1d29d9183250f5f295d2f6e3ebf8aff099f963a54d67934573a4deb980371b159fbba8 SHA512 cbe0738bc2bf3443f4bf7cb77c261b95a2ee71f0e6908dc0472a2d99e02e5231de09619d09b7261120ac62fb4d34f390b4035cf338f4d85a16e20e677d127e32
+DIST postfix-3.5.9.tar.gz 4620852 BLAKE2B 66a7bd71e7f74c8f25963ed8d41f04f1f95e060fd23c848065a0e947e766efe058e6593ed8ce1f69528f5b2e9868756d0ea0622b3d77486852882622dd3bb872 SHA512 9ff3a33cdd5811e470d5c6cfa896fa76e4d3257b139deec5f420d18e34232f327b7c8496c5d13566c6f9ae1fdf8719feb9981372b2869b0208a2eb3a1daaeadd
+DIST postfix-3.6-20210110.tar.gz 4694759 BLAKE2B fc2b69b98252d6e95c93e64bc4e56205ccc821a81ee52cd7ec28d9db61c90149071f914ede1100f3b29708a1a8361a1f56983f914d59ce9de7ea55d2c767cab8 SHA512 3cd239de4b774eff1546ce69db020f364516027d08f8646c5c8f356a9ade9667695e747c1f31a01d6fdc99e1307ab1e0bb767d96d499b4af2d85326585a72a98
+EBUILD postfix-3.5.8-r1.ebuild 8862 BLAKE2B c9712ef05b3e80c38d10f215c355e19f2b0a319034a04d10234733f50b68b161bec2789a56b553447a6932d1dfffab52a801f0ebc5b55410409f69ce1497a780 SHA512 5dce3db0ebb51b9b5e35ad5a425f2fdbfad6e439383831db7d78b740eccb9bd34ac0f7374c110cf03164e84afe745d93a1e9b3b1f34dc0c264e25cae348654a1
+EBUILD postfix-3.5.9-r1.ebuild 8867 BLAKE2B 5502caafc72e6cc477c2ec32ed39eca48d979ed09c9a797bfe2ac147385a1d636b9cadc1f9b920f17ecb0c8e43d5fca60e355e13af1d68fe20c6c5965af50262 SHA512 4330677f846f701056e408f08534709d48f3fa1a03844ee4e74e64e81064fa6c25d1416a00db3780313ed46ecd9f89dcf20d28a3b140bee932ae5c91e7ab9211
+EBUILD postfix-3.6_pre20210110-r1.ebuild 8120 BLAKE2B a7392cebc74d726b813017be8b18af3540157a39c7da146509433eb2772d812007c126c485d8fdad26fe945aa25ca50fb07baac1ae127e4d08a46b6d45ec6c41 SHA512 12ef0ea451f55996ef3aab07ee6ed5c1462a3fe0a4c313dabfa95503168cb9417e8659618309485276fd108b6928999fd35b59f5520a59391cce96ec944c8fc9
 MISC metadata.xml 939 BLAKE2B 01474efe62df1eda9a3ba5976847064d615b3c32d9c71838354ef375c851c7ab4d1fcc2bc0d2945ce3d259fc6a698938cee6d1354c4e0f02f1e66395e377a0c5 SHA512 8602700c2a21b66ecf2c024c06ce23452f7effd9c06a5d58c1ccb351bcdef43a3c89575cc9136efc72fcd4e06ecb0654017b51bb145e7ffeeda771e3f4e7a673
diff --git a/mail-mta/postfix/postfix-3.5.8.ebuild b/mail-mta/postfix/postfix-3.5.8-r1.ebuild
index df4d2a402701..5cd530ccc455 100644
--- a/mail-mta/postfix/postfix-3.5.8.ebuild
+++ b/mail-mta/postfix/postfix-3.5.8-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -261,7 +261,9 @@ src_install() {
 	# postfix set-permissions expects uncompressed man files
 	docompress -x /usr/share/man
 
-	pamd_mimic_system smtp auth account
+	if use pam; then
+		pamd_mimic_system smtp auth account
+	fi
 
 	if use sasl; then
 		insinto /etc/sasl2
diff --git a/mail-mta/postfix/postfix-3.5.9-r1.ebuild b/mail-mta/postfix/postfix-3.5.9-r1.ebuild
new file mode 100644
index 000000000000..100b89428484
--- /dev/null
+++ b/mail-mta/postfix/postfix-3.5.9-r1.ebuild
@@ -0,0 +1,319 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic pam systemd toolchain-funcs
+
+MY_PV="${PV/_rc/-RC}"
+MY_SRC="${PN}-${MY_PV}"
+MY_URI="ftp://ftp.porcupine.org/mirrors/postfix-release/official"
+RC_VER="2.7"
+
+DESCRIPTION="A fast and secure drop-in replacement for sendmail"
+HOMEPAGE="http://www.postfix.org/"
+SRC_URI="${MY_URI}/${MY_SRC}.tar.gz"
+
+LICENSE="|| ( IBM EPL-2.0 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="+berkdb cdb dovecot-sasl +eai hardened ldap ldap-bind libressl lmdb memcached mbox mysql nis pam postgres sasl selinux sqlite ssl"
+
+DEPEND="
+	acct-group/postfix
+	acct-group/postdrop
+	acct-user/postfix
+	>=dev-libs/libpcre-3.4
+	dev-lang/perl
+	berkdb? ( >=sys-libs/db-3.2:* )
+	cdb? ( || ( >=dev-db/tinycdb-0.76 >=dev-db/cdb-0.75-r4 ) )
+	eai? ( dev-libs/icu:= )
+	ldap? ( net-nds/openldap )
+	ldap-bind? ( net-nds/openldap[sasl] )
+	lmdb? ( >=dev-db/lmdb-0.9.11 )
+	mysql? ( dev-db/mysql-connector-c:0= )
+	nis? ( net-libs/libnsl )
+	pam? ( sys-libs/pam )
+	postgres? ( dev-db/postgresql:* )
+	sasl? (  >=dev-libs/cyrus-sasl-2 )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( >=dev-libs/libressl-2.9.1:0= )
+	)"
+
+RDEPEND="${DEPEND}
+	memcached? ( net-misc/memcached )
+	net-mail/mailbase
+	!mail-mta/courier
+	!mail-mta/esmtp
+	!mail-mta/exim
+	!mail-mta/mini-qmail
+	!mail-mta/msmtp[mta]
+	!mail-mta/netqmail
+	!mail-mta/nullmailer
+	!mail-mta/qmail-ldap
+	!mail-mta/sendmail
+	!mail-mta/opensmtpd
+	!mail-mta/ssmtp[mta]
+	!net-mail/fastforward
+	selinux? ( sec-policy/selinux-postfix )"
+
+REQUIRED_USE="ldap-bind? ( ldap sasl )"
+
+S="${WORKDIR}/${MY_SRC}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-libressl-certkey.patch"
+	"${FILESDIR}/${PN}-libressl-server.patch"
+)
+
+src_prepare() {
+	default
+	sed -i -e "/^#define ALIAS_DB_MAP/s|:/etc/aliases|:/etc/mail/aliases|" \
+		src/util/sys_defs.h || die "sed failed"
+	# change default paths to better comply with portage standard paths
+	sed -i -e "s:/usr/local/:/usr/:g" conf/master.cf || die "sed failed"
+}
+
+src_configure() {
+	for name in CDB LDAP LMDB MYSQL PCRE PGSQL SDBM SQLITE
+	do
+		local AUXLIBS_${name}=""
+	done
+
+	# Make sure LDFLAGS get passed down to the executables.
+	local mycc="-DHAS_PCRE" mylibs="${LDFLAGS} -ldl"
+	AUXLIBS_PCRE="$(pcre-config --libs)"
+
+	use pam && mylibs="${mylibs} -lpam"
+
+	if use ldap; then
+		mycc="${mycc} -DHAS_LDAP"
+		AUXLIBS_LDAP="-lldap -llber"
+	fi
+
+	if use mysql; then
+		mycc="${mycc} -DHAS_MYSQL $(mysql_config --include)"
+		AUXLIBS_MYSQL="$(mysql_config --libs)"
+	fi
+
+	if use postgres; then
+		mycc="${mycc} -DHAS_PGSQL -I$(pg_config --includedir)"
+		AUXLIBS_PGSQL="-L$(pg_config --libdir) -lpq"
+	fi
+
+	if use sqlite; then
+		mycc="${mycc} -DHAS_SQLITE"
+		AUXLIBS_SQLITE="-lsqlite3 -lpthread"
+	fi
+
+	if use ssl; then
+		mycc="${mycc} -DUSE_TLS"
+		mylibs="${mylibs} -lssl -lcrypto"
+	fi
+
+	if use lmdb; then
+		mycc="${mycc} -DHAS_LMDB"
+		AUXLIBS_LMDB="-llmdb -lpthread"
+	fi
+
+	if ! use eai; then
+		mycc="${mycc} -DNO_EAI"
+	fi
+
+	# broken. and "in other words, not supported" by upstream.
+	# Use inet_protocols setting in main.cf
+	#if ! use ipv6; then
+	#	mycc="${mycc} -DNO_IPV6"
+	#fi
+
+	if use sasl; then
+		if use dovecot-sasl; then
+			# Set dovecot as default.
+			mycc="${mycc} -DDEF_SASL_SERVER=\\\"dovecot\\\""
+		fi
+		if use ldap-bind; then
+			mycc="${mycc} -DUSE_LDAP_SASL"
+		fi
+		mycc="${mycc} -DUSE_SASL_AUTH -DUSE_CYRUS_SASL -I/usr/include/sasl"
+		mylibs="${mylibs} -lsasl2"
+	elif use dovecot-sasl; then
+		mycc="${mycc} -DUSE_SASL_AUTH -DDEF_SERVER_SASL_TYPE=\\\"dovecot\\\""
+	fi
+
+	if ! use nis; then
+		mycc="${mycc} -DNO_NIS"
+	fi
+
+	if ! use berkdb; then
+		mycc="${mycc} -DNO_DB"
+		if use cdb; then
+			# change default hash format from Berkeley DB to cdb
+			mycc="${mycc} -DDEF_DB_TYPE=\\\"cdb\\\""
+		fi
+	fi
+
+	if use cdb; then
+		mycc="${mycc} -DHAS_CDB -I/usr/include/cdb"
+		# Tinycdb is preferred.
+		if has_version dev-db/tinycdb ; then
+			einfo "Building with dev-db/tinycdb"
+			AUXLIBS_CDB="-lcdb"
+		else
+			einfo "Building with dev-db/cdb"
+			CDB_PATH="/usr/$(get_libdir)"
+			for i in cdb.a alloc.a buffer.a unix.a byte.a ; do
+				AUXLIBS_CDB="${AUXLIBS_CDB} ${CDB_PATH}/${i}"
+			done
+		fi
+	fi
+
+	# Robin H. Johnson <robbat2@gentoo.org> 17/Nov/2006
+	# Fix because infra boxes hit 2Gb .db files that fail a 32-bit fstat signed check.
+	mycc="${mycc} -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
+	filter-lfs-flags
+
+	# Workaround for bug #76512
+	if use hardened; then
+		[[ "$(gcc-version)" == "3.4" ]] && replace-flags -O? -Os
+	fi
+
+	# Remove annoying C++ comment style warnings - bug #378099
+	append-flags -Wno-comment
+
+	sed -i -e "/^RANLIB/s/ranlib/$(tc-getRANLIB)/g" "${S}"/makedefs
+	sed -i -e "/^AR/s/ar/$(tc-getAR)/g" "${S}"/makedefs
+
+	emake makefiles shared=yes dynamicmaps=no pie=yes \
+		shlib_directory="/usr/$(get_libdir)/postfix/MAIL_VERSION" \
+		DEBUG="" CC="$(tc-getCC)" OPT="${CFLAGS}" CCARGS="${mycc}" AUXLIBS="${mylibs}" \
+		AUXLIBS_CDB="${AUXLIBS_CDB}" AUXLIBS_LDAP="${AUXLIBS_LDAP}" \
+		AUXLIBS_LMDB="${AUXLIBS_LMDB}" AUXLIBS_MYSQL="${AUXLIBS_MYSQL}" \
+		AUXLIBS_PCRE="${AUXLIBS_PCRE}" AUXLIBS_PGSQL="${AUXLIBS_PGSQL}" \
+		AUXLIBS_SQLITE="${AUXLIBS_SQLITE}"
+}
+
+src_install() {
+	LD_LIBRARY_PATH="${S}/lib" \
+	/bin/sh postfix-install \
+		-non-interactive \
+		install_root="${D}" \
+		config_directory="/etc/postfix" \
+		manpage_directory="/usr/share/man" \
+		command_directory="/usr/sbin" \
+		mailq_path="/usr/bin/mailq" \
+		newaliases_path="/usr/bin/newaliases" \
+		sendmail_path="/usr/sbin/sendmail" \
+		|| die "postfix-install failed"
+
+	# Fix spool removal on upgrade
+	rm -Rf "${D}"/var
+	keepdir /var/spool/postfix
+
+	# Install rmail for UUCP, closes bug #19127
+	dobin auxiliary/rmail/rmail
+
+	# Provide another link for legacy FSH
+	dosym ../sbin/sendmail /usr/$(get_libdir)/sendmail
+
+	# Install qshape, posttls-finger and collate
+	dobin auxiliary/qshape/qshape.pl
+	doman man/man1/qshape.1
+	dobin bin/posttls-finger
+	doman man/man1/posttls-finger.1
+	dobin auxiliary/collate/collate.pl
+	newdoc auxiliary/collate/README README.collate
+
+	# Performance tuning tools and their manuals
+	dosbin bin/smtp-{source,sink} bin/qmqp-{source,sink}
+	doman man/man1/smtp-{source,sink}.1 man/man1/qmqp-{source,sink}.1
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/postfix
+	fowners -R postfix:postfix /var/lib/postfix
+	fperms 0750 /var/lib/postfix
+	fowners root:postdrop /usr/sbin/post{drop,queue}
+	fperms 02755 /usr/sbin/post{drop,queue}
+
+	keepdir /etc/postfix
+	keepdir /etc/postfix/postfix-files.d
+	if use mbox; then
+		mypostconf="mail_spool_directory=/var/spool/mail"
+	else
+		mypostconf="home_mailbox=.maildir/"
+	fi
+	LD_LIBRARY_PATH="${S}/lib" \
+	"${D}"/usr/sbin/postconf -c "${D}"/etc/postfix \
+		-e ${mypostconf} || die "postconf failed"
+
+	insinto /etc/postfix
+	newins "${FILESDIR}"/smtp.pass saslpass
+	fperms 600 /etc/postfix/saslpass
+
+	newinitd "${FILESDIR}"/postfix.rc6.${RC_VER} postfix
+	# do not start mysql/postgres unnecessarily - bug #359913
+	use mysql || sed -i -e "s/mysql //" "${D}/etc/init.d/postfix"
+	use postgres || sed -i -e "s/postgresql //" "${D}/etc/init.d/postfix"
+
+	dodoc *README COMPATIBILITY HISTORY PORTING RELEASE_NOTES*
+	mv "${S}"/examples "${D}"/usr/share/doc/${PF}/
+	# postfix set-permissions expects uncompressed man files
+	docompress -x /usr/share/man
+
+	if use pam; then
+		pamd_mimic_system smtp auth account
+	fi
+
+	if use sasl; then
+		insinto /etc/sasl2
+		newins "${FILESDIR}"/smtp.sasl smtpd.conf
+	fi
+
+	# header files
+	insinto /usr/include/postfix
+	doins include/*.h
+
+	if has_version mail-mta/postfix; then
+		# let the sysadmin decide when to change the compatibility_level
+		sed -i -e /^compatibility_level/"s/^/#/" "${D}"/etc/postfix/main.cf || die
+	fi
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+}
+
+pkg_preinst() {
+	if has_version '<mail-mta/postfix-3.4'; then
+		elog
+		elog "Postfix-3.4 introduces a new master.cf service 'postlog'"
+		elog "with type 'unix-dgram' that is used by the new postlogd(8) daemon."
+		elog "Before backing out to an older Postfix version, edit the master.cf"
+		elog "file and remove the postlog entry."
+		elog
+	fi
+}
+
+pkg_postinst() {
+	if [[ ! -e /etc/mail/aliases.db ]] ; then
+		ewarn
+		ewarn "You must edit /etc/mail/aliases to suit your needs"
+		ewarn "and then run /usr/bin/newaliases. Postfix will not"
+		ewarn "work correctly without it."
+		ewarn
+	fi
+
+	# check and fix file permissions
+	"${EROOT}"/usr/sbin/postfix set-permissions
+
+	# configure tls
+	if use ssl ; then
+		if "${EROOT}"/usr/sbin/postfix tls all-default-client; then
+			elog "To configure client side TLS settings:"
+			elog "${EROOT}"/usr/sbin/postfix tls enable-client
+		fi
+		if "${EROOT}"/usr/sbin/postfix tls all-default-server; then
+			elog "To configure server side TLS settings:"
+			elog "${EROOT}"/usr/sbin/postfix tls enable-server
+		fi
+	fi
+}
diff --git a/mail-mta/postfix/postfix-3.6_pre20201212.ebuild b/mail-mta/postfix/postfix-3.6_pre20210110-r1.ebuild
index 05a166047960..5b244efd5c7c 100644
--- a/mail-mta/postfix/postfix-3.6_pre20201212.ebuild
+++ b/mail-mta/postfix/postfix-3.6_pre20210110-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -246,7 +246,9 @@ src_install() {
 	# postfix set-permissions expects uncompressed man files
 	docompress -x /usr/share/man
 
-	pamd_mimic_system smtp auth account
+	if use pam; then
+		pamd_mimic_system smtp auth account
+	fi
 
 	if use sasl; then
 		insinto /etc/sasl2