gentoo auto-resync : 27:10:2022 - 09:57:18

4 files changed, 224 insertions, 3 deletions

diff --git a/mail-client/claws-mail/Manifest b/mail-client/claws-mail/Manifest
index a30f5f504b39..84189f39be74 100644
--- a/mail-client/claws-mail/Manifest
+++ b/mail-client/claws-mail/Manifest
@@ -10,6 +10,7 @@ EBUILD claws-mail-3.18.0-r3.ebuild 5631 BLAKE2B 82456d518d3316d71923667da8743142
 EBUILD claws-mail-3.19.0-r1.ebuild 5625 BLAKE2B 5b815f6be5b482d15a32c8c51d49c927cf80aec0ad8706b32af80c1bde46434ff7fd794d8677fc8ef29c15cf58f650e503674d46a7e0e0fb956eb445641906fd SHA512 05569a87074f974e86ccbf03118020b2b2449f3cf3014a9082c2bc759f3e7c69f37fa823103e7f244749cd55d45a0682e2a62882e8ddacbc69da4a403d6681ee
 EBUILD claws-mail-3.19.0-r2.ebuild 5674 BLAKE2B 2e7d16867ff97f487479672a09cebd43e6867e922f51834e1111095d7da20fe733f871daa5ea90f4dfb633d14bc1a454a75cee11346e8ef0a610bed37b1748df SHA512 ef74c181adb25adb3c5bc1b672c6435a9293005db1513e5ab1de47b9d1e2164dcb3752cbadb05e4ad7873a04870704819db12d83dd289d559a684625f2473d7e
 EBUILD claws-mail-4.1.0-r1.ebuild 5799 BLAKE2B d857c2300e97d11ce0fbfd9d157b61b64aa21c6cb8a3ddd97b14b6410726e4f610880585f5d739d492e187d1fde1e6278b4b17fea28a4cbb7586c2b252cdc3be SHA512 d04644ace0d55e50ff76b6fd19d8332cad1325f51abf1855e1f9b1506b6c3642644ab26ff26681e57b23308f7ba548a8b48dd4398f3a8c251995bf72c8a075f9
+EBUILD claws-mail-4.1.1-r1.ebuild 5663 BLAKE2B f0eefb0825f416ba50b6546bc64602f8e012bed7cd8f6277180e9632af8957c7dc054155afea782bf289e3d3441797b3107240e1973d3d43185288cf24ef8d75 SHA512 0d98ba45ce9552fe009f89d969bb0a9cd42db1ca6d74061e1ad8b0565f76af12692ad1a3a383ea0f680cbe33b718a618b1231ca77a77bdffa54b5bbfb16575a9
 EBUILD claws-mail-4.1.1.ebuild 5608 BLAKE2B c5d17ef4163d50b3a71486fd2dcfb2484c844af9dc70901ae1b78056813a2acb8771801c23b119ea0c59c7798caed08b14b347f8c77f77642f6345d9cf9105fb SHA512 9c16eac8505d755f74bbb05936e03f6d74aa145e5550052fb3ba3faf08f54b6852c226a7eba4c504ec8a4213a2b05e099e7c20b2063e2af34bf0961e85148667
-EBUILD claws-mail-9999.ebuild 5608 BLAKE2B c5d17ef4163d50b3a71486fd2dcfb2484c844af9dc70901ae1b78056813a2acb8771801c23b119ea0c59c7798caed08b14b347f8c77f77642f6345d9cf9105fb SHA512 9c16eac8505d755f74bbb05936e03f6d74aa145e5550052fb3ba3faf08f54b6852c226a7eba4c504ec8a4213a2b05e099e7c20b2063e2af34bf0961e85148667
-MISC metadata.xml 1380 BLAKE2B 134e42b62ca1d00f602b20ee1443c6f491adc1dc1ce1bff1b508b16160fcf492be561eb3c0d4be13073b32c0a2cb42efcaaa8783e5686a36668f11db909b0452 SHA512 1333b9a5401dd6389feb7d31f51e04576bca1773e69fcd5597d8ed6b439886cd7a0785371f6706aa012d03b4772857519074c1b13e824d2a555d8147e9acfaac
+EBUILD claws-mail-9999.ebuild 5663 BLAKE2B f0eefb0825f416ba50b6546bc64602f8e012bed7cd8f6277180e9632af8957c7dc054155afea782bf289e3d3441797b3107240e1973d3d43185288cf24ef8d75 SHA512 0d98ba45ce9552fe009f89d969bb0a9cd42db1ca6d74061e1ad8b0565f76af12692ad1a3a383ea0f680cbe33b718a618b1231ca77a77bdffa54b5bbfb16575a9
+MISC metadata.xml 1445 BLAKE2B 2c20d83b5af1f03c791c733c9cdaa970ea070fe9ee63cfe4d8f4b2c5284bb791579fa0629f1b70c336440b8a8dae7c70d460b906fc34e7e314b074b67ae00523 SHA512 a956df8043597fb5be434fec8747c49088fdd82ea8c7d2a32d8b9a3d88d058cf4bf8cb3a8cc77463ebb8484729f155c258f58dd581b96eb0703de1464ead73b9
diff --git a/mail-client/claws-mail/claws-mail-4.1.1-r1.ebuild b/mail-client/claws-mail/claws-mail-4.1.1-r1.ebuild
new file mode 100644
index 000000000000..ebf3c59858ec
--- /dev/null
+++ b/mail-client/claws-mail/claws-mail-4.1.1-r1.ebuild
@@ -0,0 +1,217 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools desktop python-any-r1 xdg
+
+DESCRIPTION="An email client (and news reader) based on GTK+"
+HOMEPAGE="https://www.claws-mail.org/"
+
+if [[ "${PV}" == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.claws-mail.org/readonly/claws.git"
+else
+	SRC_URI="https://www.claws-mail.org/download.php?file=releases/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+SLOT="0"
+QA_PKGCONFIG_VERSION="${PV}.0"
+LICENSE="GPL-3"
+
+IUSE="archive bogofilter calendar clamav dbus debug dillo doc gdata +gnutls +imap ldap +libcanberra +libnotify litehtml networkmanager nls nntp +notification +oauth pdf perl +pgp rss session sieve smime spamassassin spam-report spell startup-notification svg valgrind webkit xface"
+REQUIRED_USE="
+	libcanberra? ( notification )
+	libnotify? ( notification )
+	networkmanager? ( dbus )
+	oauth? ( gnutls )
+	smime? ( pgp )
+"
+
+COMMONDEPEND="
+	dev-libs/nettle:=
+	net-mail/ytnef
+	sys-libs/zlib:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2[jpeg]
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/pango
+	archive? (
+		app-arch/libarchive
+		>=net-misc/curl-7.9.7
+	)
+	bogofilter? ( mail-filter/bogofilter )
+	calendar? (
+		>=dev-libs/libical-2.0.0:=
+		>=net-misc/curl-7.9.7
+	)
+	dbus? (
+		>=dev-libs/dbus-glib-0.60
+		sys-apps/dbus
+	)
+	gdata? ( >=dev-libs/libgdata-0.17.2 )
+	dillo? ( www-client/dillo )
+	gnutls? ( >=net-libs/gnutls-3.0 )
+	imap? ( >=net-libs/libetpan-0.57 )
+	ldap? ( >=net-nds/openldap-2.0.7:= )
+	litehtml? (
+		>=dev-libs/glib-2.36:2
+		>=dev-libs/gumbo-0.10
+		net-misc/curl
+		media-libs/fontconfig
+	)
+	nls? ( >=sys-devel/gettext-0.18 )
+	nntp? ( >=net-libs/libetpan-0.57 )
+	notification? (
+		dev-libs/glib:2
+		libcanberra? (  media-libs/libcanberra[gtk3] )
+		libnotify? ( x11-libs/libnotify )
+	)
+	pdf? ( app-text/poppler[cairo] )
+	pgp? ( >=app-crypt/gpgme-1.0.0:= )
+	session? (
+		x11-libs/libICE
+		x11-libs/libSM
+	)
+	smime? ( >=app-crypt/gpgme-1.0.0:= )
+	spam-report? ( >=net-misc/curl-7.9.7 )
+	spell? ( >=app-text/enchant-2.0.0:2= )
+	startup-notification? ( x11-libs/startup-notification )
+	svg? ( >=gnome-base/librsvg-2.40.5 )
+	valgrind? ( dev-util/valgrind )
+	webkit? ( net-libs/webkit-gtk:4 )
+"
+
+DEPEND="${COMMONDEPEND}
+	xface? ( >=media-libs/compface-1.4 )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+RDEPEND="${COMMONDEPEND}
+	app-misc/mime-types
+	x11-misc/shared-mime-info
+	clamav? ( app-antivirus/clamav )
+	networkmanager? ( net-misc/networkmanager )
+	pdf? ( app-text/ghostscript-gpl )
+	perl? ( dev-lang/perl:= )
+	rss? (
+		dev-libs/libxml2
+		net-misc/curl
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.17.5-enchant-2_default.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Don't use libsoup-gnome (bug #565924)
+	export HAVE_LIBSOUP_GNOME=no
+
+	local myeconfargs=(
+		--disable-bsfilter-plugin
+		--disable-generic-umpc
+		--disable-jpilot #735118
+		--disable-python-plugin
+		--enable-acpi_notifier-plugin
+		--enable-address_keeper-plugin
+		--enable-alternate-addressbook
+		--enable-att_remover-plugin
+		--enable-attachwarner-plugin
+		--enable-fetchinfo-plugin
+		--enable-ipv6
+		--enable-mailmbox-plugin
+		--enable-newmail-plugin
+		--enable-tnef_parse-plugin
+		--with-password-encryption=$(usex gnutls gnutls old)
+		$(use_enable archive archive-plugin)
+		$(use_enable bogofilter bogofilter-plugin)
+		$(use_enable calendar vcalendar-plugin)
+		$(use_enable clamav clamd-plugin)
+		$(use_enable dbus)
+		$(use_enable debug crash-dialog)
+		$(use_enable dillo dillo-plugin)
+		$(use_enable doc manual)
+		$(use_enable gdata gdata-plugin)
+		$(use_enable gnutls)
+		$(use_enable ldap)
+		$(use_enable litehtml litehtml_viewer-plugin)
+		$(use_enable networkmanager)
+		$(use_enable nls)
+		$(use_enable notification notification-plugin)
+		$(use_enable oauth oauth2)
+		$(use_enable pdf pdf_viewer-plugin)
+		$(use_enable perl perl-plugin)
+		$(use_enable pgp pgpcore-plugin)
+		$(use_enable pgp pgpinline-plugin)
+		$(use_enable pgp pgpmime-plugin)
+		$(use_enable rss rssyl-plugin)
+		$(use_enable session libsm)
+		$(use_enable sieve managesieve-plugin)
+		$(use_enable smime smime-plugin)
+		$(use_enable spam-report spam_report-plugin)
+		$(use_enable spamassassin spamassassin-plugin)
+		$(use_enable spell enchant)
+		$(use_enable startup-notification)
+		$(use_enable svg)
+		$(use_enable valgrind valgrind)
+		$(use_enable webkit fancy-plugin)
+		$(use_enable xface compface)
+	)
+
+	# libetpan is needed if user wants nntp or imap functionality
+	if use imap || use nntp ; then
+		myeconfargs+=( --enable-libetpan )
+	else
+		myeconfargs+=( --disable-libetpan )
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	local DOCS=( AUTHORS ChangeLog* INSTALL* NEWS README* TODO* )
+	default
+
+	# Makefile install claws-mail.png in /usr/share/icons/hicolor/48x48/apps
+	# => also install it in /usr/share/pixmaps for other desktop envs
+	# => also install higher resolution icons in /usr/share/icons/hicolor/...
+	insinto /usr/share/pixmaps
+	doins ${PN}.png
+	local size
+	for size in 64 128 ; do
+		newicon -s ${size} ${PN}-${size}x${size}.png ${PN}.png
+	done
+
+	docinto tools
+	dodoc tools/README*
+
+	domenu ${PN}.desktop
+
+	einfo "Installing extra tools"
+	cd "${S}"/tools || die
+	exeinto /usr/$(get_libdir)/${PN}/tools
+	doexe *.pl *.py *.conf *.sh
+	doexe tb2claws-mail update-po uudec uuooffice
+
+	# kill useless files
+	find "${ED}"/usr/$(get_libdir)/${PN}/plugins/ \
+		\( -name "*.a" -o -name "*.la" \) -delete || die
+}
+
+pkg_postinst() {
+	ewarn "When upgrading from version 3.x please re-load any plugin you use"
+	xdg_pkg_postinst
+}
diff --git a/mail-client/claws-mail/claws-mail-9999.ebuild b/mail-client/claws-mail/claws-mail-9999.ebuild
index b4732cb9f330..ebf3c59858ec 100644
--- a/mail-client/claws-mail/claws-mail-9999.ebuild
+++ b/mail-client/claws-mail/claws-mail-9999.ebuild
@@ -22,11 +22,12 @@ SLOT="0"
 QA_PKGCONFIG_VERSION="${PV}.0"
 LICENSE="GPL-3"
 
-IUSE="archive bogofilter calendar clamav dbus debug dillo doc gdata +gnutls +imap ldap +libcanberra +libnotify litehtml networkmanager nls nntp +notification pdf perl +pgp rss session sieve smime spamassassin spam-report spell startup-notification svg valgrind webkit xface"
+IUSE="archive bogofilter calendar clamav dbus debug dillo doc gdata +gnutls +imap ldap +libcanberra +libnotify litehtml networkmanager nls nntp +notification +oauth pdf perl +pgp rss session sieve smime spamassassin spam-report spell startup-notification svg valgrind webkit xface"
 REQUIRED_USE="
 	libcanberra? ( notification )
 	libnotify? ( notification )
 	networkmanager? ( dbus )
+	oauth? ( gnutls )
 	smime? ( pgp )
 "
 
@@ -150,6 +151,7 @@ src_configure() {
 		$(use_enable networkmanager)
 		$(use_enable nls)
 		$(use_enable notification notification-plugin)
+		$(use_enable oauth oauth2)
 		$(use_enable pdf pdf_viewer-plugin)
 		$(use_enable perl perl-plugin)
 		$(use_enable pgp pgpcore-plugin)
diff --git a/mail-client/claws-mail/metadata.xml b/mail-client/claws-mail/metadata.xml
index 5e9efd0b26e6..3568245d4713 100644
--- a/mail-client/claws-mail/metadata.xml
+++ b/mail-client/claws-mail/metadata.xml
@@ -14,6 +14,7 @@
 		<flag name="libnotify">Enable notification on the desktop in connection with USE=notification</flag>
 		<flag name="litehtml">Enable <pkg>dev-libs/gumbo</pkg> html viewer plugin</flag>
 		<flag name="notification">Notification for new mail in different way, see also USE flags libcanberra, libindicate and libnotify</flag>
+		<flag name="oauth">Enable OAuth2 authentication support</flag>
 		<flag name="pgp">Enable PGP support</flag>
 		<flag name="sieve">Build plugin for sieve filter support</flag>
 		<flag name="smime">Build plugin for S/MIME support</flag>