gentoo resync : 19.03.2019

2 files changed, 113 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 5f80f8a97cda..7bcb19573b4c 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1,3 +1,5 @@
 DIST lxqt-panel-0.13.0.tar.xz 273924 BLAKE2B affed55daf1c0a4bf20faeb35278a7d0c7474e514627d24c33469954bcf57ef2c5ee0ac1346918a3edc58f929f07a923e730d0c8ec1d32eeb3d2af41134beced SHA512 f9ea21a24aa8fc0898c756349256a9a84f4e8469743383ce4372f5ab3719170c84ec731d661f7b3355b7501f16fa862ef9d64b7b346e8abd4cbceb547fcb18e3
+DIST lxqt-panel-0.14.1.tar.xz 439252 BLAKE2B 28172f61cba99450965ca2c1660ca51f268a93ffc32769b270e5c5984b8f3534c3e8736f07334bdec1a1eb408ef35a20bf12de5a445faff161a93efbdacbe51c SHA512 e7cb361a13ac480cda50bc0549d5501f0d4f5bb6c8e257febf81550aaa88c0c55b615762aedb1f03fd654f79efe5aa2590b1dd592f6ae8c7e5a8d08086e0a687
 EBUILD lxqt-panel-0.13.0.ebuild 2881 BLAKE2B bb9694192d9a3beb262d16faa94fe3fc21bef539bf15d1b267e5ec24594f633e5baca6b8d02566abd29b18be3a47adbee8a55abf576b79ee18de3c25e6a6a9de SHA512 a3c8a76c97111435069c591a7d122c8201604a55676c5e4e002d919379e659a40eb4927b711b9bd7d9e112d500a7f1830d1f7021eca00713b75181b3e0ab8d08
+EBUILD lxqt-panel-0.14.1.ebuild 2764 BLAKE2B 3611109fbcfee8851f9cbe8b0e1a6fdcaa1f3a4ac84246f5ebbc5efe02ed2cf2e5a1607c9849f87263335821e1bee4ab26f2d62cdc5816aa9a6a66c60749d200 SHA512 738b327f173c3ff234e758be1b8c61c54e9391fcf0b860f6a241a166a89c75e6bb7c1c86dd1b8c30054cd03ba42eda62ea8277d46e6e5969c4b69a3e5e138f3d
 MISC metadata.xml 1505 BLAKE2B bab5a3343f1b765980b9b59a7a7d2b3d4e9968e9f47c2d9965bd1cc59b9770d69e543ecb2adf0c65bed3324becd988e7388218ddc19039a895ede16713014b80 SHA512 3c4775f11a763645878d24f3f5cf4a6c6b8622ee6bb6ccc8cd28582eedc8092030dcff06734db1c3266f13a076a63e1474d1334c206fb4d0bc55829eb3f9f1b4
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild
new file mode 100644
index 000000000000..d63d618db914
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt.org/"
+
+MY_PV="$(ver_cut 1-2)*"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator +mainmenu
+	+mount networkmonitor pulseaudio +quicklaunch sensors +showdesktop
+	+spacer statusnotifier sysstat +taskbar +tray +volume +worldclock"
+REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.6.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/lxmenu-data-0.1.5
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}
+	=lxqt-base/lxqt-globalkeys-${MY_PV}
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	sensors? ( sys-apps/lm_sensors )
+	statusnotifier? ( dev-libs/libdbusmenu-qt[qt5(+)] )
+	sysstat? ( >=lxqt-base/libsysstat-0.4.1 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/xcb-util
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-sound/pavucontrol-qt
+			media-sound/pulseaudio
+		)
+	)
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	doman panel/man/*.1
+}