gentoo auto-resync : 18:04:2023 - 05:54:20

2 files changed, 119 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 4196e8edba2b..6a6f0292f367 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1,3 +1,5 @@
 DIST lxqt-panel-1.2.0.tar.xz 563852 BLAKE2B 78822e0a268448e0ffabec2a8418d7b72d585a8644cf7f1ee3fcd4aa6723bfd5f158ee38a3facf4410575a918e3cd4c331427d74c961ea2a17497fc464140d5c SHA512 7042cf585c153524aaa43b074f3a9f5c2848e2baf200134ca8194f4ffceda438e55d2cff6cc1c37274b35491234800d728cd89cec89cb42dc914a5bba924f3b6
+DIST lxqt-panel-1.3.0.tar.xz 610764 BLAKE2B 96d4f0368a5071badec0c7dfbcb1f5c9592723fa2ca3be81fe47e0cdccd3108451f204c6de95c154d2ca03f7554fe639afd257f72d554682fabc2bd493ab896d SHA512 1bf66db90e4fbd1ec38688b3a27c9dc5ab2e0a71ace74555580c379e9e12211ded61d01fa46484e8a600bb9b30cb3203ec38697ade0a9cb81cb2cd8043af8b97
 EBUILD lxqt-panel-1.2.0.ebuild 2992 BLAKE2B 3c7d54076f9cf0574251b04a44ee3a67c195d83439dec63b8758bc61ba6810269b9579887ed04dff508ca3a046a32ce4bde3e241fb432be17303e47974baaf7f SHA512 a2db476f00df9c3a2191ebff2a5ae6675826f6fc70729dea4c0d66ee28bb31cd14c4205182806b0a19b12d047c46f3cf017a1a00adf5d11447b8654ee75e29d3
+EBUILD lxqt-panel-1.3.0.ebuild 2995 BLAKE2B 17f1c37bf2e33d47f5708498a874de88a1c0488a0359645b6c2c958ede9318d1459560710b3cbc6cec89489c91c0399bd28ec4ff6d4a04e6da41a7798a0bcf13 SHA512 042257cfe1e86caae434849d5a0483863f4c67d6163f005dd67bdc3ada9d015f86bb1ee2edb0ccaa72ba3cd9f49f0421492989478a936b7ce413e42207e5ca62
 MISC metadata.xml 1320 BLAKE2B 3e932f653506f6ad90453214383eaa94eb32da594c76af60270426544a3bac1ef87dd34204a6c786510e3a00f9e143c92e956b46d7613da343f2030f01b8d9aa SHA512 b68531439f0600dbc28389ee25548dbaa8f85109ea45ba4f6e588c1d49b374d5b27745a517ac508d15d0c48c3b003fa97243cb50eb81177bea6ebcd2713d5809
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild
new file mode 100644
index 000000000000..00ca261b2d51
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
++mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
++spacer +statusnotifier sysstat +taskbar tray +volume +worldclock"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+	>=dev-util/lxqt-build-tools-0.13.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.11.0
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtsvg-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtxml-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/lxmenu-data-0.1.5
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-globalkeys-${MY_PV}*
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? (
+		dev-libs/libdbusmenu-qt[qt5(+)]
+		>=dev-qt/qtconcurrent-5.15:5
+	)
+	sysstat? ( >=lxqt-base/libsysstat-0.4.6 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/xcb-util
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-sound/pavucontrol-qt
+			media-sound/pulseaudio
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}