gentoo resync : 30.06.2019

1 files changed, 60 insertions, 0 deletions

diff --git a/kde-plasma/systemsettings/systemsettings-5.16.2.ebuild b/kde-plasma/systemsettings/systemsettings-5.16.2.ebuild
new file mode 100644
index 000000000000..3822242a75c3
--- /dev/null
+++ b/kde-plasma/systemsettings/systemsettings-5.16.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="System settings utility"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="classic gtk"
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kactivities-stats)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_plasma_dep libkworkspace)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	classic? ( $(add_frameworks_dep khtml) )
+"
+RDEPEND="${DEPEND}
+	$(add_frameworks_dep kirigami)
+	gtk? ( $(add_plasma_dep kde-gtk-config) )
+"
+
+src_prepare() {
+	kde5_src_prepare
+
+	# FIXME: hangs in chroot; similar to bug #640432
+	sed -e "s/^ecm_find_qmlmodule.*org\.kde\.kcm/#&/" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package classic KF5KHtml)
+	)
+
+	kde5_src_configure
+}