gentoo auto-resync : 25:04:2023 - 18:13:05

2 files changed, 184 insertions, 0 deletions

diff --git a/kde-plasma/plasma-desktop/Manifest b/kde-plasma/plasma-desktop/Manifest
index 0ba19798b68d..5cd9f1e04101 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -2,8 +2,10 @@ AUX plasma-desktop-5.26.5-missing-kpackage-1.patch 607 BLAKE2B 9259235c168e41395
 AUX plasma-desktop-5.26.5-missing-kpackage-2.patch 1123 BLAKE2B 160c72f267016be9a320bd735b1d84e3cba30a28a09665a2f4e4a73eb9834c9b04feb468b1359867d77ee062a84278a65048f727595ac211b492b8490a00e8b3 SHA512 cb75f2a27d4436f5828929fd05d92ec3847c2741a776eeeb7df26fc406da5751ec542f94db9a6e1d71e063e7c292f09c1233e81693409d33d9f65641c558f6ad
 DIST plasma-desktop-5.26.5.tar.xz 6352588 BLAKE2B 093d559830719ac011d5aea33beb86c6fb39403a44416da97646c1f890373cfcd570ae6015dfacf0d4cd2448b44e03f814376a3897351178c582bc865e110fce SHA512 6d58bc09c7f0e0218d3ffe4609fe206012c34d8c1ad64003a51ee3228e2ca203b0131b878f797babc43476bd0cf3e7cbe295e8a11ff1ae97843a61b2183ae182
 DIST plasma-desktop-5.27.4-patchset-1.tar.xz 3344 BLAKE2B 4e8daaa10a1f88fcfbf72346b275d3cf6656460dc05f3c61dae4cdc5b9c9071728cf9cf82a13f69d4b8cb6ca79844c1ca37842540a1acfe2fa799553bd0b6773 SHA512 a75e15053134968d805642daeadcf6b3aa321736470d1a04f19f7dc76b513423d97929b36363632bc8eab4167eead2ae58df727bbb69587ef90fcfc0aa94669e
+DIST plasma-desktop-5.27.4-patchset-2.tar.xz 9180 BLAKE2B 1ef7f0151d0b62e496aa06c8c63f970bff2133797a901dd11f916484a2b58d948f5433c4c979a1993f7997f7f5efbd4b197d1bd9c520836121d8ccab5dda5dd7 SHA512 40883f770c9c49d883b10708d3b6fbe00aa50eea8a8819e5882eb3661cc59fc67351c9690d1d569592d2e05a984847e6981eb98d6d047edc62fb50cc562e83d0
 DIST plasma-desktop-5.27.4.tar.xz 14335168 BLAKE2B b45aaa6cc04d3d519e7ccad0cae674f60c6f4c81105deb0a575db7f6c1eeaf19e9ce8e441c4144ac670c722a9413b68e9eb2c111338844e0bed0839e69da69ce SHA512 a9e8dc3244631af50429d05c3ec861396e2b5b58738ebee7dfcc9c912f43ca9865ed8343f585fd665df41a05c401996a97161da10e852970dfc2741e01614162
 DIST plasma-desktop-override-include-dirs-2.tar.xz 8324 BLAKE2B 5ddf9340edf6b6fa76e80158a982ac887b0fb464bc40d5bc4dcd3d6b8f5a87c2d6ecdd153e67e168454aa7faff8d84defb90ba16096b64f3af1e7a74570a00c6 SHA512 452923555bd419d3e389e808c4c9ea35e48795d4f0d78c5845aea677e21f594068540538a8968c2d4034aacb11e910a7b69908e10518eba486ebcc0dda39221a
 EBUILD plasma-desktop-5.26.5-r2.ebuild 5670 BLAKE2B bb1797e33205edb737cecbb075d7632ceae2f1794b9d71c23c6c00d5dcd6b98c2a43f44fc97a454521ae11032ab9765f29351bb663c1f2052cf5416821d4d8fe SHA512 ed1c75f01fd9f080141adc186a47fc102f080b8691f7ec1af2ade8bbbb5dea43eb68155fa4c307f1f0bdb53baab2d86dba4e43669d5251c1ff1bb9c30b210565
 EBUILD plasma-desktop-5.27.4-r1.ebuild 5402 BLAKE2B 887f57ed533fbb35f531b8a929125b3cb7dde301a241b8e2600246fe82f9a8c087481c9ee471fab455ea76d9509442e1a24a740aac34ff5d55897ab808f53b37 SHA512 159fbdb13cae84f848ca6d02808e34544d03dd8859b297e06a4c77d60abf352e6e6dce885acc46db9bbaab42f6c9022d6932ad301708fa3bb85aee1d5a398cde
+EBUILD plasma-desktop-5.27.4-r2.ebuild 5454 BLAKE2B 814c06830d2679124df84ce10e9a52aff4755643bb7f9b2ba9ba30fd0bd29147c9b68c3325c09c3a225824733027c6282aaad64aa6a7303f74912adf099bf07e SHA512 77140bc4ee8bb0c54379d321150da9d68af3ecf3ba8afbfa71003b050103d829a9723d034e3cd8c3e43d84f1b7c057c5cabe29d34d182a9c7a5a5dcfcee179ae
 MISC metadata.xml 682 BLAKE2B fbd378484f259e8b85c9c8776c5ce7eb034432f9a4e547453e0b810b22273bc8c494fdcc5f435c1b660c9660fc68b4860fc40987b0c6b8ee82764cc7fd15e771 SHA512 dff0c23d15a172b901fb0d0b9e383b8cfbc47b2123cf06545c3f9064db492987043695305de4af66fedc8d1900fcfb266b120f4883e2384303c9e4f2a208bee5
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.27.4-r2.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.27.4-r2.ebuild
new file mode 100644
index 000000000000..bdb7bf10a2f9
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.27.4-r2.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.102.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.7
+VIRTUALX_REQUIRED="test"
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-2"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz
+	https://dev.gentoo.org/~asturm/distfiles/${P}-patchset-2.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="ibus +kaccounts scim screencast +semantic-desktop"
+
+# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
+COMMON_DEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5[screencast?]
+	>=media-libs/phonon-4.11.0
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	ibus? (
+		app-i18n/ibus
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	kaccounts? (
+		kde-apps/kaccounts-integration:5
+		net-libs/accounts-qt
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/wayland-protocols-1.25
+	dev-libs/boost
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/kdeplasma-addons-5.25.50
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/oxygen-${PVCUT}:5
+	media-fonts/noto-emoji
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	x11-misc/xdg-user-dirs
+	kaccounts? ( net-libs/signon-oauth2 )
+	screencast? ( >=kde-plasma/kpipewire-${PVCUT}:5 )
+"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${WORKDIR}/${XORGHDRS}/${PN}-5.25.80-override-include-dirs.patch" # downstream patch
+	# KDE-bugs 452187, 467709, 468313, 468328, 436362, 468217, 468668, 468410, 462760
+	"${WORKDIR}/${P}-patchset-2"
+)
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use ibus; then
+		sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+			-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if ! use scim; then
+		sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
+		-DEVDEV_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DSYNAPTICS_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		$(cmake_use_find_package ibus GLIB2)
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# test_kio_fonts needs D-Bus, bug #634166
+	# lookandfeel-kcmTest is unreliable for a long time, bug #607918
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "screen reader support" app-accessibility/orca
+	fi
+	ecm_pkg_postinst
+}