summaryrefslogtreecommitdiff
path: root/kde-apps/lokalize/lokalize-21.04.3-r1.ebuild
diff options
context:
space:
mode:
authorV3n3RiX <venerix@redcorelinux.org>2021-07-17 19:04:28 +0100
committerV3n3RiX <venerix@redcorelinux.org>2021-07-17 19:04:28 +0100
commit514d1bbe260df2521fe60f1a3ec87cfcfde1a829 (patch)
tree555c194dbeb0fb2ac4ad3cde7c0f6a80fd330ce2 /kde-apps/lokalize/lokalize-21.04.3-r1.ebuild
parent4df3bf9762850b34cd1ead5c80374d1a0fc3362e (diff)
gentoo resync : 17.07.2021
Diffstat (limited to 'kde-apps/lokalize/lokalize-21.04.3-r1.ebuild')
-rw-r--r--kde-apps/lokalize/lokalize-21.04.3-r1.ebuild73
1 files changed, 73 insertions, 0 deletions
diff --git a/kde-apps/lokalize/lokalize-21.04.3-r1.ebuild b/kde-apps/lokalize/lokalize-21.04.3-r1.ebuild
new file mode 100644
index 000000000000..a93b5b86e594
--- /dev/null
+++ b/kde-apps/lokalize/lokalize-21.04.3-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+PYTHON_COMPAT=( python3_{8,9} )
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit python-single-r1 ecm kde.org optfeature
+
+DESCRIPTION="Localization tool for KDE software and other free and open source software"
+HOMEPAGE="https://apps.kde.org/lokalize/ https://l10n.kde.org/tools/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT+=" test" # tests are broken, bug 739734
+
+DEPEND="${PYTHON_DEPS}
+ >=app-text/hunspell-1.2.8:=
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtsql-${QTMIN}:5[sqlite]
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=dev-qt/qtxml-${QTMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kcrash-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kitemviews-${KFMIN}:5
+ >=kde-frameworks/knotifications-${KFMIN}:5
+ >=kde-frameworks/kparts-${KFMIN}:5
+ >=kde-frameworks/kross-${KFMIN}:5
+ >=kde-frameworks/ktextwidgets-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ >=kde-frameworks/sonnet-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+ $(python_gen_cond_dep '
+ dev-python/translate-toolkit[${PYTHON_MULTI_USEDEP}]
+ ')
+"
+
+PATCHES=( "${FILESDIR}/${P}-unused-dep.patch" )
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ ecm_pkg_setup
+}
+
+src_install() {
+ ecm_src_install
+ rm "${ED}"/usr/share/lokalize/scripts/msgmerge.{py,rc} || die
+ python_fix_shebang "${ED}"/usr/share/${PN}
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ optfeature "autofetch kde.org translations in new project wizard" dev-vcs/subversion
+ optfeature "spell and grammar checking" app-text/languagetool
+ fi
+ ecm_pkg_postinst
+}