gentoo auto-resync : 08:06:2023 - 15:45:39

1 files changed, 67 insertions, 0 deletions

diff --git a/kde-apps/kate/kate-23.04.2.ebuild b/kde-apps/kate/kate-23.04.2.ebuild
new file mode 100644
index 000000000000..43b77161cfb4
--- /dev/null
+++ b/kde-apps/kate/kate-23.04.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm flag-o-matic gear.kde.org
+
+DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
+HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${KDE_ORG_NAME}-23.04.1-cmake.patch.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	~kde-apps/kate-lib-${PV}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	virtual/libintl
+"
+RDEPEND="${DEPEND}
+	~kde-apps/kate-addons-${PV}:5
+"
+
+PATCHES=( "${WORKDIR}/${KDE_ORG_NAME}-23.04.1-cmake.patch" ) # KDE-bug 905709
+
+src_prepare() {
+	ecm_src_prepare
+
+	# these tests are run in kde-apps/kate-lib
+	cmake_run_in apps/lib cmake_comment_add_subdirectory autotests
+
+	# delete colliding kwrite translations
+	rm -f po/*/*.po || die # installed by kde-apps/kate-lib
+	rm -rf po/*/docs/kwrite || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_addons=FALSE
+		-DBUILD_kwrite=FALSE
+	)
+
+	# provided by kde-apps/kate-lib
+	append-libs -lkateprivate
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# provided by kde-apps/kate-lib
+	rm -v "${ED}"/usr/$(get_libdir)/libkateprivate.so.* || die
+}