gentoo resync : 04.05.2021

4 files changed, 217 insertions, 15 deletions

diff --git a/gui-libs/Manifest.gz b/gui-libs/Manifest.gz
index 52a45de9ff13..32fd243786cf 100644
--- a/gui-libs/Manifest.gz
+++ b/gui-libs/Manifest.gz
diff --git a/gui-libs/gtk/Manifest b/gui-libs/gtk/Manifest
index fb7d047bf643..e40f3de8ed42 100644
--- a/gui-libs/gtk/Manifest
+++ b/gui-libs/gtk/Manifest
@@ -1,3 +1,5 @@
 DIST gtk-4.2.0.tar.xz 25772584 BLAKE2B 38c29475050ff6d0aa41299201343d506e051387c44058f8d3e970470e49046bb11eae57d57d8d869577ca2d5f01da507edb3a87f79c98828ec938a0d87e6989 SHA512 12e825245b92f5dc652530c35b9a48a0bb284641d4128d054a19a35cb7814babe78bfbbdfd7fe3f2472d5028d078ae209a6da5d614b023c2b438223e4c5a04a0
-EBUILD gtk-4.2.0.ebuild 4372 BLAKE2B e98a842ee04d9eb29deeb7d60dea66422c5bafbf692831e317cf01a7565d7fddc76bcd7037495cd40d9f89125cd5e7f3233adc88701121bafc17fb2a96a0fc6e SHA512 d8664f429ed84d58b5f7b0fdd852d54272103543263a8936d3d5b784886c68faff80ab60101553bf3558d7dba6b541d9b7d75802b87788b077ef92d6f4f7e0da
+DIST gtk-4.2.1.tar.xz 25809520 BLAKE2B 63183950703375b092ce451be93d16d1149eb2095b5f304578a064422821546ae161235b46617647cd67a7d8898e2c3854d87bf31ede0cd6db2138d7e5c36c30 SHA512 a2721d6b9a72be481460081aedfbd713842cb5abdb24d810ec48e346342d0d91271f4ace321a9697214477ad4829d0b0ca67754ea316e719784f01c43f0fe732
+EBUILD gtk-4.2.0.ebuild 4452 BLAKE2B 26ff8af4001096d0515b3322e3feb36f3f535eadfc0cd5f07384f51c0e92e28752fa5a8ff064fbd6c6cac9b24fd224ef7bf92b1768308ff9c0a46cc9695b6448 SHA512 f8ddee9dda3d44ecf27fb4dfea414ea05fe308b01b62bb71c8e2f0ec0582ba90e2d93fbad7dcce6962b4bf90357b829dd7a8e303b6f50162b4194af42936fc01
+EBUILD gtk-4.2.1.ebuild 4698 BLAKE2B 220b78802e3b709cb1e8f90063ee01dbf5a07ba31e18ad603424b8a9fe245cba586adc21287be0e591763966111bab9800146029d90919bbe83d68a2ba1c3c38 SHA512 53e9fc4b47c4b07869e286bea09ca3d8f7499c5654d3521e1c450f974b93c9936e71d7a6a564317c51357c21a1d29b85cfd9fde344df0a53dbc63fe69596a9df
 MISC metadata.xml 762 BLAKE2B ba9cb841a877cab910c5517bd4ddd5ade8eeeee9730842412ea371c745a90c5b69d06d95d2f77adff6b90daff589173525914139bb6bde699f241c3ddaa5662b SHA512 8678e380c257cb7cdbee752bec79bc53632b453bbb72a6c05c9ecbd791285e964ea3a57197dd247b0cd881757f3e5210551755e043126a3db9913f96a0f142ae
diff --git a/gui-libs/gtk/gtk-4.2.0.ebuild b/gui-libs/gtk/gtk-4.2.0.ebuild
index da0781e043da..2ab650d33e30 100644
--- a/gui-libs/gtk/gtk-4.2.0.ebuild
+++ b/gui-libs/gtk/gtk-4.2.0.ebuild
@@ -5,14 +5,15 @@ EAPI=7
 
 inherit gnome.org gnome2-utils meson virtualx xdg
 
-DESCRIPTION="Gimp ToolKit +"
-HOMEPAGE="https://www.gtk.org/"
+DESCRIPTION="GTK is a multi-platform toolkit for creating graphical user interfaces"
+HOMEPAGE="https://www.gtk.org/ https://gitlab.gnome.org/GNOME/gtk/"
 
 LICENSE="LGPL-2+"
 SLOT="4"
 IUSE="aqua broadway cloudprint colord cups examples ffmpeg gstreamer gtk-doc +introspection sysprof test vulkan wayland +X xinerama"
 REQUIRED_USE="
 	|| ( aqua wayland X )
+	gtk-doc? ( introspection )
 	xinerama? ( X )
 "
 
@@ -21,7 +22,7 @@ KEYWORDS="~amd64"
 COMMON_DEPEND="
 	>=dev-libs/fribidi-0.19.7
 	>=dev-libs/glib-2.66.0:2
-	>=media-libs/graphene-1.9.1
+	>=media-libs/graphene-1.9.1[introspection?]
 	>=media-libs/libepoxy-1.4[X(+)?]
 	>=x11-libs/cairo-1.14[aqua?,glib,svg,X?]
 	>=x11-libs/gdk-pixbuf-2.30:2[introspection?]
@@ -61,19 +62,11 @@ COMMON_DEPEND="
 	)
 "
 DEPEND="${COMMON_DEPEND}
-	>=sys-devel/gettext-0.19.7
 	sysprof? ( >=dev-util/sysprof-capture-3.38:4 )
-	test? (
-		media-fonts/font-misc-misc
-		media-fonts/font-cursor-misc
-	)
 	X? ( x11-base/xorg-proto )
 "
-# gtk+-3.2.2 breaks Alt key handling in <=x11-libs/vte-0.30.1:2.90
-# gtk+-3.3.18 breaks scrolling in <=x11-libs/vte-0.31.0:2.90
 RDEPEND="${COMMON_DEPEND}
 	>=dev-util/gtk-update-icon-cache-3
-	!<x11-libs/vte-0.31.0:2.90
 "
 # librsvg for svg icons (PDEPEND to avoid circular dep), bug #547710
 PDEPEND="
@@ -88,11 +81,18 @@ BDEPEND="
 	dev-libs/libxslt
 	>=dev-util/gdbus-codegen-2.48
 	dev-util/glib-utils
-	>=dev-util/gtk-doc-am-1.20
+	>=sys-devel/gettext-0.19.7
 	virtual/pkgconfig
 	gtk-doc? (
 		app-text/docbook-xml-dtd:4.3
-		>=dev-util/gtk-doc-1.33
+		dev-util/gi-docgen
+	)
+	test? (
+		dev-libs/glib:2
+		wayland? ( dev-libs/weston )
+
+		media-fonts/font-misc-misc
+		media-fonts/font-cursor-misc
 	)
 "
 
@@ -136,7 +136,7 @@ src_configure() {
 }
 
 src_test() {
-	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/gtk" || die
+	"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/gtk" || die
 
 	if use X; then
 		einfo "Running tests under X"
@@ -159,6 +159,11 @@ src_test() {
 	fi
 }
 
+src_install() {
+	meson_src_install
+	mv "${ED}"/usr/share/doc/{gtk4,${P}} || die
+}
+
 pkg_preinst() {
 	gnome2_schemas_savelist
 }
diff --git a/gui-libs/gtk/gtk-4.2.1.ebuild b/gui-libs/gtk/gtk-4.2.1.ebuild
new file mode 100644
index 000000000000..0b4e9dad9c1a
--- /dev/null
+++ b/gui-libs/gtk/gtk-4.2.1.ebuild
@@ -0,0 +1,195 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="GTK is a multi-platform toolkit for creating graphical user interfaces"
+HOMEPAGE="https://www.gtk.org/ https://gitlab.gnome.org/GNOME/gtk/"
+
+LICENSE="LGPL-2+"
+SLOT="4"
+IUSE="aqua broadway cloudprint colord cups examples ffmpeg gstreamer gtk-doc +introspection sysprof test vulkan wayland +X xinerama"
+REQUIRED_USE="
+	|| ( aqua wayland X )
+	gtk-doc? ( introspection )
+	xinerama? ( X )
+"
+
+KEYWORDS="~amd64"
+
+COMMON_DEPEND="
+	>=dev-libs/fribidi-0.19.7
+	>=dev-libs/glib-2.66.0:2
+	>=media-libs/graphene-1.9.1[introspection?]
+	>=media-libs/libepoxy-1.4[X(+)?]
+	>=x11-libs/cairo-1.14[aqua?,glib,svg,X?]
+	>=x11-libs/gdk-pixbuf-2.30:2[introspection?]
+	>=x11-libs/pango-1.47.0[introspection?]
+	>=media-libs/harfbuzz-0.9:=
+	x11-misc/shared-mime-info
+
+	cloudprint? (
+		>=net-libs/rest-0.7
+		>=dev-libs/json-glib-1.0
+	)
+	colord? ( >=x11-misc/colord-0.1.9:0= )
+	cups? ( >=net-print/cups-2.0 )
+	ffmpeg? ( media-video/ffmpeg )
+	gstreamer? ( >=media-libs/gst-plugins-bad-1.12.3 )
+	introspection? ( >=dev-libs/gobject-introspection-1.39:= )
+	vulkan? ( media-libs/vulkan-loader:= )
+	wayland? (
+		>=dev-libs/wayland-1.14.91
+		>=dev-libs/wayland-protocols-1.20
+		media-libs/mesa[wayland]
+		>=x11-libs/libxkbcommon-0.2
+	)
+	X? (
+		>=app-accessibility/at-spi2-atk-2.5.3
+		media-libs/fontconfig
+		media-libs/mesa[X(+)]
+		x11-libs/libX11
+		>=x11-libs/libXi-1.3
+		x11-libs/libXext
+		>=x11-libs/libXrandr-1.5
+		x11-libs/libXcursor
+		x11-libs/libXfixes
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		xinerama? ( x11-libs/libXinerama )
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	sysprof? ( >=dev-util/sysprof-capture-3.38:4 )
+	X? ( x11-base/xorg-proto )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/gtk-update-icon-cache-3
+"
+# librsvg for svg icons (PDEPEND to avoid circular dep), bug #547710
+PDEPEND="
+	gnome-base/librsvg
+	>=x11-themes/adwaita-icon-theme-3.14
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/docbook-xsl-stylesheets
+	dev-lang/sassc
+	dev-libs/gobject-introspection-common
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.48
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	gtk-doc? (
+		app-text/docbook-xml-dtd:4.3
+		dev-util/gi-docgen
+	)
+	test? (
+		dev-libs/glib:2
+		wayland? ( dev-libs/weston )
+
+		media-fonts/font-misc-misc
+		media-fonts/font-cursor-misc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		# GDK backends
+		$(meson_use X x11-backend)
+		$(meson_use wayland wayland-backend)
+		$(meson_use broadway broadway-backend)
+		-Dwin32-backend=false
+		$(meson_use aqua macos-backend)
+
+		# Media backends
+		$(meson_feature ffmpeg media-ffmpeg)
+		$(meson_feature gstreamer media-gstreamer)
+
+		# Print backends
+		$(meson_feature cups print-cups)
+		$(meson_feature cloudprint print-cloudprint)
+
+		# Optional dependencies
+		$(meson_feature vulkan)
+		$(meson_feature xinerama)
+		-Dcloudproviders=disabled  # cloudprovider is not packaged in Gentoo yet
+		$(meson_feature sysprof)
+		-Dtracker=disabled  # tracker3 is not packaged in Gentoo yet
+		$(meson_feature colord)
+
+		# Documentation and introspection
+		$(meson_use gtk-doc gtk_doc)
+		-Dman-pages=true
+		$(meson_feature introspection)
+
+		# Demos and binaries
+		$(meson_use examples build-examples)
+		$(meson_use examples demos)
+		$(meson_use test build-tests)
+		-Dinstall-tests=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/gtk" || die
+
+	if use X; then
+		einfo "Running tests under X"
+		GSETTINGS_SCHEMA_DIR="${S}/gtk" virtx meson_src_test --setup=x11
+	fi
+
+	if use wayland; then
+		einfo "Running tests under Weston"
+
+		export XDG_RUNTIME_DIR="$(mktemp -p $(pwd) -d xdg-runtime-XXXXXX)"
+
+		weston --backend=headless-backend.so --socket=wayland-5 --idle-time=0 &
+		compositor=$!
+		export WAYLAND_DISPLAY=wayland-5
+
+		GSETTINGS_SCHEMA_DIR="${S}/gtk" meson_src_test --setup=wayland
+
+		exit_code=$?
+		kill ${compositor}
+	fi
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc ; then
+		mkdir "${ED}"/usr/share/doc/${PF}/html || die
+
+		local docdirs=( gdk4 gsk4 gtk4 )
+		use wayland && docdirs+=( gdk4-wayland )
+		use X && docdirs+=( gdk4-x11 )
+
+		local d
+		for d in "${docdirs[@]}"; do
+			mv "${ED}"/usr/share/doc/{${d},${PF}/html/} || die
+		done
+	fi
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+
+	if ! has_version "app-text/evince"; then
+		elog "Please install app-text/evince for print preview functionality."
+		elog "Alternatively, check \"gtk-print-preview-command\" documentation and"
+		elog "add it to your settings.ini file."
+	fi
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}