gentoo auto-resync : 15:09:2023 - 22:58:46

3 files changed, 108 insertions, 0 deletions

diff --git a/gnome-extra/Manifest.gz b/gnome-extra/Manifest.gz
index d778cdddb0c7..f0eb9805a510 100644
--- a/gnome-extra/Manifest.gz
+++ b/gnome-extra/Manifest.gz
diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 9e72c8c5b3ae..85446f1a41b4 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,5 +1,7 @@
 DIST gnome-software-44.4.tar.xz 2426404 BLAKE2B 6f60ffd115ad0e11b619118ae5e665fb35c70621adefe4c532481ab3742c8e2c6a5a0790dae29b2fcf0311f89fda93c323e5bc24b185bbbe95e62a687f71930d SHA512 97eaa33b4dd91a6865ee7eeee28e5acf3cf5fbd6a72a60cf5a7c528f79f6f0684014d1169318314b8efce23c1c29e7d24a71193998ced930584a50494137cf8b
+DIST gnome-software-45.0.tar.xz 2474756 BLAKE2B c42d31bdfb1f8f55cd37ce80a10c84928649e7126a17f1c9fa2309687612244d94f50a619b855abdd629ffb24b4bdb64a4baaa9f393561ee7b686d03c6fa00ae SHA512 3a7fab748c6d826e07e4bf86462cfecd9494bfaca2383222f7053be97830ab603cb0dc83d4d5693c2ddac1cc72897783922a05f5aae2ad07d6b7f5ccd5a4eefb
 DIST gnome-software-45.rc.tar.xz 2466120 BLAKE2B e8d741872831f8259ce6b1dc6472250544a6aaa5c412464ddf103839fcf6907e752ae261d9ac78215d069e05bcdd2acfc0673f0db647b00f506f9206d9410843 SHA512 674c89619419cb7622bed3ce1453c31460d51ba6716db3d8bfc79829ca619e24d1f9c954f2fe72d96156e2e6dbaaf151faa29c97425b0cac132ec3e49871fb79
 EBUILD gnome-software-44.4.ebuild 2664 BLAKE2B c8464d8e45ea71097e91ceaaacb722e317bd089c27e0e7ade3318ed7e8ec16c274baa1337cb7ea88fbddfdf2c37ad903a21f2736ed24cf5dbf54c04f8227c1d8 SHA512 9163535b7198d7d2369f31d6dbab926b98b628120715f212d88388a11167a60ceffd92971b7dd9f5dd5594f6a7700cb3c6127456fc786bc4f66d551e06f7cddb
+EBUILD gnome-software-45.0.ebuild 2614 BLAKE2B e64261261d7af4003eb882df60efcfcd117b51475b394c60a928dd61e54097a77c603009a995035948fbfd5742bf6073c7d4e28110431c55f1160fb832988dab SHA512 0800a64edba9cfbd52fc652d4634a7a38cf8de28eb416a90004b47277e4299777da322b4be5c6db3d9737141ee42c9a94d90d74669e17c66e5735c6192bf322c
 EBUILD gnome-software-45_rc.ebuild 2665 BLAKE2B d1bc0454f325ff45581a7d98ccfb7e9a69690cd8d609c6b5d1f6a22bdfb8df422411838f29114ec70d289aa8934f70a78c9bc2db67cfc575dee3db794d1ea94a SHA512 5dff15b22e9fb7a1a00781bef546be3f100709b03338021ba1d809fac599ea40a0d5d1bc38f1418cdde5238db982e3643479c05eddb2f4ff3901e0b3ef661686
 MISC metadata.xml 688 BLAKE2B e157620837f5fd999b67d2a20f09cc64066317a47391ad97ae645b268964cff5a57e2e088e3040bfc98900f75ddcbffed10f1c159516c38f03d11aa1d2d00386 SHA512 9735764b439bdcb3db3b329d986530677ba87e00f10f217178d8014ea4335c3b74ec0e0051117086da92e9eac59849460a62c324ca249f621b13a3a7d50771a4
diff --git a/gnome-extra/gnome-software/gnome-software-45.0.ebuild b/gnome-extra/gnome-software/gnome-software-45.0.ebuild
new file mode 100644
index 000000000000..748c3b8bedd4
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-45.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://apps.gnome.org/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.10.0:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.3_rc:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.5.6 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.0-r1
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		# TODO: Will this be beneficial to us with flatpak at least? If
+		# enabled, it shows some apps under installed (probably merely due to
+		# /usr/share/app-info presence), but launching and removal of them is
+		# broken
+		-Ddefault_featured_apps=false
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}