gentoo resync : 31.12.2018

3 files changed, 174 insertions, 3 deletions

diff --git a/gnome-extra/libgda/Manifest b/gnome-extra/libgda/Manifest
index 8b1aefa0a000..f266c22ff432 100644
--- a/gnome-extra/libgda/Manifest
+++ b/gnome-extra/libgda/Manifest
@@ -4,5 +4,7 @@ AUX libgda-5.2.4-format-security.patch 1003 BLAKE2B 7b8727e080b0a82645a4f9cdbe71
 AUX libgda-5.2.4-jre18.patch 450 BLAKE2B 1ce265d157bab47f94cc4ffcc620813efd0683a78b516e5b8ecb90f0d3d69b6b6daff7b30c2ec24842d6726804787d06e8b5858a75beb7c4b41d6cf4304d0f0f SHA512 4280b18ac16a1831aac433a2dc64f0713f8668b31d18465877861e0c0e2dd5eb2bc2aa70cdf0d742da4b6c48f2b7ec7bd7f109de99436f84c5d155c2dc4fed94
 AUX libgda-5.2.4-vala-check.patch 920 BLAKE2B 97ec35e7f3bceaa05ffb31dbb1bc8952409bd5b5b695f77fbc99b7a6b4980154bafccaece3a8eec8008f07a973c937918864c60ecc215bf2db2a6a1c5fda8419 SHA512 dba082bdae037d4b9e021085166c4b5e8791c461cfbd9b0668731651b07f931bae8405b8b7d3c7f0cf51ddbfa23b03a265abd8ab3603e90933e0c99a299b53a0
 DIST libgda-5.2.4.tar.xz 12320228 BLAKE2B 567b82934e9fe05abdd7405f17c3e8db1a335698236aed069c66037bb387f34adfc41eae7663d8cedb1ba97d2b54afda15280d745c574e5b28cb1856ff8376b1 SHA512 90449795a64136389c26ee4bbdbd5c1330d441e6c11ff15eff83d0ee39c4ce3abd686222aaa468995496ba1417c0fbc963898107f1806d80648cdc939d3c87cc
-EBUILD libgda-5.2.4-r2.ebuild 4925 BLAKE2B 6d78da6d22688f9c8d3b71425b5828e83d91f36c33e5f9215d3953a4746b4f46f1577396bbac18d1e881ab0184634622bbb9bbc76ab5d65aecced3795be02251 SHA512 c03a97df0b0aeeeba44410c367e5bff172ac3b66c7baf1ca030d96243fcf7ef3a538c16c9cb60a20b136bb81e2a9d907b539fb72778833e83af6d4811fd23487
+DIST libgda-5.2.8.tar.xz 12506208 BLAKE2B 7174aa862f04ec6c73fe98560914ee307afe75b9713adad70fa7dedf97fd4ddb79c98ad1e9a8919218f7453014d8e71e42730e168fae7c6ca0dc58ae99b0558e SHA512 6512d08df072dfc10837b71b2369ab538fa8bf0cdac51ecbb738a138f5b765f030fc7a88b14232eaab2724af8e749898da146bb63969983d3bcfeb11bc22aece
+EBUILD libgda-5.2.4-r2.ebuild 4949 BLAKE2B 554ec6cc79bb402d73d9cc86c59a16f49d235388abd83ab085a77f75dd4f6ca9b99461220e24436059a5e0add9bdca99a9ba37c407229ee6baf43c47780cde30 SHA512 c59cbf63e1f5f8256a2b54bf3b31eebab3ae05fc90e24f7519ec9e3dc76c3380779a23c0c3501a2f2880b7972528f0948d49d53738976043a6b6754a07a6c184
+EBUILD libgda-5.2.8.ebuild 5020 BLAKE2B c5d5f7bff23e606c109e28d1902023d16f50ae10d15204b46024e00de2476e3024128aacaaae38195c3243348cb5de5f426b8da937aaa6b254fc52e918784d9b SHA512 0a8019b11978e5fed29b6e69434e883e330f7a3247ace6bf539636efe180ddd80d53dfae2140488c669cadb1984ef39da9f310f2081ed7acbf4b8aec77e38685
 MISC metadata.xml 759 BLAKE2B ce4b021f5697460110c6d976231579b4299875991f28fad526ce29b83da1db248d0be46eb83e1f2704c3aa997b1a7f4546f901410ee1751dbd2d03718fc2e935 SHA512 aa0bce4d0262948dc57ce220d453a92dd957db925dc381a362055e5a5d09479cf3954e1bc19966cca21ab0e4d9e41f8611242bcf9f3fe1051388c5a8094c851e
diff --git a/gnome-extra/libgda/libgda-5.2.4-r2.ebuild b/gnome-extra/libgda/libgda-5.2.4-r2.ebuild
index 478c37175488..b45f3537357a 100644
--- a/gnome-extra/libgda/libgda-5.2.4-r2.ebuild
+++ b/gnome-extra/libgda/libgda-5.2.4-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -52,7 +52,7 @@ RDEPEND="
 		${PYTHON_DEPS}
 		dev-java/fop
 		dev-python/reportlab )
-	ssl? ( dev-libs/openssl:= )
+	ssl? ( <dev-libs/openssl-1.1:0= )
 	>=dev-db/sqlite-3.6.22:3=
 	vala? ( dev-libs/libgee:0.8 )
 "
@@ -61,6 +61,7 @@ RDEPEND="
 DEPEND="${RDEPEND}
 	>=app-text/gnome-doc-utils-0.9
 	app-text/yelp-tools
+	dev-util/glib-utils
 	dev-util/gtk-doc-am
 	>=dev-util/intltool-0.40.6
 	virtual/pkgconfig
diff --git a/gnome-extra/libgda/libgda-5.2.8.ebuild b/gnome-extra/libgda/libgda-5.2.8.ebuild
new file mode 100644
index 000000000000..0eb06d4b35cc
--- /dev/null
+++ b/gnome-extra/libgda/libgda-5.2.8.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME2_EAUTORECONF="yes"
+PYTHON_COMPAT=( python2_7 )
+VALA_USE_DEPEND="vapigen"
+
+inherit db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python-single-r1 vala
+
+DESCRIPTION="GNOME database access library"
+HOMEPAGE="http://www.gnome-db.org/"
+LICENSE="GPL-2+ LGPL-2+"
+
+IUSE="berkdb canvas debug firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres reports sourceview ssl vala"
+REQUIRED_USE="
+	reports? ( ${PYTHON_REQUIRED_USE} )
+	canvas? ( gtk )
+	graphviz? ( gtk )
+	sourceview? ( gtk )
+	vala? ( introspection )
+"
+# firebird license is not GPL compatible
+
+SLOT="5/4" # subslot = libgda-5.0 soname version
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libxml2-2
+	dev-libs/libxslt
+	sys-libs/readline:0=
+	sys-libs/ncurses:0=
+	berkdb? ( sys-libs/db:* )
+	firebird? ( dev-db/firebird )
+	gnome-keyring? ( app-crypt/libsecret )
+	gtk? (
+		>=x11-libs/gtk+-3.0.0:3
+		canvas? ( x11-libs/goocanvas:2.0= )
+		sourceview? ( x11-libs/gtksourceview:3.0 )
+		graphviz? ( media-gfx/graphviz )
+	)
+	http? ( >=net-libs/libsoup-2.24:2.4 )
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+	json? ( dev-libs/json-glib )
+	ldap? ( net-nds/openldap:= )
+	mdb? ( >app-office/mdbtools-0.5:= )
+	mysql? ( virtual/mysql:= )
+	postgres? ( dev-db/postgresql:= )
+	reports? (
+		${PYTHON_DEPS}
+		dev-java/fop
+		dev-python/reportlab )
+	ssl? ( dev-libs/openssl:0= )
+	>=dev-db/sqlite-3.10.2:3=
+	vala? ( dev-libs/libgee:0.8 )
+"
+
+# java dep shouldn't rely on slots, bug #450004
+# TODO: libgee shouldn't be needed at build with USE=-vala, but needs build system fixes - bug 674066
+DEPEND="${RDEPEND}
+	dev-libs/libgee:0.8
+	>=app-text/gnome-doc-utils-0.9
+	app-text/yelp-tools
+	dev-util/glib-utils
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40.6
+	virtual/pkgconfig
+	java? ( >=virtual/jdk-1.6 )
+	vala? ( $(vala_depend) )
+"
+
+# FIXME: lots of tests failing. Check if they still fail in 5.1.2
+# firebird support bindist-restricted because it is not GPL compatible
+RESTRICT="
+	test
+	firebird? ( bindist )
+"
+
+pkg_setup() {
+	java-pkg-opt-2_pkg_setup
+	use reports && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Fix compilation with -Werror=format-security (from 'master')
+	eapply "${FILESDIR}"/${PN}-5.2.4-format-security.patch
+
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	use reports ||
+		sed -e '/SUBDIRS =/ s/trml2html//' \
+			-e '/SUBDIRS =/ s/trml2pdf//' \
+			-i libgda-report/RML/Makefile.{am,in} || die
+
+	# Prevent file collisions with libgda:4
+	eapply "${FILESDIR}/${PN}-4.99.1-gda-browser-doc-collision.patch"
+	eapply "${FILESDIR}/${PN}-4.99.1-control-center-icon-collision.patch"
+	# Move files with mv (since epatch can't handle rename diffs) and
+	# update pre-generated gtk-doc files (for non-git versions of libgda)
+	local f
+	for f in tools/browser/doc/gda-browser* ; do
+		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
+	done
+	for f in tools/browser/doc/html/gda-browser.devhelp* ; do
+		sed -e 's:name="gda-browser":name="gda-browser-5.0":' \
+			-i ${f} || die "sed ${f} failed"
+		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
+	done
+	for f in control-center/data/*_gda-control-center.png ; do
+		mv ${f} ${f/_gda-control-center.png/_gda-control-center-5.0.png} ||
+			die "mv ${f} failed"
+	done
+
+	gnome2_src_prepare
+	java-pkg-opt-2_src_prepare
+	use vala && vala_src_prepare
+
+	# Support JRE 1.8 (from Fedora) - patches configure, so applied AFTER gnome2_src_prepare runs eautoreconf
+	eapply "${FILESDIR}"/${PN}-5.2.4-jre18.patch
+
+}
+
+src_configure() {
+	# Upstream broken configure handling for UI library introspection and vala bindings if passing a choice with use_enable - https://gitlab.gnome.org/GNOME/libgda/issues/158
+	# But if we don't pass an explicit choice, it behaves as we need (only enable them if --enable-ui AND the appropriate --enable-introspection or --enable-vala)
+	gnome2_src_configure \
+		--with-help \
+		--disable-default-binary \
+		--disable-static \
+		--enable-system-sqlite \
+		$(use_with berkdb bdb /usr) \
+		$(use_with canvas goocanvas) \
+		$(use_enable debug) \
+		$(use_with firebird firebird /usr) \
+		$(use_with gnome-keyring libsecret) \
+		$(use_with graphviz) \
+		$(use_with gtk ui) \
+		$(use_with http libsoup) \
+		$(use_enable introspection) \
+		"$(use_with java java $JAVA_HOME)" \
+		$(use_enable json) \
+		$(use_with ldap) \
+		$(use_with mdb mdb /usr) \
+		$(use_with mysql mysql /usr) \
+		$(use_with oci8 oracle) \
+		$(use_with postgres postgres /usr) \
+		$(use_enable ssl crypto) \
+		$(use_with sourceview gtksourceview) \
+		$(use_enable vala)
+}
+
+pkg_preinst() {
+	gnome2_pkg_preinst
+	java-pkg-opt-2_pkg_preinst
+}
+
+src_install() {
+	gnome2_src_install
+	if use reports; then
+		for t in trml2{html,pdf}; do
+			python_scriptinto /usr/share/libgda-5.0/gda_${t}
+			python_doscript libgda-report/RML/${t}/${t}.py
+		done
+	fi
+}