gentoo (leap year) resync : 29.02.2020

2 files changed, 102 insertions, 0 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index d1821227937a..caad0b7f4859 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,3 +1,5 @@
 DIST gnome-software-3.30.6.tar.xz 5217384 BLAKE2B 6a9478aa7752ea62c391545b5f84191a22c839802bd1ac2118696b9dd954a19003477a688d9f36868a617dbf3dd186fc36a054ce0eac8ba8c7a5eee834732ce4 SHA512 dd98e9e61469fc5566ab569f09bdc06ccb5812a236e305185b911c70364e2983f257e939aed0bb61778163084fb5628d63ff6bd5f056d4a7626a2e771ad6426a
+DIST gnome-software-3.32.4.tar.xz 4852860 BLAKE2B 334eaeccbcd897720e11f0b7b9d4cd9f88c848e536c11e74217074044cfc40ea41fe452b68b6c45787a8369b49268dd704a2efeaf6378e35d3a878ec24f6907e SHA512 81a32477fe755f57465cfbc3d1c88a2f460d6a21222fd73aced06c92b409023a1ace002c338e713135658896c2c14a7ff8508eeefbc5f648e66d8c8777dee881
 EBUILD gnome-software-3.30.6.ebuild 2531 BLAKE2B dbbf3176ecaed83bb3310531ed437afe91793c1ccbd1b788ac9ff05af8fb5342d0c147b0eeca9e94cd3e8637df8aac12324ced104c2c5416680bd8960cb6ca3b SHA512 53a36a9d2dcf7f75d73f56eeb75d6a6fe785984f3dbbc0df87ea965f53ba30c04b1a8839a77ab455649930834507dd04ef31d63f92d0963dfa91f50c8b797855
+EBUILD gnome-software-3.32.4.ebuild 2511 BLAKE2B 287cc883208934666ec0f2205d9152a76483cce475b622ed5f705aa654e230c3c8ae74c792e0d568d0a07397b8c7964da35c4ad54ef93498e34188e27c0555ed SHA512 b473dde75bb656b29e97874e9d6704505d6149e689aaf260b4af295fd931f9060871645c5fda38d396870355b50c15b343d255b0ca4a7eeae5175389cfe1bde8
 MISC metadata.xml 443 BLAKE2B 5f060a298a752150f4b06545c328985c5e55a6e32afb45382b419e33beb27c7ac965d59465dc02e23e4214fd9b995b44894a666b2b4ff55bbca469d3992d12f8 SHA512 aff64504d9b2df32113844e86e05c393314ba247ae0742bbd140b2212771d8a3c76856c79426aca11908a8a8f5e881f6ad8a9a4d298d11fc4f9990bd1fe454f7
diff --git a/gnome-extra/gnome-software/gnome-software-3.32.4.ebuild b/gnome-extra/gnome-software/gnome-software-3.32.4.ebuild
new file mode 100644
index 000000000000..41a258a51acc
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.32.4.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome.org gnome2-utils meson python-any-r1 virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+firmware gnome gtk-doc packagekit spell test udev"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/appstream-glib-0.7.14:0
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7
+	>=dev-libs/glib-2.56:2
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.22.4:3
+	>=dev-libs/json-glib-1.2.0
+	>=net-libs/libsoup-2.52.0:2.4
+	gnome? ( >=gnome-base/gnome-desktop-3.18.0:3= )
+	spell? ( app-text/gspell:= )
+	sys-auth/polkit
+	packagekit? ( >=app-admin/packagekit-base-1.1.0 )
+	firmware? ( >=sys-apps/fwupd-1.0.3 )
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+# test? ( dev-util/valgrind )
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
+	# TODO: Investigate; seems to work outside ebuild .. test/emerge
+	sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_use spell gspell)
+		$(meson_use gnome gnome_desktop) # Investigate purpose, in relation to shell_extensions too (is it ok to be same USE?)
+		-Dman=true
+		$(meson_use packagekit)
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		$(meson_use firmware fwupd)
+		-Dflatpak=false
+		-Drpm_ostree=false
+		$(meson_use gnome shell_extensions) # Maybe gnome-shell USE?
+		-Dodrs=false
+		-Dwebapps=true
+		$(meson_use udev gudev)
+		-Dsnap=false
+		-Dexternal_appstream=false
+		-Dvalgrind=false
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson test -v -C "${BUILD_DIR}"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}