gentoo resync : 14.07.2018

3 files changed, 95 insertions, 0 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
new file mode 100644
index 000000000000..97a0df4093d6
--- /dev/null
+++ b/gnome-extra/gnome-software/Manifest
@@ -0,0 +1,3 @@
+DIST gnome-software-3.22.7.tar.xz 3865764 BLAKE2B c23e3b9e34a9b233a584a920fcd5969b3ebb5fa4227da147870e71c1531da6c3efda913149a903667ae1725c505c1c842aac0a76b439a2730bf6c837f39757fc SHA512 184714710695d8c48451c1ee7885524dfa30cc6091975bdd317bdd6ce130e7815ab7474074ed191913594bcd5142932bd7918ae19a695170a34a5f934e1b9825
+EBUILD gnome-software-3.22.7.ebuild 1905 BLAKE2B 37a604c6a5f8d29c2cfc3f8e8a0ab83d10e97a8232dcbe8bc62068998cc251686f53122e27c04db4d309f51b466431dc8e29723b5c197c9b3da76f3c0238ca58 SHA512 39cd8f54b680ade58142114ba78bc56ee18655a24659c4cdb3f1e3f2c9df155bcad34bf1b6a333a29ac697b50ef067eb17f6296b91dd0483985e6a884e16718e
+MISC metadata.xml 259 BLAKE2B 32f8c5208a55a1dda504b7df969127393a2c70e672aba383fcdc870de8fe778366d3dde3c3313bd043068d2e7831d1e18bad6fb428e82266fc2a630104e0a193 SHA512 fbef629394690b3a5608abc6344816f6acf1e8e2663f29949fd14a662c628f16fee77a1ec1641066806d143fb94c1571bc5b46b829dc53620af6956377fe15cc
diff --git a/gnome-extra/gnome-software/gnome-software-3.22.7.ebuild b/gnome-extra/gnome-software/gnome-software-3.22.7.ebuild
new file mode 100644
index 000000000000..f43cb6123697
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.22.7.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome spell test udev"
+
+RDEPEND="
+	>=app-admin/packagekit-base-1.1.0
+	app-crypt/libsecret
+	dev-db/sqlite:3
+	>=dev-libs/appstream-glib-0.6.7:0
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/json-glib-1.1.1
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+	>=net-libs/libsoup-2.51.92:2.4
+	sys-auth/polkit
+	>=x11-libs/gdk-pixbuf-2.31.5
+	>=x11-libs/gtk+-3.20:3
+	gnome? ( >=gnome-base/gnome-desktop-3.17.92:3= )
+	spell? ( app-text/gtkspell:3 )
+	udev? ( virtual/libgudev )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+# test? ( dev-util/valgrind )
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# valgrind fails with SIGTRAP
+	sed -e 's/TESTS = .*/TESTS =/' \
+		-i "${S}"/src/Makefile.{am,in} || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# FIXME: investigate limba and firmware update support
+	gnome2_src_configure \
+		--enable-man \
+		--enable-packagekit \
+		--enable-polkit \
+		--disable-firmware \
+		--disable-limba \
+		--disable-ostree \
+		--disable-rpm \
+		--disable-steam \
+		--disable-flatpak \
+		--enable-webapps \
+		--disable-snap \
+		$(use_enable spell gtkspell) \
+		$(use_enable test dogtail) \
+		$(use_enable test tests) \
+		$(use_enable gnome gnome-desktop) \
+		$(use_enable gnome shell-extensions) \
+		$(use_enable udev gudev)
+}
+
+src_test() {
+	virtx emake check TESTS_ENVIRONMENT="dbus-run-session"
+}
diff --git a/gnome-extra/gnome-software/metadata.xml b/gnome-extra/gnome-software/metadata.xml
new file mode 100644
index 000000000000..4cbddcaa19ad
--- /dev/null
+++ b/gnome-extra/gnome-software/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnome@gentoo.org</email>
+    <name>Gentoo GNOME Desktop</name>
+  </maintainer>
+</pkgmetadata>