gentoo resync : 24.12.2018

4 files changed, 154 insertions, 1 deletions

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index f33285beaf7f..ec2a9922fb36 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1,5 +1,9 @@
 AUX 3.22.1-fix-vala-0.35-part1.patch 884 BLAKE2B 2994fc2b28bbe8f3b547542b100324fce5d95b385ea8edc1013c86c1e0df1dabafb4306b8153953c67a36e1d96e1c658c599afea5f1c3e3a7d617d01c05d3224 SHA512 73754d230efe89d3e3273e1d24a69e58e45a8d6e74fce1a41f7a7889aa58189fcc2f5edf36ce2418c43871716634301308f0c211f0f18282cb409d009669bdf2
 AUX 3.22.1-fix-vala-0.35-part2.patch 1501 BLAKE2B ca7149152cae32912977bb8a2ca420d1711fcff5e2b18e040d9969e246a0398f66ad09cee72f22b282d6eec834d10721a99d270ba873d782f09bc6e30b7c80d6 SHA512 700772e2c87bfad32e408f20653a20976c0a3b243fd4bc8b6ed61cb9fe34f1b1f572b877aa05e9b9c3854cc444d5d7fc1c26dcd9ac28bf76694eb02c2e31bb4c
 DIST gnome-contacts-3.22.1.tar.xz 788820 BLAKE2B 8f620334dd380e8cb690f7b71d3a99a921f5814ab230690a60be6022150db7a6a0f74e426e72d8d027eb5280e1b6bfd04fa7b0b030519bb19e4718ca0c9f2120 SHA512 d93ed6c65ffdabe1925cc795b88ff374fe69e03fcd36af7c2fc67a5236b90ab6af4bd269b6fc3b344fcd6b4688d866628b8b090bb62de95f8bd0c2e40c26a107
+DIST gnome-contacts-3.26.1.tar.xz 974588 BLAKE2B da989125408702099ecd1afaad6c06ab1cbeda2309bc7b207be671c833792a325bbbba0ebc6561f960d2c524ebd51743a60d5b792a0c2b8126318d38a6d801aa SHA512 1ba445efd71dbc77213d75011b0abcffcf6fe534cba14cf8ca92890e8dfb7b44d9565399200aa7aa03862cf08be60289b78501a1807a760bb1e68f0fe46c4685
+DIST gnome-contacts-3.30.1.tar.xz 369392 BLAKE2B ba3e9263b1de210efec88d2ccecaaf7ae7a6761a5997e213d1a0d9a7694fed54f8123b792e138ec8ac67843408562e320a5490c5daf51478b763b9fbcb21adda SHA512 4aa5629299233d24c36ec1c67d412fc421d5b6836c9759a0278bebe0239897ec6046e3aa8ea7ef10c5e537ec9aed67346221a353f683e18032a708eb333826d7
 EBUILD gnome-contacts-3.22.1-r1.ebuild 1840 BLAKE2B 3678c0ff5796cb2bfed0d35954e0553bdb6b94c79fd9e4d120fac3a307351c948c4cf2d733878002907af6416548ef6c18063fce60a48b022e3f0faa9130e6d2 SHA512 81cfe1119ad2b63bb3041eecae2b4a5b0dc0e1b8e4901f6ad74cb1c52004abcd820dd131f3b2bac0e0d7b067c69c2a53a84187ab7f9019d991f81de79def191d
-MISC metadata.xml 249 BLAKE2B e71e1b95fee768c696704acbf7e3cf0e599ed2bc8de92bae0141d1194ef9e842bdc292798904487a9b90ddfda9b0e84abd3b76b1518576c1d288240e4e46f110 SHA512 c40662134899a5c9f0369a1017806f35adf3280a0b3c91726f7a8ca6012a073a8b471583f5bfb6fe95faac1dcf607e8e2e43f8c91d48ec46f4a8824e2f551506
+EBUILD gnome-contacts-3.26.1.ebuild 1605 BLAKE2B 93f08053b6dfbc85916e9871cb4747e6d05d8933631ee5d06c3ee371eeda2e7cb16ad0350f24b7b39d475e13e0c4f5a57ccddacb156201a61ad3d2e9e7d38c33 SHA512 5d0d89ad60b377cdbda70c8a08f057ca7537a65b449ff7d80e18f6f899cae532a7e5f9e05471daa141413d7d8b397a477ccaa5d3da20dd2acac45d9ca0c4b277
+EBUILD gnome-contacts-3.30.1.ebuild 1719 BLAKE2B 3d412a3232f8b2a696ada524f44b009ea85b92a2869e058de47e370a475c3cea7e40b4f199522da891501b3dde47584b47395e4b46d718bec43a4aac789f1b14 SHA512 b6e689e1bfbdbc9b35bb0e02388be10ff9dcaff3f0614a7649f2146f56ab4e34f54b9bf841a40677a9096322c23892f7dd9a8008232c0ee635e29d0122c0eac2
+MISC metadata.xml 325 BLAKE2B f00835a4dbd2fafbc578f1d36cd3101da6ccbd9236b6a874c862f6e584fe856c7fc1585e0d9da7c3c6a243cc1ea271fc281a127c2f330ba91495873baea0ac6b SHA512 5c6da9fcb4666a80a2fcdaeaa0263feee21140932084683dec7257bbb9e686a08d7d2b476684800216c13f3c851a92416267d5415c25643200250edd8d6041f5
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.26.1.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.26.1.ebuild
new file mode 100644
index 000000000000..0496d35861d3
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-3.26.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.24"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="v4l"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-0.9.6:=
+	dev-libs/folks[vala(+)]
+	gnome-base/gnome-desktop:3=[introspection]
+	gnome-extra/evolution-data-server[vala]
+	net-libs/telepathy-glib[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=dev-libs/folks-0.11.4:=[eds,telepathy]
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgee-0.10:0.8
+	>=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
+	>=gnome-base/gnome-desktop-3.0:3=
+	media-libs/clutter:1.0
+	media-libs/clutter-gtk:1.0
+	media-libs/libchamplain:0.12
+	net-libs/gnome-online-accounts:=
+	>=net-libs/telepathy-glib-0.22.0
+	>=sci-geosciences/geocode-glib-3.15.3
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.20.0:3
+	x11-libs/pango
+	v4l? ( >=media-video/cheese-3.5.91:= )
+"
+DEPEND="${RDEPEND}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Regenerate the pre-generated C sources, bug #471628
+	if ! use v4l; then
+		touch src/*.vala
+	fi
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-man-pages \
+		$(use_with v4l cheese)
+}
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.30.1.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.30.1.ebuild
new file mode 100644
index 000000000000..7144fd7e808d
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-3.30.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.24"
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="telepathy v4l"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-0.9.6:=
+	dev-libs/folks[vala(+)]
+	gnome-base/gnome-desktop:3=[introspection]
+	gnome-extra/evolution-data-server[vala]
+	net-libs/telepathy-glib[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=dev-libs/folks-0.11.4:=[eds,telepathy?]
+	>=dev-libs/libgee-0.10:0.8
+	>=dev-libs/glib-2.44:2
+	>=gnome-base/gnome-desktop-3.0:3=
+	net-libs/gnome-online-accounts:=[vala]
+	>=x11-libs/gtk+-3.22:3
+	>=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
+	v4l? ( >=media-video/cheese-3.5.91:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.22 )
+"
+DEPEND="${RDEPEND}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Regenerate the pre-generated C sources, bug #471628
+	if ! use v4l; then
+		touch src/*.vala
+	fi
+
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use v4l cheese)
+		$(meson_use telepathy)
+		-Dmanpage=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
diff --git a/gnome-extra/gnome-contacts/metadata.xml b/gnome-extra/gnome-contacts/metadata.xml
index 39980802b1da..03d1d32cafd1 100644
--- a/gnome-extra/gnome-contacts/metadata.xml
+++ b/gnome-extra/gnome-contacts/metadata.xml
@@ -5,4 +5,7 @@
 	<email>gnome@gentoo.org</email>
 	<name>Gentoo GNOME Desktop</name>
 </maintainer>
+<use>
+	<flag name="telepathy">Start chat from contact details</flag>
+</use>
 </pkgmetadata>