gentoo resync : 31.12.2018

5 files changed, 177 insertions, 0 deletions

diff --git a/games-strategy/0ad-data/0ad-data-0.0.23b_alpha.ebuild b/games-strategy/0ad-data/0ad-data-0.0.23b_alpha.ebuild
new file mode 100644
index 000000000000..c5edceca6d79
--- /dev/null
+++ b/games-strategy/0ad-data/0ad-data-0.0.23b_alpha.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="0ad-${PV/_/-}"
+DESCRIPTION="Data files for 0ad"
+HOMEPAGE="https://play0ad.com/"
+SRC_URI="http://releases.wildfiregames.com/${MY_P}-unix-data.tar.xz"
+
+LICENSE="GPL-2 CC-BY-SA-3.0 LPPL-1.3c BitstreamVera"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	rm binaries/data/tools/fontbuilder/fonts/*.txt
+}
+
+src_install() {
+	insinto /usr/share/0ad
+	doins -r binaries/data/*
+}
diff --git a/games-strategy/0ad-data/Manifest b/games-strategy/0ad-data/Manifest
index b4e82a39df11..9fc667499365 100644
--- a/games-strategy/0ad-data/Manifest
+++ b/games-strategy/0ad-data/Manifest
@@ -1,3 +1,5 @@
 DIST 0ad-0.0.23-alpha-unix-data.tar.xz 691973492 BLAKE2B 7dcd36d21ea2c12f314f5a185a0fce57cec33754fbd26ad34c376fb9c7725fe5487e79a3da54249981fe58bf03c39350a871198a4cfb98c3a40eb878c6cc39b6 SHA512 9eae8bbdf83f609a0775261d691435c2924b505499fdf36ac0922b5f0c1d605dae49f257a872153c718d8bad018f6635320ec376418761c0d650bf165765e062
+DIST 0ad-0.0.23b-alpha-unix-data.tar.xz 691280800 BLAKE2B 9ee0a1c14adb4fa2a842ad734f67a40af60d063c2f1876a34c49e584017b3fc6894a6be7c6533f15031b118d8a88b40b223decdbc3b8ea95f912271ec56f3a90 SHA512 d0515e44f575737a06f27c75c0a58a5229ead474ae6d48531142015548e5986145f895f95e0fa9209cf9085c7c431f4179ff2e70c1a532f61d1cb62c0a91bcfc
 EBUILD 0ad-data-0.0.23_alpha.ebuild 534 BLAKE2B 3517c0dc476b363aab702a25ef2bc4d19c2fd162b0c6c9ea41995b190215c8ff859d630700db8760cd80514d4197a4d4583cacf991d0b98118b755da1dc55e30 SHA512 d6d9d5de0fa84a76ca80d701de2e0d8340ac8990c83bd6238e66a180a02820112a3c1e20c2c75fa1e03b4fe4671cdde716092841bbe76c71db060b7ceb3452a3
+EBUILD 0ad-data-0.0.23b_alpha.ebuild 531 BLAKE2B 1cff748ab3521a996d51b73d0f69401821e314d19e82491529d367182cbc36f3aed0664c54aa98759ae3585f4ae586072d6b2fa193493320d8587de646a2e10b SHA512 797208fa6d5e2ec00a497170660ea6fa970c125180763125b0d70dc2eafeb89985df24e303faa096baff7e9a975ce3789279dcea29984468b85113dad73e459a
 MISC metadata.xml 330 BLAKE2B 9f9fa8d997d33a71d11d118396fd718f8109e3e44410d5c8c2aeb54cc48b4c979e88922be7e5e9b0009e330b67ce85696fd747c52b2a23b51dc3e8d475c24254 SHA512 55b1c876bea472fc72321364ac95e97c950c675c68e9a32862eb6135b96f7bf7da5c0b787ddd28685b322a33c60dd51dafe1d382eb46e066a5cf8bd15fb5347f
diff --git a/games-strategy/0ad/0ad-0.0.23b_alpha.ebuild b/games-strategy/0ad/0ad-0.0.23b_alpha.ebuild
new file mode 100644
index 000000000000..632db8344465
--- /dev/null
+++ b/games-strategy/0ad/0ad-0.0.23b_alpha.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WX_GTK_VER="3.0"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads,ssl"
+
+inherit eutils wxwidgets toolchain-funcs gnome2-utils python-any-r1
+
+MY_P=0ad-${PV/_/-}
+DESCRIPTION="A free, real-time strategy game"
+HOMEPAGE="https://play0ad.com/"
+SRC_URI="http://releases.wildfiregames.com/${MY_P}-unix-build.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1 MIT CC-BY-SA-3.0 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="editor +lobby nvtt pch test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/icu:=
+	dev-libs/libsodium
+	dev-libs/libxml2
+	dev-libs/nspr
+	~games-strategy/0ad-data-${PV}
+	media-libs/libpng:0
+	media-libs/libsdl2[X,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	net-libs/enet:1.3
+	net-libs/miniupnpc:=
+	net-misc/curl
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXcursor
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
+	lobby? ( >=net-libs/gloox-1.0.20 )
+	nvtt? ( media-gfx/nvidia-texture-tools )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	use editor && setup-wxwidgets
+}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.0.21_alpha-gentoo.patch
+)
+
+src_configure() {
+	local myconf=(
+		--with-system-nvtt
+		--with-system-miniupnpc
+		--minimal-flags
+		$(usex nvtt "" "--without-nvtt")
+		$(usex pch "" "--without-pch")
+		$(usex test "" "--without-tests")
+		$(usex editor "--atlas" "")
+		$(usex lobby "" "--without-lobby")
+		--collada
+		--bindir="/usr/bin"
+		--libdir="/usr/$(get_libdir)"/${PN}
+		--datadir="/usr/share/${PN}"
+		)
+
+	# stock premake4 does not work, use the shipped one
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# regenerate scripts.c so our patch applies
+	cd "${S}"/build/premake/premake4 || die
+	"${S}"/build/premake/premake4/bin/release/premake4 embed || die
+
+	# rebuild premake again... this is the most stupid build system
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix clean
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# run premake to create build scripts
+	cd "${S}"/build/premake || die
+	"${S}"/build/premake/premake4/bin/release/premake4 \
+		--file="premake4.lua" \
+		--outpath="../workspaces/gcc/" \
+		--platform=$(usex amd64 "x64" "x32") \
+		--os=linux \
+		"${myconf[@]}" \
+		gmake || die "Premake failed"
+}
+
+src_compile() {
+	tc-export AR
+
+	# build bundled and patched spidermonkey
+	cd libraries/source/spidermonkey || die
+	JOBS="${MAKEOPTS}" ./build.sh || die
+	cd "${S}" || die
+
+	# build 3rd party fcollada
+	emake -C libraries/source/fcollada/src
+
+	# build 0ad
+	emake -C build/workspaces/gcc verbose=1
+}
+
+src_test() {
+	cd binaries/system || die
+	./test -libdir "${S}/binaries/system" || die "test phase failed"
+}
+
+src_install() {
+	newbin binaries/system/pyrogenesis 0ad
+	use editor && newbin binaries/system/ActorEditor 0ad-ActorEditor
+
+	insinto /usr/share/${PN}
+	doins -r binaries/data/l10n
+
+	exeinto /usr/$(get_libdir)/${PN}
+	doexe binaries/system/libCollada.so
+	doexe libraries/source/spidermonkey/lib/*.so
+	use editor && doexe binaries/system/libAtlasUI.so
+
+	dodoc binaries/system/readme.txt
+	doicon -s 128 build/resources/${PN}.png
+	make_desktop_entry ${PN}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/0ad/Manifest b/games-strategy/0ad/Manifest
index 259a859ff9ef..bd2e6c1f7052 100644
--- a/games-strategy/0ad/Manifest
+++ b/games-strategy/0ad/Manifest
@@ -1,4 +1,6 @@
 AUX 0ad-0.0.21_alpha-gentoo.patch 3905 BLAKE2B 265020af1e1df234d0932c6294e0cda9c0f48bc1b311d6770c8347431c17e5e99c68f4c52cf6e1277ffb2e57431a6c237d2dc4f452e563eb343b06f62ab1eede SHA512 592e9fdff6ef6d88efc9c4a5c856e41240845187cc4a4b3d9d6b5c616eb1f664fdf702b7b0a30cdfeedd6d87ac0fab913df477567b84d42e13d2cf2761cfdec8
 DIST 0ad-0.0.23-alpha-unix-build.tar.xz 31907988 BLAKE2B 567b9e1b5cd653206194e042f4f0859cd4f9afe75d52d3f480a328b76fdcdd746254502fbf284f790b4932c912ff31453bbc8c986c879ad76baa3d2a5db802c9 SHA512 4a1c86b19e0d8ec7d9b8bf75428df0255f95e7f991f419734f9b6ddc288a537405a34c5d7081f1a97475155c49013af85dee5c0265c35c7dbc003b46637a03d7
+DIST 0ad-0.0.23b-alpha-unix-build.tar.xz 31922812 BLAKE2B db7d6bf1a2bb084870b914cf974bfdb19812ff6f9391e5bc5213ae215fc670b77bd4508a5432aa3e47bf327bd37d4bb14961ab3332b165b53327c3f01a935ac1 SHA512 82934313c46c4fd89e3841d5bbf901904abbd2108e9749529d7282bd24ac53b9e6878681c06e6019f4d8ec0e425c28300b0aafc9610a66a331777ffb58ed6135
 EBUILD 0ad-0.0.23_alpha.ebuild 3408 BLAKE2B bb6fbd77a2e9a0b27f086b33bb347ac5c5a8c76277b967359dfd8b4c7b6ea4b3f296aa150bacc3b3dd9a1460e5ebda436ad1429c5c1eaefe826a64403417ac1c SHA512 99db5ad39c1e0fe4ec9762df7c27e5ae12a1234007cd5d6e229110471affa705373015bb6e42e23b1f8ace93c5a3bae4afc204d966c5940f810415cd255186bc
+EBUILD 0ad-0.0.23b_alpha.ebuild 3405 BLAKE2B 604eeb83f57a526ae2b2af60ac81f8f0b7704c4c3596c64a4b171d55297ead1d51a36379e04e2dc65d7f0ccf8b693063960327557d82e30d2c2111bee64d6d82 SHA512 75e3cc52724798374c2c9818ec180ccec2d6bc41699ff7eb1c2e91bda38afa9f2f2550838b2ea5b72a94e2909d2cd12bb66e38ec4799acc0d6e92f8c8526ebc6
 MISC metadata.xml 668 BLAKE2B 9bfa86da2d6e1631217082f88905d8d8be7a2c91248839b9a0f5da9d0c214552b11f4af861eb04072e4645b47505d83d0b93c1313f7a3857b1006f94a699b3b2 SHA512 7aab21c31587f1cce5b4635ace0fbbb5bcdc2a6d811df68494ac1fb251fbfc75911cfa3a9e1a60c28f684f64a919164c6e3504fd3fbba3b0ec05afe8278ae343
diff --git a/games-strategy/Manifest.gz b/games-strategy/Manifest.gz
index a09d5f35a432..473c25fb8740 100644
--- a/games-strategy/Manifest.gz
+++ b/games-strategy/Manifest.gz