reinit the tree, so we can have metadata

5 files changed, 406 insertions, 0 deletions

diff --git a/games-strategy/0ad/0ad-0.0.21_alpha.ebuild b/games-strategy/0ad/0ad-0.0.21_alpha.ebuild
new file mode 100644
index 000000000000..89de55c9db87
--- /dev/null
+++ b/games-strategy/0ad/0ad-0.0.21_alpha.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WX_GTK_VER="3.0"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads,ssl"
+
+inherit eutils wxwidgets toolchain-funcs gnome2-utils python-any-r1
+
+MY_P=0ad-${PV/_/-}
+DESCRIPTION="A free, real-time strategy game"
+HOMEPAGE="https://play0ad.com/"
+SRC_URI="mirror://sourceforge/zero-ad/${MY_P}-unix-build.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1 MIT CC-BY-SA-3.0 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="editor +lobby nvtt pch sound test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/icu:=
+	dev-libs/libxml2
+	dev-libs/nspr
+	~games-strategy/0ad-data-${PV}
+	media-libs/libpng:0
+	media-libs/libsdl2[X,opengl,video]
+	net-libs/enet:1.3
+	net-libs/miniupnpc:=
+	net-misc/curl
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXcursor
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
+	lobby? ( net-libs/gloox )
+	nvtt? ( media-gfx/nvidia-texture-tools )
+	sound? ( media-libs/libvorbis
+		media-libs/openal )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+)
+
+src_configure() {
+	local myconf=(
+		--with-system-nvtt
+		--with-system-miniupnpc
+		--minimal-flags
+		$(usex nvtt "" "--without-nvtt")
+		$(usex pch "" "--without-pch")
+		$(usex test "" "--without-tests")
+		$(usex sound "" "--without-audio")
+		$(usex editor "--atlas" "")
+		$(usex lobby "" "--without-lobby")
+		--collada
+		--bindir="/usr/bin"
+		--libdir="/usr/$(get_libdir)"/${PN}
+		--datadir="/usr/share/${PN}"
+		)
+
+	# stock premake4 does not work, use the shipped one
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# regenerate scripts.c so our patch applies
+	cd "${S}"/build/premake/premake4 || die
+	"${S}"/build/premake/premake4/bin/release/premake4 embed || die
+
+	# rebuild premake again... this is the most stupid build system
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix clean
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# run premake to create build scripts
+	cd "${S}"/build/premake || die
+	"${S}"/build/premake/premake4/bin/release/premake4 \
+		--file="premake4.lua" \
+		--outpath="../workspaces/gcc/" \
+		--platform=$(usex amd64 "x64" "x32") \
+		--os=linux \
+		"${myconf[@]}" \
+		gmake || die "Premake failed"
+}
+
+src_compile() {
+	tc-export AR
+
+	# build bundled and patched spidermonkey
+	cd libraries/source/spidermonkey || die
+	JOBS="${MAKEOPTS}" ./build.sh || die
+	cd "${S}" || die
+
+	# build 3rd party fcollada
+	emake -C libraries/source/fcollada/src
+
+	# build 0ad
+	emake -C build/workspaces/gcc verbose=1
+}
+
+src_test() {
+	cd binaries/system || die
+	./test -libdir "${S}/binaries/system" || die "test phase failed"
+}
+
+src_install() {
+	newbin binaries/system/pyrogenesis 0ad
+	use editor && newbin binaries/system/ActorEditor 0ad-ActorEditor
+
+	insinto /usr/share/${PN}
+	doins -r binaries/data/l10n
+
+	exeinto /usr/$(get_libdir)/${PN}
+	doexe binaries/system/libCollada.so
+	doexe libraries/source/spidermonkey/lib/*.so
+	use editor && doexe binaries/system/libAtlasUI.so
+
+	dodoc binaries/system/readme.txt
+	doicon -s 128 build/resources/${PN}.png
+	make_desktop_entry ${PN}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/0ad/0ad-0.0.22_alpha.ebuild b/games-strategy/0ad/0ad-0.0.22_alpha.ebuild
new file mode 100644
index 000000000000..73de7d6ddbe6
--- /dev/null
+++ b/games-strategy/0ad/0ad-0.0.22_alpha.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WX_GTK_VER="3.0"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads,ssl"
+
+inherit eutils wxwidgets toolchain-funcs gnome2-utils python-any-r1
+
+MY_P=0ad-${PV/_/-}
+DESCRIPTION="A free, real-time strategy game"
+HOMEPAGE="https://play0ad.com/"
+SRC_URI="http://releases.wildfiregames.com/${MY_P}-unix-build.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1 MIT CC-BY-SA-3.0 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="editor +lobby nvtt pch test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/icu:=
+	dev-libs/libxml2
+	dev-libs/nspr
+	~games-strategy/0ad-data-${PV}
+	media-libs/libpng:0
+	media-libs/libsdl2[X,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	net-libs/enet:1.3
+	net-libs/miniupnpc:=
+	net-misc/curl
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXcursor
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
+	lobby? ( >=net-libs/gloox-1.0.20 )
+	nvtt? ( media-gfx/nvidia-texture-tools )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.0.21_alpha-gentoo.patch
+)
+
+src_configure() {
+	local myconf=(
+		--with-system-nvtt
+		--with-system-miniupnpc
+		--minimal-flags
+		$(usex nvtt "" "--without-nvtt")
+		$(usex pch "" "--without-pch")
+		$(usex test "" "--without-tests")
+		$(usex editor "--atlas" "")
+		$(usex lobby "" "--without-lobby")
+		--collada
+		--bindir="/usr/bin"
+		--libdir="/usr/$(get_libdir)"/${PN}
+		--datadir="/usr/share/${PN}"
+		)
+
+	# stock premake4 does not work, use the shipped one
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# regenerate scripts.c so our patch applies
+	cd "${S}"/build/premake/premake4 || die
+	"${S}"/build/premake/premake4/bin/release/premake4 embed || die
+
+	# rebuild premake again... this is the most stupid build system
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix clean
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# run premake to create build scripts
+	cd "${S}"/build/premake || die
+	"${S}"/build/premake/premake4/bin/release/premake4 \
+		--file="premake4.lua" \
+		--outpath="../workspaces/gcc/" \
+		--platform=$(usex amd64 "x64" "x32") \
+		--os=linux \
+		"${myconf[@]}" \
+		gmake || die "Premake failed"
+}
+
+src_compile() {
+	tc-export AR
+
+	# build bundled and patched spidermonkey
+	cd libraries/source/spidermonkey || die
+	JOBS="${MAKEOPTS}" ./build.sh || die
+	cd "${S}" || die
+
+	# build 3rd party fcollada
+	emake -C libraries/source/fcollada/src
+
+	# build 0ad
+	emake -C build/workspaces/gcc verbose=1
+}
+
+src_test() {
+	cd binaries/system || die
+	./test -libdir "${S}/binaries/system" || die "test phase failed"
+}
+
+src_install() {
+	newbin binaries/system/pyrogenesis 0ad
+	use editor && newbin binaries/system/ActorEditor 0ad-ActorEditor
+
+	insinto /usr/share/${PN}
+	doins -r binaries/data/l10n
+
+	exeinto /usr/$(get_libdir)/${PN}
+	doexe binaries/system/libCollada.so
+	doexe libraries/source/spidermonkey/lib/*.so
+	use editor && doexe binaries/system/libAtlasUI.so
+
+	dodoc binaries/system/readme.txt
+	doicon -s 128 build/resources/${PN}.png
+	make_desktop_entry ${PN}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/0ad/Manifest b/games-strategy/0ad/Manifest
new file mode 100644
index 000000000000..e6f1ed7a7bfb
--- /dev/null
+++ b/games-strategy/0ad/Manifest
@@ -0,0 +1,8 @@
+AUX 0ad-0.0.21_alpha-gentoo.patch 3905 SHA256 d325cc6f996d28fd89a323e1d55d8e0aeb130f949adaa9779fc9ee3cd01ced48 SHA512 592e9fdff6ef6d88efc9c4a5c856e41240845187cc4a4b3d9d6b5c616eb1f664fdf702b7b0a30cdfeedd6d87ac0fab913df477567b84d42e13d2cf2761cfdec8 WHIRLPOOL 06c503b96197480a4efc57721f9eb5f726df2a177699ea2f1a5d9fc3f82691952148056cab0d904cacfdcbe0e1ebcbf1017bcc5065b51d02d938707966a786a5
+DIST 0ad-0.0.21-alpha-unix-build.tar.xz 29196476 SHA256 96be23e4284a3931ef9536f988f2517040bde1f8700ee048bff18c932d8683cf SHA512 68f3586375f7dcbf3dfb6476040b8b43da8e2ea1e74947223ff5c9936b54a93caef919d8982d78c6f4ad01ee8f707b38a2c37cdab88ea5c5408544364cff4c37 WHIRLPOOL 8e72c2c3311169eabab5a8a028ffc90b8d6838f72d23ebbac3e5331a7f9434bbe7cae8cf0f5a97bf30b913f7f7f737d264aaf86298f8f65c81a270b0c4e5f871
+DIST 0ad-0.0.22-alpha-unix-build.tar.xz 29199308 SHA256 fddd36df4fd32b5b31fd8871bc5ed3ec71a921de79517fb6199ba7571ec9f5b1 SHA512 3f917e77c6cc1d3fb585c98950db6eab3f5895ba3db41a8737f8172c769b5582689b436cab31eeafecce0e9639ee456afc7b78ebb03435b06512eb9fe7393771 WHIRLPOOL ae33f4f77cb981a0e8f00969c6b1ee05a2f06bacb70f79bfac74fda383bffedd4c6027370d5003e3d7815d5c68e13308b3553d8810bc69eebee143231968e95c
+EBUILD 0ad-0.0.21_alpha.ebuild 3382 SHA256 b7852d29552cc34d914b9f3f5b47fad7ab57ae33b1c06e34f9144832548e2876 SHA512 786d02ee18617435b1b5318dc9d58e6db8de2e32fa38defc4c4eaa0c021af3661cb1dd111ff2bbfd65c7dfbd3a725cb9c38df86ccc56ef3b75cf81614017a531 WHIRLPOOL a4dfaeb9a22e82cf10bcf3bcc16ce8d05d8812041b131375b652b4f0a247c54747f83eb0bc9bef7ad74ddb948b6641ded958e8f51bdc2991a1b1bc89b030cb89
+EBUILD 0ad-0.0.22_alpha.ebuild 3357 SHA256 01a9e8e42736f8976ce34c1d4ac73ea0355553844fdcc56e55bc1dbf3073eeb3 SHA512 14522720cf81831dda716df5f3d079f6816bb0ddd336741149eef4dcc50ca7dded4753ac3260c63013329f4c800c126f20ae4787091f7fb77f2b4b05615d6c48 WHIRLPOOL 10984ef4c915f95448aa4804f4cc9bc13fdcddaf2ff7c0efa21b4ba0e5809abfef1aea8765058e24f807e77a5126433ff0f943196051bcd05531e09150ef7b39
+MISC ChangeLog 5302 SHA256 49fb4a9a88decf86725366d57a9d54084b8afd9aa7dd111c05b050a993e99036 SHA512 d9b944e5e82234d552f3e2c90b0685acde3ef22f971307b0569aff6f162f3a716083485cc9d4b853b059b4415351193b5bd3633b5d8d17481717cf500e808255 WHIRLPOOL 6f417040c74b0b7190b9c3c55eb716d1d1d4045beae42bafd8772810e233b3cb86f83aa3d0a0efe90dc82ed4114af6f33d641c58b5c7c7f875f9d26f6481b7b7
+MISC ChangeLog-2015 1237 SHA256 2b82c4707befa63cd067c788de7d7c4fbd7a25127f7bf5c26154333fcde75608 SHA512 fc8cc3ff7f823948018b740b1af8371bf43ec036158db3cea5ed1fbbb40385e85e65dc0df771e3f601c22d45525d1c4f1c75ce0bea029e179a0db7db2886b83a WHIRLPOOL d62c1334b70579ad31da0ee2c94f9737d66eb73403d0484dfee87b20d27b221a0c1e27c58de5a1497591a24b91b28b512da27fdc3c28da26f8a6c1e1357f3752
+MISC metadata.xml 668 SHA256 5a09a23b6935bfa5a88b9648e32df5be428d0773fbc79745bf73c99808799e74 SHA512 7aab21c31587f1cce5b4635ace0fbbb5bcdc2a6d811df68494ac1fb251fbfc75911cfa3a9e1a60c28f684f64a919164c6e3504fd3fbba3b0ec05afe8278ae343 WHIRLPOOL 05beb7ecd47ae5d1596103dcaf30a4fb581143c6f5628fdf3e3dcf6434aac95f2564d3fd83fd45cbf1c76651a236742ce8dec2299a6cb48e65e87ad2736795c4
diff --git a/games-strategy/0ad/files/0ad-0.0.21_alpha-gentoo.patch b/games-strategy/0ad/files/0ad-0.0.21_alpha-gentoo.patch
new file mode 100644
index 000000000000..79549d193683
--- /dev/null
+++ b/games-strategy/0ad/files/0ad-0.0.21_alpha-gentoo.patch
@@ -0,0 +1,88 @@
+--- 0ad-0.0.21-alpha/build/premake/premake4/build/gmake.unix/Premake4.make
++++ 0ad-0.0.21-alpha/build/premake/premake4/build/gmake.unix/Premake4.make
+@@ -26,9 +26,9 @@
+   DEFINES   += -DNDEBUG -DLUA_USE_POSIX -DLUA_USE_DLOPEN
+   INCLUDES  += -I../../src/host/lua-5.1.4/src
+   CPPFLAGS  += -MMD -MP $(DEFINES) $(INCLUDES)
+-  CFLAGS    += $(CPPFLAGS) -Wall -Os
+-  CXXFLAGS  += $(CPPFLAGS) -Wall -Os
+-  LDFLAGS   += -s -rdynamic
++  CFLAGS    += $(CPPFLAGS) -Wall
++  CXXFLAGS  += $(CPPFLAGS) -Wall
++  LDFLAGS   += -rdynamic
+   LIBS      += -lm -ldl 
+   RESFLAGS  += $(DEFINES) $(INCLUDES) 
+   LDDEPS    += 
+@@ -48,8 +48,8 @@
+   DEFINES   += -D_DEBUG -DLUA_USE_POSIX -DLUA_USE_DLOPEN
+   INCLUDES  += -I../../src/host/lua-5.1.4/src
+   CPPFLAGS  += -MMD -MP $(DEFINES) $(INCLUDES)
+-  CFLAGS    += $(CPPFLAGS) -Wall -g
+-  CXXFLAGS  += $(CPPFLAGS) -Wall -g
++  CFLAGS    += $(CFLAGS) $(CPPFLAGS) -Wall
++  CXXFLAGS  += $(CXXFLAGS) $(CPPFLAGS) -Wall
+   LDFLAGS   += -rdynamic
+   LIBS      += -lm -ldl 
+   RESFLAGS  += $(DEFINES) $(INCLUDES) 
+--- 0ad-0.0.21-alpha/build/premake/premake4/src/tools/gcc.lua
++++ 0ad-0.0.21-alpha/build/premake/premake4/src/tools/gcc.lua
+@@ -136,8 +136,6 @@
+ 		if not cfg.flags.Symbols then
+ 			if cfg.system == "macosx" then
+ 				table.insert(result, "-Wl,-x")
+-			else
+-				table.insert(result, "-s")
+ 			end
+ 		end
+ 	
+--- 0ad-0.0.21-alpha/libraries/source/fcollada/src/Makefile
++++ 0ad-0.0.21-alpha/libraries/source/fcollada/src/Makefile
+@@ -9,9 +9,9 @@
+ 
+ CXX ?= g++
+ CXXFLAGS += -fvisibility=hidden -W -Wall -Wno-unused-parameter -Wno-unused-function $(OS_DEFINE) $(PIC_FLAGS) $(CPPFLAGS)
+-CXXFLAGS_DEBUG := -O0 -g -D_DEBUG -DRETAIL
+-CXXFLAGS_RELEASE := -O2 -DNDEBUG -DRETAIL
+-CXXFLAGS_TEST := -O0 -g -D_DEBUG
++CXXFLAGS_DEBUG := -D_DEBUG -DRETAIL
++CXXFLAGS_RELEASE := -DNDEBUG -DRETAIL
++CXXFLAGS_TEST := -D_DEBUG
+ LIBS += `pkg-config libxml-2.0 --libs`
+ INCLUDES += -IFCollada `pkg-config libxml-2.0 --cflags`
+ INCLUDES_TEST := -IFCollada/FColladaTest $(INCLUDES)
+--- 0ad-0.0.21-alpha/libraries/source/spidermonkey/build.sh
++++ 0ad-0.0.21-alpha/libraries/source/spidermonkey/build.sh
+@@ -93,20 +93,8 @@
+ cd js/src
+ 
+ # Clean up data generated by previous builds that could cause problems
+-rm -rf build-debug
+ rm -rf build-release
+ 
+-# We want separate debug/release versions of the library, so we have to change
+-# the LIBRARY_NAME for each build.
+-# (We use perl instead of sed so that it works with MozillaBuild on Windows,
+-# which has an ancient sed.)
+-perl -i.bak -pe 's/(SHARED_LIBRARY_NAME\s+=).*/$1 '\''mozjs38-ps-debug'\''/' moz.build
+-mkdir -p build-debug
+-cd build-debug
+-CXXFLAGS="${CXXFLAGS} ${TLCXXFLAGS}" ../configure ${CONF_OPTS} --with-nspr-libs="$NSPR_LIBS" --with-nspr-cflags="$NSPR_INCLUDES" --enable-debug --disable-optimize --enable-js-diagnostics --enable-gczeal
+-${MAKE} ${MAKE_OPTS}
+-cd ..
+-
+ perl -i.bak -pe 's/(SHARED_LIBRARY_NAME\s+=).*/$1 '\''mozjs38-ps-release'\''/' moz.build
+ mkdir -p build-release
+ cd build-release
+@@ -161,12 +149,9 @@
+ mkdir -p ${INCLUDE_DIR_DEBUG}
+ mkdir -p ${INCLUDE_DIR_RELEASE}
+ cp -R -L ${FOLDER}/js/src/build-release/dist/include/* ${INCLUDE_DIR_RELEASE}/
+-cp -R -L ${FOLDER}/js/src/build-debug/dist/include/* ${INCLUDE_DIR_DEBUG}/
+ 
+ mkdir -p lib/
+-cp -L ${FOLDER}/js/src/build-debug/dist/lib/${LIB_PREFIX}mozjs38-ps-debug${LIB_SRC_SUFFIX} lib/${LIB_PREFIX}mozjs38-ps-debug${LIB_DST_SUFFIX}
+ cp -L ${FOLDER}/js/src/build-release/dist/lib/${LIB_PREFIX}mozjs38-ps-release${LIB_SRC_SUFFIX} lib/${LIB_PREFIX}mozjs38-ps-release${LIB_DST_SUFFIX}
+-cp -L ${FOLDER}/js/src/build-debug/dist/bin/${LIB_PREFIX}mozjs38-ps-debug${DLL_SRC_SUFFIX} ../../../binaries/system/${LIB_PREFIX}mozjs38-ps-debug${DLL_DST_SUFFIX}
+ cp -L ${FOLDER}/js/src/build-release/dist/bin/${LIB_PREFIX}mozjs38-ps-release${DLL_SRC_SUFFIX} ../../../binaries/system/${LIB_PREFIX}mozjs38-ps-release${DLL_DST_SUFFIX}
+ 
+ # On Windows, also copy debugging symbols files
diff --git a/games-strategy/0ad/metadata.xml b/games-strategy/0ad/metadata.xml
new file mode 100644
index 000000000000..11542ae7c10a
--- /dev/null
+++ b/games-strategy/0ad/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<use>
+		<flag name="editor">Include Atlas scenario editor projects</flag>
+		<flag name="lobby">Enable the use of <pkg>net-libs/gloox</pkg>
+			and the multiplayer lobby</flag>
+		<flag name="nvtt">Support for some uncompressed data formats
+			via <pkg>media-gfx/nvidia-texture-tools</pkg>
+			(might be needed for some mods)</flag>
+	</use>
+	<upstream>
+		<remote-id type="sourceforge">zero-ad</remote-id>
+	</upstream>
+</pkgmetadata>