gentoo resync : 19.03.2019

4 files changed, 104 insertions, 131 deletions

diff --git a/games-roguelike/angband/Manifest b/games-roguelike/angband/Manifest
index efba74be21fa..0002a4f936a4 100644
--- a/games-roguelike/angband/Manifest
+++ b/games-roguelike/angband/Manifest
@@ -1,4 +1,3 @@
-AUX angband-4.0.5-pie-gcc.patch 453 BLAKE2B f303fd00ae875a12159027c1e4f7c48017dcddd300b72095c2d91ad3a532bf40b7a2c3267bfa6906e27452651ccd99e05aa26108e44ddabeb9107cbc9c85de06 SHA512 1173ab1e5eebfba393d34085d6896b9633ec5be4914cfe3925082b6ff8ba8194b6a85970c998dc268d84e71ac524b885a66becbaa2a28ee17acfc11d4957fb3a
-DIST angband-4.0.5.tar.gz 19886562 BLAKE2B 3b8410187a66dacc5f2310e116f3abe8ca04e1363701d455df68f3daaf2a23b0ad4811cee2a50129e1f8e096c6ee9e40f8879b25e97510946b4e4ac2a9124631 SHA512 9ad46430d7e3c4b7676042b28107a2a5b9b2ed967dd1f45b91ca37583fa2d5e9ba25d963a6510ee091b8fdb3a704a60002d851d7898a6298567f804dce36a88b
-EBUILD angband-4.0.5-r1.ebuild 2650 BLAKE2B eea5b92cbf3a3ae69b0a01dacbfcdfd61804acf75ede21be3c16f81d4b884a1421025fb7e7bf8349eb1a4409bfb6beaa7166c3f1aeb469705b3122bc9ddbe15e SHA512 0dcb532baf61ee94461b055b6a3b63f5b17d42f849ea318815d8960b7c0ba6b3b31c2b72d42e7788481357bb9b0c8f0694849d44c0c7641ccb094f6ef5d5701c
+DIST angband-4.1.3.tar.gz 19924395 BLAKE2B 573181ab9b3a01abdc34cfac9e69a757eb7558c67c9490240890bc920c6c2a8ebea6268b733f06a6e421829d807fa135131c1512edfc344610a269139cc5ac47 SHA512 7810e1f04e337c1b5d1ddb6013785c953e0149dfa536c75dd8816fdfd304c37a09103d653cee0c150225c6ba702e121300a65012d8034079cd41f86a730f9c2a
+EBUILD angband-4.1.3.ebuild 2185 BLAKE2B 07f3818c5f94453bbb9841d00b4a190d15312ead0c328c0ac412486244792819c57c5775e81110ae82b873b2aa25e7f88eb2fbe0eb4719393908d562f358253d SHA512 84ec1549557201900ba7af7f5dc6cc2945e7aa5f9433bb7c47048893b6f9ff4685e40d01dc0d173c009b9ab6dd109ea110e702855e2b8e29a2fcddfe7a17fe86
 MISC metadata.xml 322 BLAKE2B 121663252d3cc2808c692febb987b8220f8f8b507598833bc42d31cf72566ac9c9c6cf01f54ea5ccdb18a011ee08ddcc21d6a33a85b7609be8b54b4520783483 SHA512 0f2cb75c7386183901d5790e27da590b8e529807f9c0ea1781d072645bf5605fd66589851189ec4b58ff7d711c00c3c0df2ab88acb96ed01079dbe2f8ac17b24
diff --git a/games-roguelike/angband/angband-4.0.5-r1.ebuild b/games-roguelike/angband/angband-4.0.5-r1.ebuild
deleted file mode 100644
index d8830482e592..000000000000
--- a/games-roguelike/angband/angband-4.0.5-r1.ebuild
+++ /dev/null
@@ -1,115 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit autotools eutils gnome2-utils versionator
-
-MAJOR_PV=$(get_version_component_range 1-2)
-
-DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
-HOMEPAGE="http://rephial.org/"
-SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="ncurses sdl +sound X"
-
-RDEPEND="X? ( x11-libs/libX11 )
-	!ncurses? ( !X? ( !sdl? ( sys-libs/ncurses:0=[unicode] ) ) )
-	ncurses? ( sys-libs/ncurses:0=[unicode] )
-	sdl? ( media-libs/libsdl[video,X]
-		media-libs/sdl-image
-		media-libs/sdl-ttf
-		sound? ( media-libs/libsdl[sound] )
-			media-libs/sdl-mixer[mp3] )"
-DEPEND="${RDEPEND}
-	dev-python/docutils
-	virtual/pkgconfig"
-
-PATCHES=("${FILESDIR}"/${P}-pie-gcc.patch)
-
-src_prepare() {
-	default
-
-	sed -i -e '/libpath/s#datarootdir#datadir#' configure.ac || die
-	sed -i -e "/^.SILENT/d" mk/buildsys.mk.in || die
-	sed -i -e '/^DOC =/s/=.*/=/' doc/Makefile || die
-
-	if use !sound ; then
-		sed -i -e 's/sounds//' lib/Makefile || die
-	fi
-
-	# Game constant files are now system config files in Angband, but
-	# users will be hidden from applying updates by default
-	{
-		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/customize/\""
-		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/gamedata/\""
-	} > "${T}"/99${PN} || die
-
-	eautoreconf
-}
-
-src_configure() {
-	local myconf
-
-	if use sdl; then
-		myconf="$(use_enable sound sdl-mixer)"
-	else
-		myconf="--disable-sdl-mixer"
-	fi
-
-	ac_cv_path_NCURSES_CONFIG="pkg-config ncursesw" \
-	econf \
-		--bindir="${EPREFIX}"/usr/bin \
-		--with-private-dirs \
-		$(use_enable X x11) \
-		$(use_enable sdl) \
-		$(use_enable ncurses curses) \
-		$(use !sdl && use !ncurses && use !X && \
-			echo --enable-curses) \
-		${myconf}
-}
-
-src_install() {
-	DOCS="changes.txt faq.txt readme.txt thanks.txt" \
-		default
-
-	dodoc doc/manual.html
-	doenvd "${T}"/99${PN}
-
-	if use X || use sdl ; then
-		if use X; then
-			make_desktop_entry "angband -mx11" "Angband (X11)" "${PN}"
-		fi
-
-		if use sdl; then
-			make_desktop_entry "angband -msdl" "Angband (SDL)" "${PN}"
-		fi
-
-		local s
-		for s in 16 32 128 256 512
-		do
-			newicon -s ${s} lib/icons/att-${s}.png "${PN}.png"
-		done
-		newicon -s scalable lib/icons/att.svg "${PN}.svg"
-	fi
-}
-
-pkg_preinst() {
-	if use X || use sdl ; then
-		gnome2_icon_savelist
-	fi
-}
-
-pkg_postinst() {
-	echo
-	elog "Angband now uses private savefiles instead of system-wide ones."
-	elog "This version of Angband is not compatible with the save files"
-	elog "of previous versions."
-	echo
-
-	if use X || use sdl ; then
-		gnome2_icon_cache_update
-	fi
-}
diff --git a/games-roguelike/angband/angband-4.1.3.ebuild b/games-roguelike/angband/angband-4.1.3.ebuild
new file mode 100644
index 000000000000..8a55a7470633
--- /dev/null
+++ b/games-roguelike/angband/angband-4.1.3.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg-utils
+
+MAJOR_PV=$(ver_cut 1-2)
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="https://rephial.org/"
+SRC_URI="https://rephial.org/downloads/${MAJOR_PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ncurses sdl sound +X"
+
+REQUIRED_USE="sound? ( sdl )
+	|| ( X ncurses )"
+
+RDEPEND="X? (
+		media-fonts/font-misc-misc
+		x11-libs/libX11
+	)
+	ncurses? ( sys-libs/ncurses:0=[unicode] )
+	sdl? (
+		media-libs/libsdl[video,X]
+		media-libs/sdl-image
+		media-libs/sdl-ttf
+		sound? (
+			media-libs/libsdl[sound]
+			media-libs/sdl-mixer[mp3]
+		)
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-python/docutils
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i -e '/libpath/s#datarootdir#datadir#' configure.ac || die
+	sed -i -e "/^.SILENT/d" mk/buildsys.mk.in || die
+	sed -i -e '/^DOC =/s/=.*/=/' doc/Makefile || die
+
+	if use !sound ; then
+		sed -i -e 's/sounds//' lib/Makefile || die
+	fi
+
+	# Game constant files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	{
+		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/customize/\""
+		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/gamedata/\""
+	} > "${T}"/99${PN} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--bindir="${EPREFIX}"/usr/bin
+		--with-private-dirs
+		$(use_enable X x11)
+		$(use_enable sdl)
+		$(use_enable sound sdl-mixer)
+		$(use_enable ncurses curses)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	dodoc changes.txt faq.txt readme.txt thanks.txt doc/manual.html
+	doenvd "${T}"/99${PN}
+
+	if use X || use sdl ; then
+		use X && make_desktop_entry "angband -mx11" "Angband (X11)" "${PN}"
+		use sdl && make_desktop_entry "angband -msdl" "Angband (SDL)" "${PN}"
+
+		local s
+		for s in 16 32 128 256 512; do
+			newicon -s ${s} lib/icons/att-${s}.png "${PN}.png"
+		done
+		newicon -s scalable lib/icons/att.svg "${PN}.svg"
+	fi
+}
+
+pkg_postinst() {
+	if use X || use sdl ; then
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use X || use sdl ; then
+		xdg_icon_cache_update
+	fi
+}
diff --git a/games-roguelike/angband/files/angband-4.0.5-pie-gcc.patch b/games-roguelike/angband/files/angband-4.0.5-pie-gcc.patch
deleted file mode 100644
index b4f3c5707d43..000000000000
--- a/games-roguelike/angband/files/angband-4.0.5-pie-gcc.patch
+++ /dev/null
@@ -1,13 +0,0 @@
-Allow gcc to construct correct partial linking command to ld.
-Otherwise ld gets an incompatible mix of '-pie -r'.
-
-https://bugs.gentoo.org/617982
-diff --git a/src/Makefile b/src/Makefile
-index 79be4cc..d27bb91 100644
---- a/src/Makefile
-+++ b/src/Makefile
-@@ -33,3 +33,3 @@ win/$(PROGNAME).res: win/$(PROGNAME).rc
- $(PROGNAME).o: $(OBJECTS)
--	$(LD) -nostdlib -Wl,-r -o $@ $(OBJECTS)
-+	$(LD) -nostdlib -r -o $@ $(OBJECTS)
- 	@printf "%10s %-20s\n" LINK $@