reinit the tree, so we can have metadata

5 files changed, 222 insertions, 0 deletions

diff --git a/games-fps/alephone/Manifest b/games-fps/alephone/Manifest
new file mode 100644
index 000000000000..cf895eb311a6
--- /dev/null
+++ b/games-fps/alephone/Manifest
@@ -0,0 +1,7 @@
+AUX alephone.sh 442 SHA256 03d4eaec18bed5fd909604ff7efbcf4ba737a2cc76ca80161bdcb4bdf527d8b9 SHA512 e6bda9a286cfbc2971af2ac4fc3a119e680ca8fe987ab4a1599a23de766b09702fe2a2c7713598918884a998636f58fd15da083c4b5130e1ae85e09720b2d0f1 WHIRLPOOL b793d2144a6d1f12a93d33f500d60d77e92f97aae93fb37e4def83fefaf39b19cfde449aab67c28d8a9311ec91dc4dbc76ba825a7c782db6b7430bcc75213f20
+DIST AlephOne-20150620.tar.bz2 5031898 SHA256 c0f360dfb74a6264f95d375103a74000930cf0439ffb0464f915f5379443e133 SHA512 fb47969137b791f83b111171d7b92b3708597db294ce19fb682ce28c49edcd4cb84a6ce4dcceb6630812a8c676dfe7f39f3fb4642f40ef7086a0d6c6fdeba8df WHIRLPOOL a00150e8c28763d7d01a5d805e449247dc9ff612eb0e9f0aa2d10e7fcf17654342fa31eb5a2eeb3bc756c80cce84dd9664179977900d635e67401036c71a7c10
+EBUILD alephone-20150620-r1.ebuild 2126 SHA256 1d83a338a13df1059ce65854edfd52ce50ab27f543debf9368b63f0af2d6a854 SHA512 0836de5d9303996e619669e23b819ca4698796e1730d0697efc642784b3f70894f94dc9049945391ae0852d6fe0e44ed3a2835ed9f4ea95da02b5a462e6e60ee WHIRLPOOL 36f5b6ce510b4dd69e000d0ad9f646d7eed287d022e31a3b0046b97f38f4374d719c4b80a70d35854a20f35b6c708459895cdd653e2d1089b45817eb27e5d736
+EBUILD alephone-20150620.ebuild 2170 SHA256 884c3067ce970534c01854b2f3ea4e81a8efcf2e3fda410889c66d66a638c7d6 SHA512 f9b78c8c13a1f640a5969099e5a94567b1a69c8b62147a7e3b1102c0fa7623c0d4644558f9c5933030a0dd9f9efa8841f9f40092579f79d82ccbc081f6132175 WHIRLPOOL ebe3df6ffac59156773f952340d9f151c85c8109d643b37d870285800c16b672246df24459a7387bda4797741b48d83779a9dfb33cd087cd2f814141aac4663a
+MISC ChangeLog 3942 SHA256 554ac0e7a269ba051aac5a8b6c205dd1405840e58d9ce92b7bec8c633c1b5eec SHA512 4ba20e445df8f04bd61300c4c57d29f5a8967ae25eb03cc120ce2abe2c25910e299f293ca3d0c3635f0095d3cc9e59250b3003d8712e83cbce4dd8a801d70f79 WHIRLPOOL d3581d3602a5ce73b7f58fc61810f216906971b61a28322a369e7147882b72d8ded49befeace14af5c675aaa6bf78ab26034502c01dc9a21a35fd98b23b5457c
+MISC ChangeLog-2015 6249 SHA256 51a39595099270ea5e09f30336dc1673802d710f08aaa9286add57a3adac4504 SHA512 051d4470be1d6f16d2a0293d81b0d0f5f1d8c97a9063aa3954a248625aac0df60449f1ddcaa017a4af3d3067b18bebf090ed4fb7fd0fc0917495c21a1b77d362 WHIRLPOOL 3e9d2d030c321b2c767b82b7a5e5d718061f696082835e9a99e8e0912e23a3d24139c9cf382536d0c1adfba717a6111e6fd5335434080625cf59da91023103ff
+MISC metadata.xml 398 SHA256 c175daac46eddc675bf22bc5d71f7c01b54e112d2f0dc6b328d186dacb50bd33 SHA512 2c4d493556b9b5407016ff655d093dc22fc1462a6d92c21c6e37bd4ba6566b64cbf848668fa1db1442f8f712dca592c38779641e3c522b23c44056405061fbe9 WHIRLPOOL 972aa8140e09bbbc331906c4fe5195d1489e5a8962b827104ccc6c1c10ae9054d7a34d299058ccc28f5aeca69b02931d6027ee7a1113506c9774ff2725f67f68
diff --git a/games-fps/alephone/alephone-20150620-r1.ebuild b/games-fps/alephone/alephone-20150620-r1.ebuild
new file mode 100644
index 000000000000..4672cf9d6742
--- /dev/null
+++ b/games-fps/alephone/alephone-20150620-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils
+
+MY_P=AlephOne-${PV}
+DESCRIPTION="An enhanced version of the game engine from the classic Mac game, Marathon"
+HOMEPAGE="http://source.bungie.org/"
+SRC_URI="https://github.com/Aleph-One-Marathon/alephone/releases/download/release-${PV}/AlephOne-${PV}.tar.bz2"
+
+LICENSE="GPL-3+ BitstreamVera OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="alsa curl ffmpeg mad mpeg sndfile speex vorbis"
+
+RDEPEND="
+	dev-libs/boost
+	dev-libs/expat
+	dev-libs/zziplib
+	media-libs/libpng:0
+	media-libs/libsdl[joystick,opengl,video]
+	media-libs/sdl-image[png]
+	media-libs/sdl-net
+	media-libs/sdl-ttf
+	virtual/opengl
+	virtual/glu
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	mad? ( media-libs/libmad )
+	mpeg? ( media-libs/smpeg )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex )
+	vorbis? ( media-libs/libvorbis )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	sed "s:GAMES_DATADIR:/usr/share:g" \
+		"${FILESDIR}"/${PN}.sh > "${T}"/${PN}.sh \
+		|| die
+
+	# try using the system expat - bug #251108
+	sed -i \
+		-e '/SUBDIRS/ s/Expat//' \
+		-e 's/Expat\/libexpat.a/-lexpat/' \
+		Source_Files/Makefile.am || die
+	sed -i -e '/Expat/d' configure.ac || die
+	rm -r Source_Files/Expat || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-lua \
+		--enable-opengl \
+		$(use_with alsa) \
+		$(use_with ffmpeg) \
+		$(use_with mad) \
+		$(use_with mpeg smpeg) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with vorbis)
+}
+
+src_install() {
+	default
+	dobin "${T}"/${PN}.sh
+	doman docs/${PN}.6
+	dodoc docs/*.html
+}
+
+pkg_postinst() {
+	echo
+	elog "Read the docs and install the data files accordingly to play."
+	echo
+	elog "If you only want to install one scenario, read"
+	elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Single_scenario_3"
+	elog "If you want to install multiple scenarios, read"
+	elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Multiple_scenarios_3"
+	echo
+}
diff --git a/games-fps/alephone/alephone-20150620.ebuild b/games-fps/alephone/alephone-20150620.ebuild
new file mode 100644
index 000000000000..c7b76c3a9b97
--- /dev/null
+++ b/games-fps/alephone/alephone-20150620.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit autotools eutils games
+
+MY_P=AlephOne-${PV}
+DESCRIPTION="An enhanced version of the game engine from the classic Mac game, Marathon"
+HOMEPAGE="http://source.bungie.org/"
+SRC_URI="https://github.com/Aleph-One-Marathon/alephone/releases/download/release-${PV}/AlephOne-${PV}.tar.bz2"
+
+LICENSE="GPL-3+ BitstreamVera OFL-1.1"
+SLOT="0"
+KEYWORDS="amd64 ~ppc64 x86"
+IUSE="alsa curl ffmpeg mad mpeg sndfile speex vorbis"
+
+RDEPEND="media-libs/sdl-net
+	media-libs/sdl-ttf
+	media-libs/sdl-image[png]
+	media-libs/libsdl[joystick,opengl,video]
+	dev-libs/expat
+	dev-libs/zziplib
+	dev-libs/boost
+	media-libs/libpng:0
+	virtual/opengl
+	virtual/glu
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	mad? ( media-libs/libmad )
+	mpeg? ( media-libs/smpeg )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex )
+	vorbis? ( media-libs/libvorbis )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	sed "s:GAMES_DATADIR:${GAMES_DATADIR}:g" \
+		"${FILESDIR}"/${PN}.sh > "${T}"/${PN}.sh \
+		|| die
+
+	# try using the system expat - bug #251108
+	sed -i \
+		-e '/SUBDIRS/ s/Expat//' \
+		-e 's/Expat\/libexpat.a/-lexpat/' \
+		Source_Files/Makefile.am || die
+	sed -i -e '/Expat/d' configure.ac || die
+	rm -r Source_Files/Expat || die
+
+	eautoreconf
+}
+
+src_configure() {
+	egamesconf \
+		--enable-lua \
+		--enable-opengl \
+		$(use_with alsa) \
+		$(use_with ffmpeg) \
+		$(use_with mad) \
+		$(use_with mpeg smpeg) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with vorbis)
+}
+
+src_install() {
+	default
+	dogamesbin "${T}"/${PN}.sh
+	doman docs/${PN}.6
+	dohtml docs/*.html
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	echo
+	elog "Read the docs and install the data files accordingly to play."
+	echo
+	elog "If you only want to install one scenario, read"
+	elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Single_scenario_3"
+	elog "If you want to install multiple scenarios, read"
+	elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Multiple_scenarios_3"
+	echo
+}
diff --git a/games-fps/alephone/files/alephone.sh b/games-fps/alephone/files/alephone.sh
new file mode 100644
index 000000000000..62ac98f85770
--- /dev/null
+++ b/games-fps/alephone/files/alephone.sh
@@ -0,0 +1,28 @@
+#!/bin/sh
+
+DIR=$(dirname "${0}")
+CMD=$(basename "${0}")
+ALEPHONE=${CMD%%.sh}
+
+if [[ -z "${1}" ]]
+then
+	echo "Usage: ${0} SCENARIO FLAGS"
+	echo "Where SCENARIO is one of:"
+	for d in "GAMES_DATADIR"/alephone-*
+	do
+		echo "  ${d##*/alephone-}"
+	done
+	exit 2
+fi
+
+export ALEPHONE_DATA="GAMES_DATADIR/alephone-${1}"
+
+shift
+
+# kill ARTS, because we're just that nice
+if artsshell terminate 2> /dev/null
+then
+	sleep 2
+fi
+
+"${DIR}"/"${ALEPHONE}" "$@"
diff --git a/games-fps/alephone/metadata.xml b/games-fps/alephone/metadata.xml
new file mode 100644
index 000000000000..f7a55faa0217
--- /dev/null
+++ b/games-fps/alephone/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">marathon</remote-id>
+		<remote-id type="github">Aleph-One-Marathon/alephone</remote-id>
+	</upstream>
+</pkgmetadata>