reinit the tree, so we can have metadata

1 files changed, 74 insertions, 0 deletions

diff --git a/games-emulation/dosbox/dosbox-9999.ebuild b/games-emulation/dosbox/dosbox-9999.ebuild
new file mode 100644
index 000000000000..82456d41531c
--- /dev/null
+++ b/games-emulation/dosbox/dosbox-9999.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+GLIDE_PATCH=3722fc563b737d2d7933df6a771651c2154e6f7b
+SRC_URI="glide? ( https://raw.githubusercontent.com/voyageur/openglide/${GLIDE_PATCH}/platform/dosbox/dosbox_glide.diff -> dosbox_glide-${GLIDE_PATCH}.diff )"
+
+if [[ ${PV} = 9999 ]]; then
+	ESVN_REPO_URI="https://svn.code.sf.net/p/dosbox/code-0/dosbox/trunk"
+	inherit subversion
+else
+	SRC_URI+=" mirror://sourceforge/dosbox/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+fi
+
+inherit autotools eutils flag-o-matic
+
+DESCRIPTION="DOS emulator"
+HOMEPAGE="http://dosbox.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="alsa debug glide hardened opengl"
+
+DEPEND="alsa? ( media-libs/alsa-lib )
+	glide? ( media-libs/openglide )
+	opengl? ( virtual/glu virtual/opengl )
+	debug? ( sys-libs/ncurses:0 )
+	media-libs/libpng:0
+	media-libs/libsdl[joystick,video,X]
+	media-libs/sdl-net
+	media-libs/sdl-sound"
+RDEPEND=${DEPEND}
+
+if [[ ${PV} = 9999 ]]; then
+	S=${WORKDIR}/${PN}
+fi
+
+PATCHES=( "${FILESDIR}/${PN}-0.74-gcc46.patch" )
+
+src_prepare() {
+	use glide && eapply "${DISTDIR}"/dosbox_glide-${GLIDE_PATCH}.diff
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use glide && append-cppflags -I"${EPREFIX}"/usr/include/openglide
+
+	econf \
+		$(use_enable alsa alsa-midi) \
+		$(use_enable !hardened dynamic-core) \
+		$(use_enable !hardened dynamic-x86) \
+		$(use_enable debug) \
+		$(use_enable opengl)
+}
+
+src_install() {
+	default
+	make_desktop_entry dosbox DOSBox /usr/share/pixmaps/dosbox.ico
+	doicon src/dosbox.ico
+}
+
+pkg_postinst() {
+	if use glide; then
+		elog "You have enabled unofficial Glide emulation. To use this, symlink"
+		elog "or copy ${EPREFIX}/usr/share/openglide/glide2x-dosbox.ovl to your game's"
+		elog "directory and add the following to your DOSBox configuration."
+		elog ""
+		elog "[glide]"
+		elog "glide=true"
+	fi
+}