gentoo resync : 29.12.2022

3 files changed, 273 insertions, 44 deletions

diff --git a/games-emulation/dolphin/Manifest b/games-emulation/dolphin/Manifest
index 78cefd74f64c..7881d8c3950e 100644
--- a/games-emulation/dolphin/Manifest
+++ b/games-emulation/dolphin/Manifest
@@ -1,5 +1,8 @@
 AUX dolphin-5.0_p20210506-musl.patch 779 BLAKE2B 5f962082cf58377801a266ec987417b731332e31ce6d79bb8e66204f6299dc1912aea760a9545ac671b090e6a3625c54b9e00583695790bd5c51ba54d524e0d7 SHA512 7a611de89b84e0f706c37d2aacdfb62cb4115098ad1b31daa4e40bd47e3793ab59f626fced184965361ba776891a63d02d66a54f8b69f675b6b88047a283bd9e
 DIST dolphin-5.0_p20210506.tar.gz 42098693 BLAKE2B bb9e5b5eb344bd944753c0198d5835109399fdfae46e6858833e5f279ff1979d39e0c512bedb96a91a1241fff525c6f945d16ce1a6b6cc22798490d73b853862 SHA512 5d23e9356995011a0e7b07622d58c8dddc5134a4ec83b3d9343b9eca8d0d2c200ea8c9a299c6aa2550ca74d8e28e258531368f7c167fe620053eb2a0f73b1f2f
+DIST dolphin-5.0_p20220520.tar.gz 34880474 BLAKE2B 925cddfe8a5d6febced5721bea6ced7c8d2855619f74ca8940b95dc78ea523b4a1083b9ef6efe3561d833b8e9ecb742cb2adf5a1864c06b629b3ecd9e92cc871 SHA512 4993cb10061b142f6627c96493885a5f9d88857d8949c2e8e8d5df5ba6e19b4f98d199da5e641d3d61294884e1cbbe8191bc5b4445c60bf80723046b2524aad5
+DIST mgba-40d4c430fc36caeb7ea32fd39624947ed487d2f2.tar.gz 12921593 BLAKE2B 8c5cf7b9b53f897f6248ad6bc51efafaa8a9d5df137d42d30f4b042b6d1527049644595938626c8cae1385d329bc45bf42db8dcc4424b963a3899e0df53246eb SHA512 26d7b60cbc7415652bb9ca2a42ccd532856867db57bf6dd91d8204551970109b6b9f4a96c42d643ea96b9d071d6aec924d3c1bb79c251c95183b7fb8536456c9
 EBUILD dolphin-5.0_p20210506-r3.ebuild 4464 BLAKE2B 55c1c06f54b6f1b0cb97d17bfc79e88fe639f0a11c4d6c67e77b51576b4cab883a9f64410805ebb99ffdcb70b75bad1e0abfe9b621f3e10e46202b194873d153 SHA512 2078b5dd79e4828ef4685351cd5764ca0dfdceec6c3db11405d1636e1385d8536b1bd06f5a571f8f460304c398164c458e52994f3a31f6e741bd726aca130aa3
-EBUILD dolphin-9999.ebuild 4581 BLAKE2B d4f3db6f02d525e954df6d0e702794561388164333b3a8fe1ff87b20055b41e5d85908769cf2e2d9f8c9b470525636cf64b426bba6d764c4d4e58bfd828d06f9 SHA512 541ceff0c46f76d6de91dbbf2e83be76dbc729fa65debe2a2c7980687d6a5e60de1e225b9380ea21d0bad17d7f4bb1d587201fc9d5e9df9c64f4692d6e58e421
+EBUILD dolphin-5.0_p20220520.ebuild 4571 BLAKE2B afa711f5ea6044f935ac0d964215a95681fbc809d79451fbc356293e7faaef0804b18c845da7392183ea04ceafbca4968c5c2a129b00dd8a08506ff2b2bf262c SHA512 0c74f4c42217f4b03f8a5dd58157fda88c8467fa15235b7a5146335a9ade5751613e9f056d92b34513cd740753f13c70fb5bacbeef10b99dd87e41ad5bbe6275
+EBUILD dolphin-9999.ebuild 4571 BLAKE2B afa711f5ea6044f935ac0d964215a95681fbc809d79451fbc356293e7faaef0804b18c845da7392183ea04ceafbca4968c5c2a129b00dd8a08506ff2b2bf262c SHA512 0c74f4c42217f4b03f8a5dd58157fda88c8467fa15235b7a5146335a9ade5751613e9f056d92b34513cd740753f13c70fb5bacbeef10b99dd87e41ad5bbe6275
 MISC metadata.xml 1014 BLAKE2B dd84038010d16d37449491e1df7236b95a7dc30097264a9f9d1a542b59feffe3b1e6a6dba318fe856eaac7b7470a1c316c5378dabcccd8ef6f7f101f5ee683c5 SHA512 87b4cb7475697d7fad526c3dcae604aa9d4f8facf68b0bcdbb1c931a839c998a34977acdd1aec9cacfa7f9a8b7d3f9e33d6f1253a0f1899fa2e3439f1ebc08a6
diff --git a/games-emulation/dolphin/dolphin-5.0_p20220520.ebuild b/games-emulation/dolphin/dolphin-5.0_p20220520.ebuild
new file mode 100644
index 000000000000..d888afe15b4d
--- /dev/null
+++ b/games-emulation/dolphin/dolphin-5.0_p20220520.ebuild
@@ -0,0 +1,211 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake desktop xdg-utils pax-utils
+
+if [[ ${PV} == *9999 ]]
+then
+	EGIT_REPO_URI="https://github.com/dolphin-emu/dolphin"
+	EGIT_SUBMODULES=( Externals/mGBA/mgba )
+	inherit git-r3
+else
+	EGIT_COMMIT=0f2540a0d1133950467845f20b1e003181147781
+	MGBA_COMMIT=40d4c430fc36caeb7ea32fd39624947ed487d2f2
+	SRC_URI="
+		https://github.com/dolphin-emu/dolphin/archive/${EGIT_COMMIT}.tar.gz
+			-> ${P}.tar.gz
+		mgba? (
+			https://github.com/mgba-emu/mgba/archive/${MGBA_COMMIT}.tar.gz
+				-> mgba-${MGBA_COMMIT}.tar.gz
+		)
+	"
+	S=${WORKDIR}/${PN}-${EGIT_COMMIT}
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+DESCRIPTION="Gamecube and Wii game emulator"
+HOMEPAGE="https://dolphin-emu.org/"
+
+LICENSE="GPL-2+ BSD BSD-2 LGPL-2.1+ MIT ZLIB"
+SLOT="0"
+IUSE="
+	alsa bluetooth discord-presence doc +evdev ffmpeg +gui log mgba
+	profile pulseaudio systemd upnp vulkan
+"
+
+RDEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils:=
+	app-arch/zstd:=
+	dev-libs/hidapi:=
+	>=dev-libs/libfmt-8:=
+	dev-libs/lzo:=
+	dev-libs/pugixml:=
+	media-libs/cubeb:=
+	media-libs/libpng:=
+	media-libs/libsfml
+	media-libs/mesa[egl(+)]
+	net-libs/enet:1.3
+	net-libs/mbedtls:=
+	net-misc/curl:=
+	sys-libs/readline:=
+	sys-libs/zlib:=[minizip]
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXrandr
+	virtual/libusb:1
+	virtual/opengl
+	alsa? ( media-libs/alsa-lib )
+	bluetooth? ( net-wireless/bluez )
+	evdev? (
+		dev-libs/libevdev
+		virtual/udev
+	)
+	ffmpeg? ( media-video/ffmpeg:= )
+	gui? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	profile? ( dev-util/oprofile )
+	pulseaudio? ( media-sound/pulseaudio )
+	systemd? ( sys-apps/systemd:0= )
+	upnp? ( net-libs/miniupnpc )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+# vulkan-loader required for vulkan backend which can be selected
+# at runtime.
+RDEPEND+="
+	vulkan? ( media-libs/vulkan-loader )
+"
+
+# [directory]=license
+declare -A KEEP_BUNDLED=(
+	# please keep this list in CMakeLists.txt order
+
+	[Bochs_disasm]=LGPL-2.1+
+	[cpp-optparse]=MIT
+	[imgui]=MIT
+	[glslang]=BSD
+
+	# FIXME: xxhash can't be found by cmake
+	[xxhash]=BSD-2
+
+	# FIXME: requires minizip-ng
+	#[minizip]=ZLIB
+
+	[FreeSurround]=GPL-2+
+	[soundtouch]=LGPL-2.1+
+
+	# FIXME: discord-rpc not packaged
+	[discord-rpc]=MIT
+
+	[mGBA]=MPL-2.0
+
+	[picojson]=BSD-2
+	[rangeset]=ZLIB
+	[gtest]= # (build-time only)
+)
+
+src_prepare() {
+	if use mgba && [[ ${PV} != *9999 ]]; then
+		rmdir Externals/mGBA/mgba || die
+		mv "${WORKDIR}/mgba-${MGBA_COMMIT}" Externals/mGBA/mgba || die
+	fi
+
+	cmake_src_prepare
+
+	local s remove=()
+	for s in Externals/*; do
+		[[ -f ${s} ]] && continue
+		if ! has "${s#Externals/}" "${!KEEP_BUNDLED[@]}"; then
+			remove+=( "${s}" )
+		fi
+	done
+
+	einfo "removing sources: ${remove[*]}"
+	rm -r "${remove[@]}" || die
+
+	# About 50% compile-time speedup
+	if ! use vulkan; then
+		sed -i -e '/Externals\/glslang/d' CMakeLists.txt || die
+	fi
+
+	# Allow regular minizip.
+	sed -i -e '/minizip/s:>=2[.]0[.]0::' CMakeLists.txt || die
+
+	# Remove dirty suffix: needed for netplay
+	sed -i -e 's/--dirty/&=""/' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Use ccache only when user did set FEATURES=ccache (or similar)
+		# not when ccache binary is present in system (automagic).
+		-DCCACHE_BIN=CCACHE_BIN-NOTFOUND
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AUTOUPDATE=OFF
+		-DENABLE_BLUEZ=$(usex bluetooth)
+		-DENABLE_EVDEV=$(usex evdev)
+		-DENCODE_FRAMEDUMPS=$(usex ffmpeg)
+		-DENABLE_LLVM=OFF
+		# just adds -flto, user can do that via flags
+		-DENABLE_LTO=OFF
+		-DUSE_MGBA=$(usex mgba)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_QT=$(usex gui)
+		-DENABLE_SDL=OFF # not supported: #666558
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DFASTLOG=$(usex log)
+		-DOPROFILING=$(usex profile)
+		-DUSE_DISCORD_PRESENCE=$(usex discord-presence)
+		-DUSE_SHARED_ENET=ON
+		-DUSE_UPNP=$(usex upnp)
+
+		# Undo cmake.eclass's defaults.
+		# All dolphin's libraries are private
+		# and rely on circular dependency resolution.
+		-DBUILD_SHARED_LIBS=OFF
+
+		# Avoid warning spam around unset variables.
+		-Wno-dev
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build unittests
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc Readme.md
+	if use doc; then
+		dodoc -r docs/ActionReplay docs/DSP docs/WiiMote
+	fi
+
+	doicon -s 48 Data/dolphin-emu.png
+	doicon -s scalable Data/dolphin-emu.svg
+	doicon Data/dolphin-emu.svg
+}
+
+pkg_postinst() {
+	# Add pax markings for hardened systems
+	pax-mark -m "${EPREFIX}"/usr/games/bin/"${PN}"-emu
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/games-emulation/dolphin/dolphin-9999.ebuild b/games-emulation/dolphin/dolphin-9999.ebuild
index c62f0305347a..d888afe15b4d 100644
--- a/games-emulation/dolphin/dolphin-9999.ebuild
+++ b/games-emulation/dolphin/dolphin-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -11,10 +11,16 @@ then
 	EGIT_SUBMODULES=( Externals/mGBA/mgba )
 	inherit git-r3
 else
-	EGIT_COMMIT=eb5cd9be78c76b9ccbab9e5fbd1721ef6876cd68
+	EGIT_COMMIT=0f2540a0d1133950467845f20b1e003181147781
+	MGBA_COMMIT=40d4c430fc36caeb7ea32fd39624947ed487d2f2
 	SRC_URI="
 		https://github.com/dolphin-emu/dolphin/archive/${EGIT_COMMIT}.tar.gz
-			-> ${P}.tar.gz"
+			-> ${P}.tar.gz
+		mgba? (
+			https://github.com/mgba-emu/mgba/archive/${MGBA_COMMIT}.tar.gz
+				-> mgba-${MGBA_COMMIT}.tar.gz
+		)
+	"
 	S=${WORKDIR}/${PN}-${EGIT_COMMIT}
 	KEYWORDS="~amd64 ~arm64"
 fi
@@ -22,24 +28,30 @@ fi
 DESCRIPTION="Gamecube and Wii game emulator"
 HOMEPAGE="https://dolphin-emu.org/"
 
-LICENSE="GPL-2+ Apache-2.0 BSD BSD-2 ISC LGPL-2.1+ MIT MPL-2.0 ZLIB"
+LICENSE="GPL-2+ BSD BSD-2 LGPL-2.1+ MIT ZLIB"
 SLOT="0"
-IUSE="alsa bluetooth discord-presence doc +evdev ffmpeg +gui log mgba
-	profile pulseaudio systemd upnp vulkan"
+IUSE="
+	alsa bluetooth discord-presence doc +evdev ffmpeg +gui log mgba
+	profile pulseaudio systemd upnp vulkan
+"
 
 RDEPEND="
-	dev-libs/hidapi:0=
-	>=dev-libs/libfmt-7.1:0=
-	dev-libs/lzo:2=
-	dev-libs/pugixml:0=
-	media-libs/libpng:0=
+	app-arch/bzip2:=
+	app-arch/xz-utils:=
+	app-arch/zstd:=
+	dev-libs/hidapi:=
+	>=dev-libs/libfmt-8:=
+	dev-libs/lzo:=
+	dev-libs/pugixml:=
+	media-libs/cubeb:=
+	media-libs/libpng:=
 	media-libs/libsfml
 	media-libs/mesa[egl(+)]
 	net-libs/enet:1.3
-	net-libs/mbedtls:0=
-	net-misc/curl:0=
-	sys-libs/readline:0=
-	sys-libs/zlib:0=
+	net-libs/mbedtls:=
+	net-misc/curl:=
+	sys-libs/readline:=
+	sys-libs/zlib:=[minizip]
 	x11-libs/libXext
 	x11-libs/libXi
 	x11-libs/libXrandr
@@ -62,55 +74,54 @@ RDEPEND="
 	systemd? ( sys-apps/systemd:0= )
 	upnp? ( net-libs/miniupnpc )
 "
-DEPEND="${RDEPEND}"
+DEPEND="
+	${RDEPEND}
+"
 BDEPEND="
 	sys-devel/gettext
-	virtual/pkgconfig"
+	virtual/pkgconfig
+"
 
 # vulkan-loader required for vulkan backend which can be selected
 # at runtime.
-RDEPEND="${RDEPEND}
-	vulkan? ( media-libs/vulkan-loader )"
+RDEPEND+="
+	vulkan? ( media-libs/vulkan-loader )
+"
 
 # [directory]=license
 declare -A KEEP_BUNDLED=(
-	[Bochs_disasm]=LGPL-2.1+
-	[FreeSurround]=GPL-2+
-
-	# vulkan's API is not backwards-compatible:
-	# new release dropped VK_PRESENT_MODE_RANGE_SIZE_KHR
-	# but dolphin still relies on it, bug #729832
-	[Vulkan]=Apache-2.0
+	# please keep this list in CMakeLists.txt order
 
+	[Bochs_disasm]=LGPL-2.1+
 	[cpp-optparse]=MIT
-	# no support for for using system library
-	[glslang]=BSD
 	[imgui]=MIT
-
-	# not packaged, tiny header library
-	[rangeset]=ZLIB
+	[glslang]=BSD
 
 	# FIXME: xxhash can't be found by cmake
 	[xxhash]=BSD-2
-	# no support for for using system library
-	[minizip]=ZLIB
-	# soundtouch uses shorts, not floats
+
+	# FIXME: requires minizip-ng
+	#[minizip]=ZLIB
+
+	[FreeSurround]=GPL-2+
 	[soundtouch]=LGPL-2.1+
-	[cubeb]=ISC
+
+	# FIXME: discord-rpc not packaged
 	[discord-rpc]=MIT
-	# Their build set up solely relies on the build in gtest.
-	[gtest]= # (build-time only)
-	# gentoo's version requires exception support.
-	# dolphin disables exceptions and fails the build.
-	[picojson]=BSD-2
-	# No code to detect shared library.
-	[zstd]=BSD
 
-	# This is a stripped-down mGBA for integrated GBA support
 	[mGBA]=MPL-2.0
+
+	[picojson]=BSD-2
+	[rangeset]=ZLIB
+	[gtest]= # (build-time only)
 )
 
 src_prepare() {
+	if use mgba && [[ ${PV} != *9999 ]]; then
+		rmdir Externals/mGBA/mgba || die
+		mv "${WORKDIR}/mgba-${MGBA_COMMIT}" Externals/mGBA/mgba || die
+	fi
+
 	cmake_src_prepare
 
 	local s remove=()
@@ -129,6 +140,9 @@ src_prepare() {
 		sed -i -e '/Externals\/glslang/d' CMakeLists.txt || die
 	fi
 
+	# Allow regular minizip.
+	sed -i -e '/minizip/s:>=2[.]0[.]0::' CMakeLists.txt || die
+
 	# Remove dirty suffix: needed for netplay
 	sed -i -e 's/--dirty/&=""/' CMakeLists.txt || die
 }
@@ -139,6 +153,7 @@ src_configure() {
 		# not when ccache binary is present in system (automagic).
 		-DCCACHE_BIN=CCACHE_BIN-NOTFOUND
 		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AUTOUPDATE=OFF
 		-DENABLE_BLUEZ=$(usex bluetooth)
 		-DENABLE_EVDEV=$(usex evdev)
 		-DENCODE_FRAMEDUMPS=$(usex ffmpeg)