gentoo resync : 14.07.2018

3 files changed, 119 insertions, 0 deletions

diff --git a/games-board/gnubg/Manifest b/games-board/gnubg/Manifest
new file mode 100644
index 000000000000..ce3cd234c4a5
--- /dev/null
+++ b/games-board/gnubg/Manifest
@@ -0,0 +1,3 @@
+DIST gnubg-release-1.05.000-sources.tar.gz 15030177 BLAKE2B a53c7d1d242083631a18f8c3eaa4d006fbbda8b6aef8240c1cc27a98b284cebd31ad2787ddd6e360a96bb365851c611971d47f686b2d8a42dfa35ff6a240eb02 SHA512 1d8080c362cb32a3828b6913823d0eb42b0befac7a9fbd6d5ee3346e7515f6150876ac3b8bd59d5fd0c0de2a03187441165bb82eff0ffa1fb84e385dcea58590
+EBUILD gnubg-1.05.000-r1.ebuild 2602 BLAKE2B 27a62ac75fe72e8ede5d30682a401e2daf11ccbbe7bd0ebd81f9a73708e4708dabe36698986bef5663d4ae7bf1b97e84c449c294447e4d47721c6704c2c1575a SHA512 5f95e71851deacdc08f62b7e96e8a60591ea4bd54f17d5376ebf4f5b51775cadf3146b4f65f96b3cfefbfa513b55490d18e052948f509291d2921686986c10d6
+MISC metadata.xml 249 BLAKE2B 7113a758d7abc93accec998a8843d8ef51ca8b72d72e659e224d5cec2a1a6a63e6c0605958091532ac6e51fa0d501ca4fd9f3f4a9e55baeb31519a02971b465f SHA512 895577c3a805c40581da03057b94e3f28f05f23012bf350c1e3575847d1a0fe40bb044a46f909012a200d991a400f6389358a60e9c2b5bef0da01fb26f846118
diff --git a/games-board/gnubg/gnubg-1.05.000-r1.ebuild b/games-board/gnubg/gnubg-1.05.000-r1.ebuild
new file mode 100644
index 000000000000..b8e5f10b0a12
--- /dev/null
+++ b/games-board/gnubg/gnubg-1.05.000-r1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1 gnome2-utils
+
+DESCRIPTION="GNU BackGammon"
+HOMEPAGE="http://www.gnubg.org/"
+SRC_URI="http://gnubg.org/media/sources/${PN}-release-${PV}-sources.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~x86-fbsd"
+IUSE="cpu_flags_x86_avx gtk opengl python sqlite cpu_flags_x86_sse cpu_flags_x86_sse2 threads"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/gmp:0
+	dev-libs/libxml2
+	media-fonts/dejavu
+	media-libs/freetype:2
+	media-libs/libcanberra
+	media-libs/libpng:0
+	sys-libs/readline:0
+	x11-libs/cairo
+	x11-libs/pango
+	gtk? ( x11-libs/gtk+:2 )
+	opengl? (
+		x11-libs/gtk+:2
+		x11-libs/gtkglext
+		virtual/glu
+	)
+	python? ( ${PYTHON_DEPS} )
+	virtual/libintl"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# use ${T} instead of /tmp for constructing credits (bug #298275)
+	sed -i -e 's:/tmp:${T}:' credits.sh || die
+	sed -i -e 's/fonts //' Makefile.in || die # handle font install ourself to fix bug #335774
+	sed -i \
+		-e '/^localedir / s#=.*$#= @localedir@#' \
+		-e '/^gnulocaledir / s#=.*$#= @localedir@#' \
+		po/Makefile.in.in || die
+	sed -i \
+		-e '/^gnubgiconsdir / s#=.*#= /usr/share#' \
+		-e '/^gnubgpixmapsdir / s#=.*#= /usr/share/pixmaps#' \
+		pixmaps/Makefile.in || die
+	sed -i \
+		-e '1i#include <config.h>' \
+		copying.c || die #551896
+}
+
+src_configure() {
+	local simd=no
+	local gtk_arg=--without-gtk
+
+	if use gtk || use opengl ; then
+		gtk_arg=--with-gtk
+	fi
+	use cpu_flags_x86_sse  && simd=sse
+	use cpu_flags_x86_sse2 && simd=sse2
+	use cpu_flags_x86_avx  && simd=avx
+	econf \
+		--localedir=/usr/share/locale \
+		--docdir=/usr/share/doc/${PF}/html \
+		--disable-cputest \
+		--enable-simd=${simd} \
+		${gtk_arg} \
+		$(use_enable threads) \
+		$(use_with python) \
+		$(use_with sqlite sqlite) \
+		$(use_with opengl board3d)
+}
+
+src_install() {
+	default
+	insinto /usr/share/${PN}
+	doins ${PN}.weights *bd
+	dodir /usr/share/${PN}/fonts
+	dosym /usr/share/fonts/dejavu/DejaVuSans.ttf /usr/share/${PN}/fonts/Vera.ttf
+	dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf /usr/share/${PN}/fonts/VeraBd.ttf
+	dosym /usr/share/fonts/dejavu/DejaVuSerif-Bold.ttf /usr/share/${PN}/fonts/VeraSeBd.ttf
+	make_desktop_entry "gnubg -w" "GNU Backgammon"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-board/gnubg/metadata.xml b/games-board/gnubg/metadata.xml
new file mode 100644
index 000000000000..78274e0fa550
--- /dev/null
+++ b/games-board/gnubg/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>games@gentoo.org</email>
+	<name>Gentoo Games Project</name>
+</maintainer>
+</pkgmetadata>