gentoo resync : 16.06.2019

3 files changed, 154 insertions, 2 deletions

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index 077ea5b58bc4..20bb8ef6ebda 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -8,4 +8,5 @@ EBUILD minetest-0.4.16-r1.ebuild 3226 BLAKE2B 917e9af650a0e760804a2247b516565864
 EBUILD minetest-0.4.17-r1.ebuild 3296 BLAKE2B e659a638177d0f1435352476393e71c6aef503fb8ce83b0bef7144c6d8c29b55955fa9e73e01f3e4954fb6eec0eaba0bcc351dce27dbe8879d8184d4ea9be206 SHA512 6024a9de7ce3ee7372f7ced01a40b0b060a351fce506d506a9fd1f225ba8cf858ca031851aeb11da351d3dac75624bcce1da924f239d83b12f79e85604ddf9ca
 EBUILD minetest-0.4.17.1.ebuild 3296 BLAKE2B e659a638177d0f1435352476393e71c6aef503fb8ce83b0bef7144c6d8c29b55955fa9e73e01f3e4954fb6eec0eaba0bcc351dce27dbe8879d8184d4ea9be206 SHA512 6024a9de7ce3ee7372f7ced01a40b0b060a351fce506d506a9fd1f225ba8cf858ca031851aeb11da351d3dac75624bcce1da924f239d83b12f79e85604ddf9ca
 EBUILD minetest-5.0.1-r1.ebuild 3518 BLAKE2B 5fe7cdd41d77c57043a028ab548d6d2ff6baa466971330d11f603fee5071cd0d448da1c577920e335c0948cf7e4457b289b8d443ec898c52a1f012304910c616 SHA512 412facd744106ea1496c1b471056479e6ce38953efa9ad2bf0b7ed7cc2d451bdf673de9e6c83ff258ff8a46392ba21c53a07607d6684ee82992ff08db4fd51b2
-MISC metadata.xml 2216 BLAKE2B 3872d007ded87d46e806b334e3808096f7a07c64e6ae1a99a5b79db81d7396131df7ea42d7d74753efd42844e7fe01de5e02be37c8f78198de953d9e8381602d SHA512 4c2a2a007239ca5a313e31caa19483fc877e241e5ede1ea509b12931d0feef1aa72cb086266d61f3d38c11fc303f646f328b17c5f184d8bb45d0019e6a31c9a7
+EBUILD minetest-5.0.1-r2.ebuild 3517 BLAKE2B 2d1e9f190a174175414c425c287622f1df602fb5be8592fa91fc62e56cd40d975eb284414387064f4be510e3afbbc3df1489168b6353b2edb577d6aa147e5a69 SHA512 0d6807cbfccdf1d3e6b414b83b937b1b2a2350fccae5cf098203831723c15ae898b8281102f89dbd13a98b3e1d1574aada6e21a71cad36c17acd602f234f8eb3
+MISC metadata.xml 2267 BLAKE2B b03bb79a231ef1cb5ae32ac59af11f3b19bf82fbd8c443dc3a028a7414bf09bf8eff90c14fbec64a369ba02d5b996001f03c5e7c5fe426d4506dadfb088a62bc SHA512 9aa15538ab9b6e99edca42bf61bb2395dec41e055cf9887d60d72193a06c2a8378c025d0b819ffee67dc340640b78e3f5485d22144b5ba4ef05c1745d481550b
diff --git a/games-action/minetest/metadata.xml b/games-action/minetest/metadata.xml
index c302c3ff8ee8..f23df1a68b75 100644
--- a/games-action/minetest/metadata.xml
+++ b/games-action/minetest/metadata.xml
@@ -38,15 +38,16 @@
 		<name>Proxy Maintainers</name>
 	</maintainer>
 	<use>
+		<flag name="client">Build Minetest client</flag>
 		<flag name="jsoncpp">Enable using a system-wide JSONCPP</flag>
 		<flag name="leveldb">Enable LevelDB backend</flag>
 		<flag name="postgres">Optionally use PostgreSQL as map backend</flag>
 		<flag name="redis">Enable redis backend via
 			<pkg>dev-libs/hiredis</pkg>
 		</flag>
+		<flag name="server">Build Minetest server</flag>
 		<flag name="spatial">Enable SpatialIndex AreaStore backend
 		</flag>
-		<flag name="server">Build minetest server</flag>
 	</use>
 	<upstream>
 		<bugs-to>https://github.com/minetest/minetest/issues</bugs-to>
diff --git a/games-action/minetest/minetest-5.0.1-r2.ebuild b/games-action/minetest/minetest-5.0.1-r2.ebuild
new file mode 100644
index 000000000000..072c5eda672b
--- /dev/null
+++ b/games-action/minetest/minetest-5.0.1-r2.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils user xdg
+
+DESCRIPTION="An InfiniMiner/Minecraft inspired game"
+HOMEPAGE="https://www.minetest.net"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +curl doc +leveldb luajit ncurses nls postgres redis +server +sound spatial +truetype"
+REQUIRED_USE="|| ( client server )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/gmp:0=
+	dev-libs/jsoncpp:=
+	sys-libs/zlib
+	client? (
+		app-arch/bzip2
+		dev-games/irrlicht
+		media-libs/libpng:0=
+		virtual/jpeg:0
+		virtual/opengl
+		x11-libs/libX11
+		x11-libs/libXxf86vm
+		sound? (
+			media-libs/libogg:=
+			media-libs/libvorbis:=
+			media-libs/openal:=
+		)
+		truetype? ( media-libs/freetype:2 )
+	)
+	curl? ( net-misc/curl )
+	leveldb? ( dev-libs/leveldb:= )
+	luajit? ( dev-lang/luajit:2 )
+	ncurses? ( sys-libs/ncurses:0= )
+	nls? ( virtual/libintl )
+	postgres? ( >=dev-db/postgresql-9.5:= )
+	redis? ( dev-libs/hiredis )
+	spatial? ( sci-libs/libspatialindex )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	if use server ; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# set paths
+	sed \
+		-e "s#@BINDIR@#${EPREFIX}/usr/bin#g" \
+		-e "s#@GROUP@#${PN}#g" \
+		"${FILESDIR}"/minetestserver.confd > "${T}"/minetestserver.confd || die
+
+	# remove bundled gmp/jsoncpp
+	rm -rf lib/{gmp,jsoncpp} || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex client)
+		-DBUILD_SERVER=$(usex server)
+		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
+		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
+		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_CURSES=$(usex ncurses)
+		-DENABLE_FREETYPE=$(usex truetype)
+		-DENABLE_GETTEXT=$(usex nls)
+		-DENABLE_GLES=0
+		-DENABLE_LEVELDB=$(usex leveldb)
+		-DENABLE_LUAJIT=$(usex luajit)
+		-DENABLE_POSTGRESQL=$(usex postgres)
+		-DENABLE_REDIS=$(usex redis)
+		-DENABLE_SPATIAL=$(usex spatial)
+		-DENABLE_SOUND=$(usex sound)
+		-DENABLE_SYSTEM_JSONCPP=1
+		-DRUN_IN_PLACE=0
+	)
+
+	use server && mycmakeargs+=(
+		-DIRRLICHT_INCLUDE_DIR="${EPREFIX}/usr/include/irrlicht"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc ; then
+		cmake-utils_src_compile doc
+		HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use server ; then
+		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
+		newconfd "${T}"/minetestserver.confd minetest-server
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use client ; then
+		elog
+		elog "optional dependencies:"
+		elog "	games-action/minetest_game (official mod)"
+		elog
+	fi
+
+	if use server ; then
+		elog
+		elog "Configure your server via /etc/conf.d/minetest-server"
+		elog "The user \"minetest\" is created with /var/lib/${PN} homedir."
+		elog "Default logfile is ~/minetest-server.log"
+		elog
+	fi
+
+	elog
+	elog "The version 5.x series is not compatible to the version 0.4 series."
+	elog "This applies to clients and servers, other content such as mods,"
+	elog "texture packs and worlds is unaffected and backwards-compatible"
+	elog "as usual."
+	elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}