gentoo resync : 14.05.2020

4 files changed, 177 insertions, 4 deletions

diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index 01ca33c783f3..d110a12de195 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -4,7 +4,9 @@ AUX mercurial-3.0.1-po_fixes.patch 1396 BLAKE2B 2de846558d2d2f8f4d4ccd7d8e0d65fd
 AUX mercurial-4.8.1-unbundle_zstd.patch 393 BLAKE2B 8556147baa6e493ee81aef1a68b2b6372ba094c6d5c73e97faa3f2da48179085ad475fe8d646916d3fb3294a166abec4a8b2a5b5e00cfd8fdaf55290a745ef2a SHA512 003844caff3dd4df15db8a6a084ee71d456026dc9222bf469f9489a9946a9205a57db274a26dabdc2d73fdff24cfd291f70b99141f2c9aad6e58d0fe1a1e7254
 DIST mercurial-5.2.2.tar.gz 7333065 BLAKE2B 9cec5a6ebe4693a1b96fe268211aa2eaa06643d5b8812c427757839d5389319f0e2ff3c1ed964a56bf8a3c46f7630321abf508c61691102856dfbdbd72fed662 SHA512 875e75587ab1f1c54edd2f7198dff21e6b287425f215a9d28ef98d5359420df90ca7ef0128ec7b772c4a31dc95b1082b4d6d28f1754968a08408516ba9ec91ee
 DIST mercurial-5.3.2.tar.gz 7514256 BLAKE2B 250ecd5c0a64138cbcda599513efba7b040c0fed0f020c73ade2525e0ef8a9ad06c10c5df4e16eb9bbeb3ab0f2cbb622a65f6d4827b269654c662810ef0385fb SHA512 b0afcf82b51676d2e7592eb9b29f9611d59816399166400027b6c8b29c10c9ddc96b57f7913e78f938b1345bb7ac29ecd4ddc793165b7cf192c3c7a95712cc99
-EBUILD mercurial-5.2.2-r1.ebuild 4260 BLAKE2B dacafbc137616dee14931e46b4e59a72c04ab878ca2492110258720fc9a2dfd8eea444cd6d88607c29d7039b2c8cc59d4e0c10fd9682d14dfdf24a21db426666 SHA512 156c151fa6a92d731f336a145b512df75d599a818892ae3b071be084150251450b9e9a48a55ed57f4948a719a31cabd217e0bbe0fbfcacd1be668c6213f6d19a
-EBUILD mercurial-5.3.2.ebuild 4273 BLAKE2B 4f4406b42a28133842cf93d85f5fbf11a17ad2b90128f51544b83db8ae32a0c140e9083d3e3a93812cd97b1b591fba02db48d6f667147d12ad2072008d343fa8 SHA512 06639342b94328556a84c7b51fac33bfa1771e50668d50b29f23a3610a26fa39894efe9b14d1e3a60f0aacb3903b623edc5606d1a9fed64844374b8999812e85
+DIST mercurial-5.4.tar.gz 7722447 BLAKE2B 9abd7b62ca6e44ede626331d080f7a0e8e7fb980c169fbfc2e847549c915b65789e317b674a8317bf58ced3cab4e2de790513e45c6556d32cac649fe23e04fdc SHA512 5f92d653ab74da4696ba7f1402e6cb219c0c514a5eeecb9d7282ab95aef2c6f16d5c8e3d0149525f3dc694a133c713b671ba92327e1b0dc3ad8701d522986d8d
+EBUILD mercurial-5.2.2-r1.ebuild 4254 BLAKE2B 543b201e0a2e3b5f1b0aab0a923232d08827644cf0f8037b6e085b7fa3f2db1941fa1bc37168d4424af46da351c7b47a8cfa38ed7bd775d3848aa4a65c457098 SHA512 7c514839c68522b7fc97ef8af14abe0a7595612d6fb7daca714e1f7e53f9627d5ef63e096e459c80a47e66177ba9704df8db3193ef621bc9b7d4ae35da98e39d
+EBUILD mercurial-5.3.2.ebuild 4261 BLAKE2B 7f9c514844fb1273c798cb950fb5a6297fd0a4e1507b05ff54eeaa5bcc93ad4da5c998d09b1ed9ce987d72947fef8a5ff049646e6eec4851c6baa3914d6f431f SHA512 1859206f9bf314a09809c7b9a2375501c0b386e28eb2f4f4d515786f270050c50d3748d50ec8b70e620ebc8fe2768d10ad23895d6aff6fcc1ea50228ee50534b
+EBUILD mercurial-5.4.ebuild 4266 BLAKE2B 070746bf6e8b7a1ab4ee60dba7cfaf9d3e6c7e9ed513cbdc31039c28eef80e7aa0f7c4749a5527a511d8627d4d4e43e157482fe2f164af8f79f0761cd3b900bf SHA512 725e6dda70241f4688783104c9cddc5048d61c071f4be85ea37c16d12a7b1257da8666031e3b4bd8b00b7d95f4b199adb1f0bb95755b71cc2b067791d3020a39
 EBUILD mercurial-9999.ebuild 4219 BLAKE2B 567a43e6491cf5317dd96998a57a6d562d07583a9b45ff4f45d01f1f2e1b61243ac646356efb90d86da51dad6634d5ea9a574a348ed73f4a2acf484a2608083f SHA512 d4e0373b8374205a72141e1376b7b17a209cd0e83456e5a0f95d382fa8b20173274f65cac74151a7dd99afb56a50cddf1fe352007fa5e1d7e198b5a37529f3c1
 MISC metadata.xml 483 BLAKE2B f81d3e855c41f0f5bef819cf4fbb537591f187917c76b5d153f9bf5f4cc14959c5aeef17ec9e5a0596d8e6bd2d8db0ad86dd4dea5ddfdd44a4c063acdc6a8a81 SHA512 3132d4cf6a2ba22ee8f93aef8de590bd576143dd80f56d515afb14cd5962899c0dfc4aee8552f041bac77b997055b2b407bad104591286be985de839f159fc83
diff --git a/dev-vcs/mercurial/mercurial-5.2.2-r1.ebuild b/dev-vcs/mercurial/mercurial-5.2.2-r1.ebuild
index a4954449a98b..0e787e47cd80 100644
--- a/dev-vcs/mercurial/mercurial-5.2.2-r1.ebuild
+++ b/dev-vcs/mercurial/mercurial-5.2.2-r1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 IUSE="+chg emacs gpg test tk zsh-completion"
 
 BROKEN_PYTHON="
diff --git a/dev-vcs/mercurial/mercurial-5.3.2.ebuild b/dev-vcs/mercurial/mercurial-5.3.2.ebuild
index e0eb454596bc..b296c9f4cc6f 100644
--- a/dev-vcs/mercurial/mercurial-5.3.2.ebuild
+++ b/dev-vcs/mercurial/mercurial-5.3.2.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ~ppc ~ppc64 x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 IUSE="+chg emacs gpg test tk zsh-completion"
 
 BROKEN_PYTHON="
diff --git a/dev-vcs/mercurial/mercurial-5.4.ebuild b/dev-vcs/mercurial/mercurial-5.4.ebuild
new file mode 100644
index 000000000000..25750d8586ff
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-5.4.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6..8} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="https://www.mercurial-scm.org/"
+SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+chg emacs gpg test tk zsh-completion"
+
+BROKEN_PYTHON="
+	!~dev-python/python-3.5.0
+	!~dev-python/python-3.5.1
+	!~dev-python/python-3.5.2
+	!~dev-python/python-3.6.0
+	!~dev-python/python-3.6.1"
+
+BDEPEND="${BROKEN_PYTHON}"
+
+RDEPEND="${BROKEN_PYTHON}
+	app-misc/ca-certificates
+	dev-python/zstandard[${PYTHON_USEDEP}]
+	gpg? ( app-crypt/gnupg )
+	tk? ( dev-lang/tk )
+	zsh-completion? ( app-shells/zsh )"
+
+DEPEND="emacs? ( >=app-editors/emacs-23.1:* )
+	test? ( app-arch/unzip
+		dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+# Too many tests fail #608720
+RESTRICT="test"
+
+python_prepare_all() {
+	# fix up logic that won't work in Gentoo Prefix (also won't outside in
+	# certain cases), bug #362891
+	sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+	# Use absolute import for zstd
+	sed -i -e 's/from \.* import zstd/import zstd/' \
+		mercurial/utils/compression.py \
+		mercurial/wireprotoframing.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	filter-flags -ftracer -ftree-vectorize
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile build_ext --no-zstd
+}
+
+python_compile_all() {
+	rm -r contrib/win32 || die
+	if use chg; then
+		emake -C contrib/chg
+	fi
+	if use emacs; then
+		cd contrib || die
+		elisp-compile mercurial.el || die "elisp-compile failed!"
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install build_ext --no-zstd
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newbashcomp contrib/bash_completion hg
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		newins contrib/zsh_completion _hg
+	fi
+
+	dobin hgeditor
+	if use tk; then
+		dobin contrib/hgk
+	fi
+	python_foreach_impl python_doscript contrib/hg-ssh
+
+	if use emacs; then
+		elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+	fi
+
+	local RM_CONTRIB=( hgk hg-ssh bash_completion zsh_completion plan9 *.el )
+
+	if use chg; then
+		dobin contrib/chg/chg
+		doman contrib/chg/chg.1
+		RM_CONTRIB+=( chg )
+	fi
+
+	for f in ${RM_CONTRIB[@]}; do
+		rm -rf contrib/${f} || die
+	done
+
+	dodoc -r contrib
+	docompress -x /usr/share/doc/${PF}/contrib
+	doman doc/*.?
+	dodoc CONTRIBUTORS hgweb.cgi
+
+	insinto /etc/mercurial/hgrc.d
+	doins "${FILESDIR}/cacerts.rc"
+}
+
+src_test() {
+	pushd tests &>/dev/null || die
+	rm -rf *svn*			# Subversion tests fail with 1.5
+	rm -f test-archive*		# Fails due to verbose tar output changes
+	rm -f test-convert-baz*		# GNU Arch baz
+	rm -f test-convert-cvs*		# CVS
+	rm -f test-convert-darcs*	# Darcs
+	rm -f test-convert-git*		# git
+	rm -f test-convert-mtn*		# monotone
+	rm -f test-convert-tla*		# GNU Arch tla
+	rm -f test-largefiles*		# tends to time out
+	if [[ ${EUID} -eq 0 ]]; then
+		einfo "Removing tests which require user privileges to succeed"
+		rm -f test-convert*
+		rm -f test-lock-badness*
+		rm -f test-permissions*
+		rm -f test-pull-permission*
+		rm -f test-journal-exists*
+		rm -f test-repair-strip*
+	fi
+
+	popd &>/dev/null || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local TEST_DIR
+
+	rm -rf "${TMPDIR}"/test
+	distutils_install_for_testing
+	cd tests || die
+	"${PYTHON}" run-tests.py --verbose \
+		--tmpdir="${TMPDIR}"/test \
+		--with-hg="${TEST_DIR}"/scripts/hg \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+
+	elog "If you want to convert repositories from other tools using convert"
+	elog "extension please install correct tool:"
+	elog "  dev-vcs/cvs"
+	elog "  dev-vcs/darcs"
+	elog "  dev-vcs/git"
+	elog "  dev-vcs/monotone"
+	elog "  dev-vcs/subversion"
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}