gentoo resync : 28.04.2019

2 files changed, 109 insertions, 0 deletions

diff --git a/dev-vcs/gitolite-gentoo/Manifest b/dev-vcs/gitolite-gentoo/Manifest
index b7a918953cc4..7a43328f1df2 100644
--- a/dev-vcs/gitolite-gentoo/Manifest
+++ b/dev-vcs/gitolite-gentoo/Manifest
@@ -28,6 +28,7 @@ EBUILD gitolite-gentoo-3.6.4.1-r1.ebuild 2796 BLAKE2B e7fe9ffb978de8be24b4969924
 EBUILD gitolite-gentoo-3.6.4.1.ebuild 2790 BLAKE2B 8ca32a75e449f42b5856e5a49eb0469dcea0247c3988167bd0fe1a1278d9c395c1a6679573d9aaa2a34780ff8a59a85baba33a3b38c782a2fcbbe2ca289f74b4 SHA512 c30568b53dfaece456c58603a0c63fc474819c66da2bb12ebe3c465edd67ce3dd38a9cb5667655b90fcb46af425a523098962c7d8f1f4dc938048f192f9001e0
 EBUILD gitolite-gentoo-3.6.4.ebuild 2790 BLAKE2B 8ca32a75e449f42b5856e5a49eb0469dcea0247c3988167bd0fe1a1278d9c395c1a6679573d9aaa2a34780ff8a59a85baba33a3b38c782a2fcbbe2ca289f74b4 SHA512 c30568b53dfaece456c58603a0c63fc474819c66da2bb12ebe3c465edd67ce3dd38a9cb5667655b90fcb46af425a523098962c7d8f1f4dc938048f192f9001e0
 EBUILD gitolite-gentoo-3.6.5.ebuild 2796 BLAKE2B e7fe9ffb978de8be24b4969924853bd04bd4482584f9780af9a98633c8b6723f0220f8f55c98335f3243d79d7afe5342be0ce972781027d1a0d36b56fdf2cc6e SHA512 3bd502a5cb7279968993e0070065b27e707c53e065ca143db5bb38e6f2a6d3b6a6282567a80522aa1a15509150218185bd1de5a2be40176acef03d30b395909c
+EBUILD gitolite-gentoo-3.6.6.1-r1.ebuild 2822 BLAKE2B 54201f3e814df8458ee90ec9524593e6450da69f2a1fd963a75f3273fe20afc737f8302dc8d1cf46a2f1fcb50a9e09695a26465d3d7d49daa40b528f95db388e SHA512 044bc927329b9ce7735783309051b28d1a97e9126c1e6e753bbe646408aeaccc80187188a761eff4c28951a64811c6ba88405404b525669ff55b34d1258bda34
 EBUILD gitolite-gentoo-3.6.6.1.ebuild 2796 BLAKE2B fc76471fd3d786d481fd98bb552818dd17177738fe73cec64e8b7391b6a1405641c04bd95f0409accb1633ce30bc72b68343e47086549b4f624e4bf5bcb9d67f SHA512 8f2800d6c8a11fd1d7ef43f754c17642db284c93e63a0028153dc33da647c59fe272eb09a2c8c0569915b7f57a5d29737a7be200b4ae8da88939e2bdecce4338
 EBUILD gitolite-gentoo-3.6.6.ebuild 2796 BLAKE2B fc76471fd3d786d481fd98bb552818dd17177738fe73cec64e8b7391b6a1405641c04bd95f0409accb1633ce30bc72b68343e47086549b4f624e4bf5bcb9d67f SHA512 8f2800d6c8a11fd1d7ef43f754c17642db284c93e63a0028153dc33da647c59fe272eb09a2c8c0569915b7f57a5d29737a7be200b4ae8da88939e2bdecce4338
 EBUILD gitolite-gentoo-9999.ebuild 2796 BLAKE2B e7fe9ffb978de8be24b4969924853bd04bd4482584f9780af9a98633c8b6723f0220f8f55c98335f3243d79d7afe5342be0ce972781027d1a0d36b56fdf2cc6e SHA512 3bd502a5cb7279968993e0070065b27e707c53e065ca143db5bb38e6f2a6d3b6a6282567a80522aa1a15509150218185bd1de5a2be40176acef03d30b395909c
diff --git a/dev-vcs/gitolite-gentoo/gitolite-gentoo-3.6.6.1-r1.ebuild b/dev-vcs/gitolite-gentoo/gitolite-gentoo-3.6.6.1-r1.ebuild
new file mode 100644
index 000000000000..b3f60acd4968
--- /dev/null
+++ b/dev-vcs/gitolite-gentoo/gitolite-gentoo-3.6.6.1-r1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+[[ ${PV} == *9999 ]] && SCM="git-2"
+EGIT_REPO_URI="git://git.gentoo.org/proj/gitolite-gentoo"
+EGIT_MASTER=master
+
+inherit perl-module user versionator ${SCM}
+
+DESCRIPTION="Highly flexible server for git directory version tracker, Gentoo fork"
+HOMEPAGE="https://cgit.gentoo.org/proj/gitolite-gentoo.git"
+if [[ ${PV} != *9999 ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	SRC_URI=""
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="selinux tools vim-syntax"
+
+DEPEND="dev-lang/perl
+	virtual/perl-File-Path
+	virtual/perl-File-Temp
+	>=dev-vcs/git-1.6.6"
+RDEPEND="${DEPEND}
+	!dev-vcs/gitolite
+	vim-syntax? ( app-vim/gitolite-syntax )
+	selinux? ( sec-policy/selinux-gitosis )
+	>=dev-perl/Net-SSH-AuthorizedKeysFile-0.17
+	dev-perl/JSON"
+
+PATCHES=( )
+
+pkg_setup() {
+	enewgroup git
+	enewuser git -1 /bin/sh /var/lib/gitolite git
+}
+
+src_prepare() {
+	default
+	echo "${PF}-gentoo" > src/VERSION || die
+}
+
+src_install() {
+	local uexec=/usr/libexec/${PN}
+
+	rm -rf src/lib/Gitolite/Test{,.pm}
+	insinto $VENDOR_LIB
+	doins -r src/lib/Gitolite
+
+	dodoc README.markdown CHANGELOG
+	# These are meant by upstream as examples, you are strongly recommended to
+	# customize them for your needs.
+	dodoc contrib/utils/ipa_groups.pl contrib/utils/ldap_groups.sh
+
+	insopts -m0755
+	insinto $uexec
+	doins -r src/{commands,syntactic-sugar,triggers,VREF}/
+	doins -r contrib/{commands,triggers,hooks}
+
+	insopts -m0644
+	doins src/VERSION
+
+	exeinto $uexec
+	doexe src/gitolite{,-shell}
+
+	dodir /usr/bin
+	for bin in gitolite{,-shell}; do
+		dosym /usr/libexec/${PN}/${bin} /usr/bin/${bin}
+	done
+
+	if use tools; then
+		dobin check-g2-compat convert-gitosis-conf
+		dobin contrib/utils/rc-format-v3.4
+	fi
+
+	keepdir /var/lib/gitolite
+	fowners git:git /var/lib/gitolite
+	fperms 750 /var/lib/gitolite
+
+	fperms 0644 ${uexec}/VREF/MERGE-CHECK # It's meant as example only
+}
+
+pkg_postinst() {
+	if [[ "$(get_major_version $REPLACING_VERSIONS)" == "2" ]]; then
+		ewarn
+		elog "***NOTE*** This is a major upgrade and will likely break your existing gitolite-2.x setup!"
+		elog "Please read http://gitolite.com/gitolite/migr.html first!"
+		ewarn
+		elog "***NOTE*** If you're using the \"umask\" feature of ${PN}-2.x:"
+		elog "You'll have to replace each \"umask = ...\" option by \"option umask = ...\""
+		elog "And you'll also have to enable the \"RepoUmask\" module in your .gitolite.rc"
+		ewarn
+	fi
+
+	# bug 352291
+	gitolite_home=$(awk -F: '$1 == "git" { print $6 }' /etc/passwd)
+	if [ -n "${gitolite_home}" -a "${gitolite_home}" != "/var/lib/gitolite" ]; then
+		ewarn
+		elog "Please make sure that your 'git' user has the correct homedir (/var/lib/gitolite)."
+		elog "Especially if you're migrating from gitosis."
+		ewarn
+	fi
+}