gentoo resync : 14.07.2018

3 files changed, 110 insertions, 0 deletions

diff --git a/dev-vcs/gitg/Manifest b/dev-vcs/gitg/Manifest
new file mode 100644
index 000000000000..cc2097113f7b
--- /dev/null
+++ b/dev-vcs/gitg/Manifest
@@ -0,0 +1,3 @@
+DIST gitg-3.26.0.tar.xz 1551308 BLAKE2B 45a9fd3df8eb891c4e07eefb6cf8f9b517c78dccc63dd08498b4c847614e164472e0605a01c81515ea349366e56c21c99a4558e73b6548b18bb94f578c0fc9bd SHA512 782aa02e2f0f4d8c86ad726045502d545877d835f0449d2ec646d93a78bbfa50f84662d3a437c922eb168b2737c00ec088dc2c73487742f332e3910f041b519d
+EBUILD gitg-3.26.0.ebuild 1927 BLAKE2B 97bb1f4da59bcf28643516ca55e054fe6405765dee0ef2bd70cedf6fc29ec2d422767d4dce420afe5900e5759e4f1b82d0b88b971e4ca59cfee9cbfe1e7b53f2 SHA512 fd96b0f937e1beaba697bd5449f6cf916809d4e121594acf405cdb98a156dae4f640ac2972f768cfb213649455948f3d008218fe7a7e0c052686be43185db217
+MISC metadata.xml 700 BLAKE2B f8330088988ad7eecd0dd8fa3f92fa9a22647e5c3a410051e0623124d2ab2bdc140b5330661124638bb2fe2d7c43b272004f07ce0bc344dd42a563b38ff1c15e SHA512 f5277e8ce7d17576ab50cbc5dd7694a9adcff03340029156915a085ada0bcc34e0366fbefdc9f4de0030694c8ce48d2d1baef62ead4650309c2af2def0309d3e
diff --git a/dev-vcs/gitg/gitg-3.26.0.ebuild b/dev-vcs/gitg/gitg-3.26.0.ebuild
new file mode 100644
index 000000000000..c9365256aab7
--- /dev/null
+++ b/dev-vcs/gitg/gitg-3.26.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{4,5,6} )
+VALA_MIN_API_VERSION="0.32" # Needed when gtk+-3.20 is found
+
+inherit gnome2 pax-utils python-r1 vala
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/libgee:0.8[introspection]
+	>=app-text/gtkspell-3.0.3:3
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/libgit2:=[threads]
+
+	>=dev-libs/libgit2-glib-0.25.0[ssh]
+	<dev-libs/libgit2-glib-0.27.0
+
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	net-libs/libsoup:2.4
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-3.10:3.0
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-libs/libgit2-glib-0.24.4[vala]
+	>=dev-util/intltool-0.40
+	gnome-base/gnome-common
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-deprecations \
+		$(use_enable glade glade-catalog) \
+		$(use_enable python)
+}
+
+src_install() {
+	# -j1: bug #???
+	gnome2_src_install -j1
+
+	if use python ; then
+		install_gi_override() {
+			python_moduleinto "$(python_get_sitedir)/gi/overrides"
+			python_domodule "${S}"/libgitg-ext/GitgExt.py
+		}
+		python_foreach_impl install_gi_override
+	fi
+}
diff --git a/dev-vcs/gitg/metadata.xml b/dev-vcs/gitg/metadata.xml
new file mode 100644
index 000000000000..bebf2c542746
--- /dev/null
+++ b/dev-vcs/gitg/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ikelos@gentoo.org</email>
+		<name>Mike Auty</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>gnome@gentoo.org</email>
+		<name>Gentoo GNOME Desktop</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>mgorny@gentoo.org</email>
+		<name>Michał Górny</name>
+	</maintainer>
+	<longdescription lang="en">
+		GTK+ based frontend for GIT
+	</longdescription>
+	<use>
+		<flag name="glade">Install a glade catalog file</flag>
+		<flag name="python">Install Python bindings for those plugins requiring it.</flag>
+	</use>
+</pkgmetadata>