gentoo resync : 18.01.2020

6 files changed, 299 insertions, 0 deletions

diff --git a/dev-util/cookiecutter/cookiecutter-1.7.0.ebuild b/dev-util/cookiecutter/cookiecutter-1.7.0.ebuild
new file mode 100644
index 000000000000..76f1d784ee90
--- /dev/null
+++ b/dev-util/cookiecutter/cookiecutter-1.7.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Command-line utility to create projects from cookiecutters (project templates)"
+HOMEPAGE="https://github.com/audreyr/cookiecutter"
+
+SRC_URI="https://github.com/audreyr/cookiecutter/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-python/future-0.15.2[${PYTHON_USEDEP}]
+	>=dev-python/binaryornot-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7[${PYTHON_USEDEP}]
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/whichcraft-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/poyo-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-time-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-catchlog[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-vcs/git )"
+
+DOCS=( README.md HISTORY.md CONTRIBUTING.md )
+
+python_test() {
+	py.test || die
+}
diff --git a/dev-util/icmake/icmake-9.03.01.ebuild b/dev-util/icmake/icmake-9.03.01.ebuild
new file mode 100644
index 000000000000..e6bd5c26d8b4
--- /dev/null
+++ b/dev-util/icmake/icmake-9.03.01.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Hybrid between a make utility and a shell scripting language"
+HOMEPAGE="https://fbb-git.gitlab.io/icmake/ https://gitlab.com/fbb-git/icmake"
+SRC_URI="https://gitlab.com/fbb-git/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+S=${WORKDIR}/${P}/${PN}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-9.00.00-ar.patch
+	"${FILESDIR}"/${PN}-9.02.02-verbose-build.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e "/^#define LIBDIR/s/lib/$(get_libdir)/" \
+		-e "/^#define DOCDIR/s/${PN}/${PF}/" \
+		-e "/^#define DOCDOCDIR/s/${PN}-doc/${PF}/" \
+		-i INSTALL.im || die
+
+	# fix build issues (bug #589896)
+	append-cflags -std=gnu99
+
+	tc-export AR CC
+}
+
+src_configure() {
+	./icm_prepare "${EROOT}" || die
+}
+
+src_compile() {
+	./icm_bootstrap "${EROOT}" || die
+}
+
+src_install() {
+	./icm_install all "${ED}" || die
+}
diff --git a/dev-util/lldb/lldb-11.0.0.9999.ebuild b/dev-util/lldb/lldb-11.0.0.9999.ebuild
new file mode 100644
index 000000000000..de7777bae713
--- /dev/null
+++ b/dev-util/lldb/lldb-11.0.0.9999.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{6,7}} )
+inherit cmake-utils llvm llvm.org multiprocessing python-single-r1 \
+	toolchain-funcs
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+LLVM_COMPONENTS=( lldb )
+LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
+llvm.org_set_globals
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="libedit lzma ncurses +python test"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	lzma? ( app-arch/xz-utils:= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? ( dev-python/six[${PYTHON_USEDEP}]
+		${PYTHON_DEPS} )
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	python? ( >=dev-lang/swig-3.0.11 )
+	test? (
+		~dev-python/lit-${PV}[${PYTHON_USEDEP}]
+		sys-devel/lld )
+	${PYTHON_DEPS}"
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLDB_ENABLE_CURSES=$(usex ncurses)
+		-DLLDB_ENABLE_LIBEDIT=$(usex libedit)
+		-DLLDB_ENABLE_PYTHON=$(usex python)
+		-DLLDB_ENABLE_LZMA=$(usex lzma)
+		-DLLDB_USE_SYSTEM_SIX=1
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		-DCLANG_LINK_CLANG_DYLIB=ON
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=$(usex test)
+		# compilers for lit tests
+		-DLLDB_TEST_C_COMPILER="$(type -P clang)"
+		-DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
+
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake-utils_src_make check-lldb-lit
+	use python && cmake-utils_src_make check-lldb
+}
+
+src_install() {
+	cmake-utils_src_install
+	find "${D}" -name '*.a' -delete || die
+
+	use python && python_optimize
+}
diff --git a/dev-util/qdevicemonitor/files/qdevicemonitor-1.0.1-screen-geometry-is-deprecated.patch b/dev-util/qdevicemonitor/files/qdevicemonitor-1.0.1-screen-geometry-is-deprecated.patch
new file mode 100644
index 000000000000..9b9b46320fe7
--- /dev/null
+++ b/dev-util/qdevicemonitor/files/qdevicemonitor-1.0.1-screen-geometry-is-deprecated.patch
@@ -0,0 +1,39 @@
+From 08985f03236a70b35b03b2749cabbd45398e968b Mon Sep 17 00:00:00 2001
+From: Alexander Lopatin <alopatindev@gmail.com>
+Date: Thu, 16 Jan 2020 11:26:38 +0300
+Subject: [PATCH] Fix "error: const QRect QDesktopWidget::screenGeometry(int)
+ const is deprecated: Use QGuiApplication::screens()
+ [-Werror=deprecated-declarations]" https://bugs.gentoo.org/705438
+
+Signed-off-by: Alexander Lopatin <alopatindev@gmail.com>
+---
+ qdevicemonitor/ui/MainWindow.cpp | 5 +++--
+ 1 file changed, 3 insertions(+), 2 deletions(-)
+
+diff --git a/qdevicemonitor/ui/MainWindow.cpp b/qdevicemonitor/ui/MainWindow.cpp
+index 4266de6..69d4433 100644
+--- a/qdevicemonitor/ui/MainWindow.cpp
++++ b/qdevicemonitor/ui/MainWindow.cpp
+@@ -29,6 +29,7 @@
+ #include <QFileInfo>
+ #include <QMessageBox>
+ #include <QProcess>
++#include <QScreen>
+ #include <QSettings>
+ #include <QStringList>
+ #include <QTabBar>
+@@ -181,9 +182,9 @@ void MainWindow::loadSettings()
+     {
+         setGeometry(geom.toRect());
+     }
+-    else
++    else if (!qApp->screens().isEmpty())
+     {
+-        QRect geom = qApp->desktop()->screenGeometry();
++        QRect geom = qApp->screens()[0]->availableVirtualGeometry();
+         const int screenWidth = geom.width();
+         const int screenHeight = geom.height();
+         geom.setWidth(int(screenWidth * 0.7f));
+-- 
+2.21.0
+
diff --git a/dev-util/qdevicemonitor/qdevicemonitor-1.0.1-r2.ebuild b/dev-util/qdevicemonitor/qdevicemonitor-1.0.1-r2.ebuild
new file mode 100644
index 000000000000..fd543ed3980a
--- /dev/null
+++ b/dev-util/qdevicemonitor/qdevicemonitor-1.0.1-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit desktop qmake-utils
+
+DESCRIPTION="Crossplatform log viewer for Android, iOS and text files"
+HOMEPAGE="https://github.com/alopatindev/qdevicemonitor"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/alopatindev/${PN}"
+else
+	SRC_URI="https://github.com/alopatindev/qdevicemonitor/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-util/android-tools
+	app-pda/usbmuxd"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-qt-5.11.patch
+	"${FILESDIR}"/${P}-crash-after-fresh-install.patch
+	"${FILESDIR}"/${P}-screen-geometry-is-deprecated.patch
+)
+
+src_configure() {
+	cd "${PN}" || die
+	export VERSION_WITH_BUILD_NUMBER="${PV}"
+	eqmake5
+}
+
+src_compile() {
+	cd "${PN}" || die
+	emake
+}
+
+src_install() {
+	dobin "${PN}/${PN}"
+	dodoc README.md
+	newicon -s scalable "icons/app_icon.svg" "${PN}.svg"
+	domenu "icons/${PN}.desktop"
+}
diff --git a/dev-util/stripe-mock/stripe-mock-0.79.0.ebuild b/dev-util/stripe-mock/stripe-mock-0.79.0.ebuild
new file mode 100644
index 000000000000..03b73892d5d0
--- /dev/null
+++ b/dev-util/stripe-mock/stripe-mock-0.79.0.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGO_SRC="github.com/stripe/stripe-mock"
+EGO_PN=${EGO_SRC}/...
+inherit golang-build golang-vcs-snapshot
+
+DESCRIPTION="Mock HTTP server that responds like the real Stripe API"
+HOMEPAGE="https://github.com/stripe/stripe-mock"
+SRC_URI="https://github.com/stripe/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="MIT ISC BSD-2"
+SLOT="0"
+
+src_install() {
+	golang-build_src_install
+	dobin bin/stripe-mock
+	rm -rf "${D%/}$(get_golibdir_gopath)" || die
+}