reinit the tree, so we can have metadata

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-util/trinity/trinity-9999.ebuild b/dev-util/trinity/trinity-9999.ebuild
new file mode 100644
index 000000000000..2e263c788cee
--- /dev/null
+++ b/dev-util/trinity/trinity-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs git-r3
+
+EGIT_REPO_URI="https://github.com/kernelslacker/trinity.git"
+
+DESCRIPTION="A Linux system call fuzz tester"
+HOMEPAGE="http://codemonkey.org.uk/projects/trinity/ https://github.com/kernelslacker/trinity/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples"
+
+DEPEND="sys-kernel/linux-headers"
+
+src_prepare() {
+	sed -e 's/-g -O2//' \
+		-e 's/-D_FORTIFY_SOURCE=2//' \
+		-e '/-o $@/s/$(LDFLAGS) //' \
+		-i Makefile || die
+
+	tc-export CC
+	default
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_install() {
+	dobin ${PN}
+	dodoc Documentation/* README
+
+	if use examples ; then
+		exeinto /usr/share/doc/${PF}/scripts
+		doexe scripts/*
+		docompress -x /usr/share/doc/${PF}/scripts
+	fi
+}