gentoo resync : 29.12.2022

2 files changed, 136 insertions, 0 deletions

diff --git a/dev-util/trace-cmd/Manifest b/dev-util/trace-cmd/Manifest
index ec85577c1905..7adeec2c7b25 100644
--- a/dev-util/trace-cmd/Manifest
+++ b/dev-util/trace-cmd/Manifest
@@ -1,3 +1,5 @@
 DIST trace-cmd-v2.9.1.tar.gz 4298008 BLAKE2B f7aa2f12b2c90f35390857ed6f5818b74c42be36ce70835d86410f9f4931d27410123baaad007fa2795c1ba1f5bafc739db620f467ccc48021d774ee7be8a68d SHA512 186bfdd8ff1e88e9e6d3ae87b123f049892deaaa8d6a42944b6f8abee6b828946b88774029aa96daf4423a3dfc01b42835508f44f636dd02579ef9a8ef425131
+DIST trace-cmd-v3.0.2.tar.gz 308097 BLAKE2B 109cf260a2bc219c9bef92fb85bdd5abd0698d261ecec35ea31b152986af720aae26720cfa6148f798fca1d33f631ea3e50906a5fc7ef00dbd705c63d3b83f2a SHA512 3f364409f4a8931a09b762b19ee19ae52215b46e7ed90610a0fa4092e71d88d0dae91353ff98ba11f18012c27ef67289097c6c132f0f07193fac459ac52861d0
 EBUILD trace-cmd-2.9.1.ebuild 2787 BLAKE2B 22b4be76ae6d985733791fe7c47fc274b83e5861695b99d4065e24667e567704591f0e532867e6524e603101c7a7b131eed7ee310beb2fb6f69dc279d7360548 SHA512 589e69f1c0c06887bfd27438617c9038ee59e4c9f21bf0807489aaf1c114b630756ed31a37c2fdda40c5474aa6a2699b88fd71e2eb0d356942b065e75cbabd61
+EBUILD trace-cmd-3.0.2.ebuild 3021 BLAKE2B 0fa5c12c6fc8be5adc4bd8bf170bf6c4636cb430d333ca1b8c54d53daba33b73421f32cb97842a8f7cd5f1c2c0718eb18d3af60c8314812b40d15710377a2fe8 SHA512 7cb9c9ed0f79a45090b5227206d92e5ed4ea64dbc7bac40f65d59789ad71b1bac9175beb28027ca86eb79ad5a5ae8da5fca8b4798a6cc908cb4a55858dc21662
 MISC metadata.xml 350 BLAKE2B 2504f9b76218d15f29a847c28e7a3d6c656b332ce39eee66700d510fe6c6a993848fc3a83c1a0e74113ea8022449723e31ebdcd09ac05e3310a3eeac1d7ee390 SHA512 6c8207a666c677c74cab3112b23b21867d2f1face36b5cdb7200d7edd9dd04f6e095551abf7ffdbe7d2c77df20d90062f17fc83e309bfe85568af791548c5a18
diff --git a/dev-util/trace-cmd/trace-cmd-3.0.2.ebuild b/dev-util/trace-cmd/trace-cmd-3.0.2.ebuild
new file mode 100644
index 000000000000..6fad1f86144f
--- /dev/null
+++ b/dev-util/trace-cmd/trace-cmd-3.0.2.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_OPTIONAL=1
+
+inherit linux-info bash-completion-r1 python-r1 toolchain-funcs
+
+DESCRIPTION="User-space front-end for Ftrace"
+HOMEPAGE="https://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/utils/trace-cmd/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git/snapshot/${PN}-v${PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-v${PV}"
+fi
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/${PV}"
+IUSE="+audit doc python test udis86 +zstd"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# XXX trace-cmd autodetects this without configurability. This might cause
+# issues if the libraries are picked up with the useflag disabled and later
+# uninstalled
+RDEPEND="
+	audit? ( sys-process/audit )
+	python? ( ${PYTHON_DEPS} )
+	udis86? ( dev-libs/udis86 )
+	zstd? ( >=app-arch/zstd-1.4 )
+	>=dev-libs/libtracefs-1.3
+	>=dev-libs/libtraceevent-1.5
+"
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers
+	test? ( dev-util/cunit )
+"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( dev-lang/swig )
+	doc? ( app-text/asciidoc )
+"
+
+# having trouble getting tests to compile
+RESTRICT+=" test"
+
+pkg_setup() {
+	local CONFIG_CHECK="
+		~TRACING
+		~FTRACE
+		~BLK_DEV_IO_TRACE"
+
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed -r -e 's:([[:space:]]+)install_bash_completion($|[[:space:]]+):\1:' \
+		-i Makefile || die "sed failed"
+}
+
+src_configure() {
+	EMAKE_FLAGS=(
+		BUILD_OUTPUT="${WORKDIR}/${P}_build"
+		"prefix=${EPREFIX}/usr"
+		"libdir=${EPREFIX}/usr/$(get_libdir)"
+		"CC=$(tc-getCC)"
+		"AR=$(tc-getAR)"
+		"BASH_COMPLETE_DIR=$(get_bashcompdir)"
+		"etcdir=/etc"
+		$(usex audit '' 'NO_AUDIT=' '' '1')
+		$(usex test 'CUNIT_INSTALLED=' '' '1' '')
+		$(usex udis86 '' 'NO_UDIS86=' '' '1')
+		VERBOSE=1
+	)
+}
+
+src_compile() {
+	emake "${EMAKE_FLAGS[@]}" NO_PYTHON=1 \
+		trace-cmd
+
+	if use python; then
+		python_copy_sources
+		python_foreach_impl python_compile
+	fi
+
+	use doc && emake doc
+}
+
+python_compile() {
+	pushd "${BUILD_DIR}" > /dev/null || die
+
+	emake "${EMAKE_FLAGS[@]}" \
+		PYTHON_VERS="${EPYTHON}" \
+		PYTHON_PKGCONFIG_VERS="${EPYTHON//python/python-}" \
+		python_dir=$(python_get_sitedir)/${PN} \
+		python ctracecmd.so
+
+	popd > /dev/null || die
+}
+
+src_test() {
+	emake "${EMAKE_FLAGS[@]}" test
+}
+
+src_install() {
+	emake "${EMAKE_FLAGS[@]}" NO_PYTHON=1 \
+		DESTDIR="${D}" \
+		install install_libs
+
+	newbashcomp tracecmd/trace-cmd.bash "${PN}"
+
+	use doc && emake DESTDIR="${D}" install_doc
+	use python && python_foreach_impl python_install
+}
+
+python_install() {
+	pushd "${BUILD_DIR}" > /dev/null || die
+
+	emake "${EMAKE_FLAGS[@]}" DESTDIR="${D}" \
+		PYTHON_VERS="${EPYTHON}" \
+		PYTHON_PKGCONFIG_VERS="${EPYTHON//python/python-}" \
+		python_dir=$(python_get_sitedir)/${PN} \
+		install_python
+
+	popd > /dev/null || die
+
+	python_optimize
+}