gentoo resync : 14.07.2018

3 files changed, 88 insertions, 0 deletions

diff --git a/dev-util/sysprof/Manifest b/dev-util/sysprof/Manifest
new file mode 100644
index 000000000000..bde6831c1a15
--- /dev/null
+++ b/dev-util/sysprof/Manifest
@@ -0,0 +1,3 @@
+DIST sysprof-3.24.1.tar.xz 595920 BLAKE2B 90582eab3fc12a0169c151ce0fad20b839841f77a31e5858f8d660f9b0f2630396bec3b239dd88baa3f6e3dd936bdd6d63a652e491a1d32f966a755f9099f160 SHA512 5d323bcb9923c511065132711963dc8856c4d837b4d7ccfae5cc5794be5ac8ad1dc42504025469199f4bfd6a6fad4d8f49b7b21cab6f0c9a954820182e75c7d0
+EBUILD sysprof-3.24.1.ebuild 1762 BLAKE2B 2af5ed24c22b41c66be0e4526b8e1627f1215320444c23559e6e553125700e31df955ec542b9ee04ec9a12a0bd4a669eb23cd4fbf96de6fb8d3562cb2c258c2b SHA512 24b82366648690bd9a4a03e04dc14e88d23c177c75dcca745a816213cf018ea4a959bb733da54ae0b1cbe85706df63cfc79140744716300a457c348eeb57982b
+MISC metadata.xml 842 BLAKE2B a36dfd049b5a5307006e5189a46fff5b6de8f16fbb8fcaffa8d737895e9864974478c00007b452c350b673fdc735e809ace65fb31d9a7e21c4d4905d9e1d3574 SHA512 cf90f7e7b64c02bb8ca0ec210959c39e004b0c4f6707b2c489ef2a566fd8d62961b902c00deec95f2f762c55d142f5d706a944553cd8e37bcce3d62c9eff8a9d
diff --git a/dev-util/sysprof/metadata.xml b/dev-util/sysprof/metadata.xml
new file mode 100644
index 000000000000..2f805617ad1a
--- /dev/null
+++ b/dev-util/sysprof/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+<maintainer type="person">
+	<email>tetromino@gentoo.org</email>
+	<name>Alexandre Rostovtsev</name>
+</maintainer>
+<longdescription lang="en">
+	Sysprof is a sampling CPU profiler for Linux that profiles the entire system,
+	not just a single application.
+	Sysprof handles shared libraries and applications do not need to be recompiled.
+	In fact they don't even have to be restarted.
+</longdescription>
+<use>
+	<flag name="systemd">Build the sysprofd daemon service, required to run the UI without root permissions.
+		Relies on <pkg>sys-apps/systemd</pkg> running as the init system.</flag>
+</use>
+</pkgmetadata>
diff --git a/dev-util/sysprof/sysprof-3.24.1.ebuild b/dev-util/sysprof/sysprof-3.24.1.ebuild
new file mode 100644
index 000000000000..f15fb682bb21
--- /dev/null
+++ b/dev-util/sysprof/sysprof-3.24.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2 linux-info systemd
+
+DESCRIPTION="System-wide Linux Profiler"
+HOMEPAGE="http://sysprof.com/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="debug gtk systemd"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	gtk? (
+		sys-auth/polkit
+		>=x11-libs/gtk+-3.22.0:3 )
+	systemd? (
+		sys-auth/polkit
+		>=sys-apps/systemd-222 )
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	>=sys-devel/gettext-0.19.6
+	>=sys-kernel/linux-headers-2.6.32
+	dev-libs/appstream-glib
+	virtual/pkgconfig
+"
+
+pkg_pretend() {
+	kernel_is -ge 2 6 31 && return
+	die "Sysprof will not work with a kernel version less than 2.6.31"
+}
+
+src_configure() {
+	# introspection & vala not use in build system
+	# --with-sysprofd=host currently unavailable from ebuild
+	gnome2_src_configure \
+		$(use_enable debug) \
+		$(use_enable gtk) \
+		--disable-introspection \
+		--disable-static \
+		--disable-vala \
+		--with-sysprofd=$(usex systemd bundled no) \
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "On many systems, especially amd64, it is typical that with a modern"
+	elog "toolchain -fomit-frame-pointer for gcc is the default, because"
+	elog "debugging is still possible thanks to gcc4/gdb location list feature."
+	elog "However sysprof is not able to construct call trees if frame pointers"
+	elog "are not present. Therefore -fno-omit-frame-pointer CFLAGS is suggested"
+	elog "for the libraries and applications involved in the profiling. That"
+	elog "means a CPU register is used for the frame pointer instead of other"
+	elog "purposes, which means a very minimal performance loss when there is"
+	elog "register pressure."
+}