gentoo Easter resync : 12.04.2020

3 files changed, 137 insertions, 0 deletions

diff --git a/dev-util/sysdig/Manifest b/dev-util/sysdig/Manifest
index ff3a5fa64f91..f7f1df54ae09 100644
--- a/dev-util/sysdig/Manifest
+++ b/dev-util/sysdig/Manifest
@@ -1,3 +1,6 @@
 DIST sysdig-0.26.4.tar.gz 902181 BLAKE2B a7ac38be2f7a3d7e4f4fdec6a2fbf5305a8224ee27352da70f509139ebefd14616f84c7b8860f50d2546819a94deb1117034bceddd22128fcf25386b835274f2 SHA512 f56f5d0a522b861df4803bfdafcaf8db3fc9c0e751d06c321082757f6828a210cb86bab4550a3b35bf6412f930e44ab0f5cf709a30651c57dd7064a68e273a88
+DIST sysdig-0.26.6.tar.gz 923918 BLAKE2B e022eba30977f5300c80a4806926d3e755b1395f05475c1fe925b86823670e397ad29e8bd18b1beaa893cb1bf83c329960c1bf9ff6faf0a5144343e88d52a4a0 SHA512 94784f0dfe46924b81d8804d950a9563cd18f4aa8b1cacd7e27e3974ecf7215223e03bdab001f408f64eb6c72f0da5082fd922d63079119427eb493c77e15795
+EBUILD sysdig-0.26.4-r1.ebuild 1351 BLAKE2B f1039664147482e4315038b0a61b91da1f13e988ab25c298670d0c98962a947cca5a1b63d092f62bb1d4e4daf299282575a84f29465e3d9c9bc183ecd90e9a79 SHA512 d06f10fdf0209d7842b2a7da5aea77a1fc71db662743b10618f1723ce21c95e5e82de884f7092227394460b06578691c427770dd8f1c10a4bf5ffe1c61d220d5
 EBUILD sysdig-0.26.4.ebuild 1818 BLAKE2B adf4b596e5301a650745609b547b47012c4de89954ceadc5a0d8f6399c25ca50c1c1458f323572a340d833119b00f791a9e62aa6b9b2ed70ffc8d89c59ebbf32 SHA512 6ae75c8dbe947fccf2db51e98ae1f96ec9c9b1f99d9dc8878e44c3a4cb02cb9006f3b2d0543dfd1f504ae25224b2a2099df8b15fd5fc1c9dc6ecb15f5ca09e7c
+EBUILD sysdig-0.26.6.ebuild 1446 BLAKE2B 8cacc86c38675a24c5b8d7e6402259ee6cf88035e08967bdfa43c24025be755cc326674d10189a3dbbd4331380b3b9f911375aa98507db8da708c4f93e6668f9 SHA512 2b2bec125737f8c5741b76c83844af1694c5753a2c9e10724d0e6483e2bc985162cbe85b0f724d2f49478e3b279df6e1de67235beabb7d6fb0051d077e9c775d
 MISC metadata.xml 507 BLAKE2B 4e19c0d3370019c80eda625ae812a4485139ab8a83285946ebc6ef62abad280beaefaaac29d7a57e14b5ca5448bd9d1c23a8cf6a4f783149633dd09e7ae1465c SHA512 d218731de7acfbbfa3c3043b2d942c00b7f5aff1a020b6dca2019f202be3a5390f44337e04691a0d4641e661f7581f703db5fda3d2a116c0d63fb7d9da25ed06
diff --git a/dev-util/sysdig/sysdig-0.26.4-r1.ebuild b/dev-util/sysdig/sysdig-0.26.4-r1.ebuild
new file mode 100644
index 000000000000..7ad2a9931646
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.26.4-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-cpp/tbb:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	dev-libs/protobuf:0=
+	net-dns/c-ares:0=
+	net-libs/grpc:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	virtual/os-headers"
+PDEPEND="
+	modules? ( >=dev-util/sysdig-kmod-${PV} )"
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# done in dev-util/sysdig-kmod
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove sources
+	rm -r "${ED}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED}"/usr/etc || die
+}
diff --git a/dev-util/sysdig/sysdig-0.26.6.ebuild b/dev-util/sysdig/sysdig-0.26.6.ebuild
new file mode 100644
index 000000000000..55a20f694f42
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.26.6.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-cpp/tbb:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	dev-libs/protobuf:0=
+	net-dns/c-ares:0=
+	net-libs/grpc:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	virtual/os-headers
+	test? ( dev-cpp/gtest )"
+PDEPEND="
+	modules? ( >=dev-util/sysdig-kmod-${PV} )"
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCREATE_TEST_TARGETS=$(usex test)
+
+		# done in dev-util/sysdig-kmod
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove sources
+	rm -r "${ED}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED}"/usr/etc || die
+}