gentoo resync : 14.07.2018

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-util/pkgcheck/pkgcheck-9999.ebuild b/dev-util/pkgcheck/pkgcheck-9999.ebuild
new file mode 100644
index 000000000000..2b1a33742b3b
--- /dev/null
+++ b/dev-util/pkgcheck/pkgcheck-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_6 )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pkgcore/pkgcheck.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="pkgcore-based QA utility"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+	RDEPEND="
+		=dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+		=sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+	RDEPEND="
+		>=dev-python/snakeoil-0.8.0[${PYTHON_USEDEP}]
+		>=sys-apps/pkgcore-0.10.0[${PYTHON_USEDEP}]"
+fi
+RDEPEND+=" dev-python/lxml[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+[[ ${PV} == *9999 ]] && DEPEND+=" dev-python/sphinx[${PYTHON_USEDEP}]"
+
+python_compile_all() {
+	esetup.py build_man
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS NEWS.rst )
+	distutils-r1_python_install install_man
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	python_foreach_impl pplugincache pkgcheck.plugins
+}