gentoo resync : 30.12.2017

2 files changed, 113 insertions, 0 deletions

diff --git a/dev-util/mingw64-runtime/Manifest b/dev-util/mingw64-runtime/Manifest
index 6efccaf82b74..7fcab200b720 100644
--- a/dev-util/mingw64-runtime/Manifest
+++ b/dev-util/mingw64-runtime/Manifest
@@ -22,5 +22,6 @@ EBUILD mingw64-runtime-5.0.1.ebuild 2560 BLAKE2B caf05db1d9a9a4578c044edb30d2513
 EBUILD mingw64-runtime-5.0.2-r1.ebuild 2651 BLAKE2B e3b044350a01e75c1bc32a67ad6593b2a9cee0002ea00f7c6546a6a66d24ec45fb1d2f8cc70a62d1f07c3b347d8da7a672ced76011bab1068845cdbcd955681c SHA512 f8c0fd5cc01431016675bf3831488e5852c29d9a0621216842f72b2bef1bdc57585b98885913d7c859a4aa8de01d1294a65ff1f7bd3224c691db7208d96946fc
 EBUILD mingw64-runtime-5.0.2-r2.ebuild 2691 BLAKE2B f05cbb14202abd1c5ac32c69c872aab7ebb879f020156faf975c1c6d1df63a29b2e59d89ac2b3da2b3271962e8dc569df4f5b53ab5c153d3d4e91842c67c1284 SHA512 33615d4db2e4fe13bc0a63e3b84445392133edbac907514dc41a0bc29f82be0ce54c837bd0dfd6c1872e74f89055cdc3d2b7989f6912f3d8f37e3ffcc72b3106
 EBUILD mingw64-runtime-5.0.2.ebuild 2560 BLAKE2B caf05db1d9a9a4578c044edb30d2513d028478672c5d1258eddd8863e34c949ed5bea5a44a5a6262e89e80de58b3d298b9bd5f5c21e6d535c955675b23a7c476 SHA512 a701ebddba123544e6c1854beac891ec1104d5bc3c5dbf151d0ed3c1be7e05a13a18885d0c9f5f74cb8e5f615cf30d084692e28770a57bc749a8504a36328392
+EBUILD mingw64-runtime-5.0.3-r1.ebuild 2569 BLAKE2B 61fb453aa51120d8c6ef25b1a72d029c579e9759cef08cc1c830907924478a57e8678d20f4b00706ee0b8c242abcec244bcf25a9b24e5ef64d3a5629563d77ba SHA512 1e566d554e2808e30bc952022ad427b8aa0ff46157815eafecbeca0e52740633f55e851a2a4b0bbaa2fde52ed17f5034551895102bbf48ff97e1df2c288d1dd4
 EBUILD mingw64-runtime-5.0.3.ebuild 2533 BLAKE2B 4449ac0eb34c7861c43884328b82983f424f45dc0e1565629a5aaa75e41b894d3144841c0ec25c96b4a7cd4787a958e4b502a08a1b878c7d4f2dce8eb4aa33a3 SHA512 ec22d9a4f4bf860e35167445d521d1e7d8a193b09e334ee17fa5fbb3b8313b565e0d474e18e1e47ddd60bd0dfffdde46a337aa12749502ae550f4d7e341688a5
 MISC metadata.xml 544 BLAKE2B 5d2a688f8f644b6893efd4f7a2e756d336c569a6a51fc4a0b0df94623ef7f3e8fa317fe6c971f233883b424e1abeaaf03ef92d56434cfea6eab5bdd3798ad6d5 SHA512 297a90e704de81f41a4f29871f96bed47aa00c703e79fd825b3a06ab8850fe67896c66dee2603f86cd6596a0c5cbd533c87cb94c1c674714f65767954341a3c8
diff --git a/dev-util/mingw64-runtime/mingw64-runtime-5.0.3-r1.ebuild b/dev-util/mingw64-runtime/mingw64-runtime-5.0.3-r1.ebuild
new file mode 100644
index 000000000000..1b9f05639b8d
--- /dev/null
+++ b/dev-util/mingw64-runtime/mingw64-runtime-5.0.3-r1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+export CBUILD=${CBUILD:-${CHOST}}
+export CTARGET=${CTARGET:-${CHOST}}
+if [[ ${CTARGET} == ${CHOST} ]] ; then
+	if [[ ${CATEGORY} == cross-* ]] ; then
+		export CTARGET=${CATEGORY#cross-}
+	fi
+fi
+
+WANT_AUTOMAKE="1.15"
+
+inherit autotools flag-o-matic eutils
+
+DESCRIPTION="Free Win64 runtime and import library definitions"
+HOMEPAGE="http://mingw-w64.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mingw-w64/mingw-w64/mingw-w64-release/mingw-w64-v${PV}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crosscompile_opts_headers-only idl libraries tools"
+RESTRICT="strip"
+
+S="${WORKDIR}/mingw-w64-v${PV}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-build.patch"
+)
+
+is_crosscompile() {
+	[[ ${CHOST} != ${CTARGET} ]]
+}
+just_headers() {
+	use crosscompile_opts_headers-only && [[ ${CHOST} != ${CTARGET} ]]
+}
+crt_with() {
+	just_headers && echo --without-$1 || echo --with-$1
+}
+crt_use_enable() {
+	just_headers && echo --without-$2 || use_enable "$@"
+}
+crt_use_with() {
+	just_headers && echo --without-$2 || use_with "$@"
+}
+
+pkg_setup() {
+	if [[ ${CBUILD} == ${CHOST} ]] && [[ ${CHOST} == ${CTARGET} ]] ; then
+		die "Invalid configuration"
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	CHOST=${CTARGET} strip-unsupported-flags
+
+	if ! just_headers; then
+		mkdir "${WORKDIR}/headers"
+		pushd "${WORKDIR}/headers" > /dev/null
+		CHOST=${CTARGET} "${S}/configure" \
+			--prefix="${T}/tmproot" \
+			--with-headers \
+			--without-crt \
+			|| die
+		popd > /dev/null
+		append-cppflags "-I${T}/tmproot/include"
+	fi
+
+	CHOST=${CTARGET} econf \
+		--prefix="${EPREFIX}"/usr/${CTARGET} \
+		--includedir="${EPREFIX}"/usr/${CTARGET}/usr/include \
+		--libdir="${EPREFIX}"/usr/${CTARGET}/usr/lib \
+		--with-headers \
+		--enable-sdk \
+		$(crt_with crt) \
+		$(crt_use_enable idl idl) \
+		$(crt_use_with libraries libraries) \
+		$(crt_use_with tools tools) \
+		$(
+			$(tc-getCPP ${CTARGET}) ${CPPFLAGS} -dM - < /dev/null | grep -q __MINGW64__ \
+				&& echo --disable-lib32 --enable-lib64 \
+				|| echo --enable-lib32 --disable-lib64
+		)
+}
+
+src_compile() {
+	if ! just_headers; then
+		emake -C "${WORKDIR}/headers" install
+	fi
+	default
+}
+
+src_install() {
+	default
+
+	if is_crosscompile ; then
+		# gcc is configured to look at specific hard-coded paths for mingw #419601
+		dosym usr /usr/${CTARGET}/mingw
+		dosym usr /usr/${CTARGET}/${CTARGET}
+		dosym usr/include /usr/${CTARGET}/sys-include
+	fi
+
+	env -uRESTRICT CHOST=${CTARGET} prepallstrip
+	rm -rf "${ED}/usr/share"
+}