gentoo resync : 29.12.2022

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-util/mdds/mdds-2.0.3.ebuild b/dev-util/mdds/mdds-2.0.3.ebuild
new file mode 100644
index 000000000000..6599638fac76
--- /dev/null
+++ b/dev-util/mdds/mdds-2.0.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.com/mdds/mdds.git"
+	inherit git-r3
+else
+	SRC_URI="https://kohei.us/files/${PN}/src/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux"
+fi
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Collection of multi-dimensional data structure and indexing algorithm"
+HOMEPAGE="https://gitlab.com/mdds/mdds"
+
+LICENSE="MIT"
+SLOT="1/2.0" # Check API version on version bumps!
+IUSE="doc openmp valgrind test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+	)
+	valgrind? ( dev-util/valgrind )
+"
+DEPEND="dev-libs/boost:="
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-1.5.0-buildsystem.patch" )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable doc docs)
+		$(use_enable openmp)
+		$(use_enable valgrind memory_tests)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	tc-export CXX
+	default
+}