gentoo auto-resync : 25:01:2023 - 14:07:44

2 files changed, 116 insertions, 0 deletions

diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index 92968c32d9dc..0c410393cb14 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -12,4 +12,5 @@ EBUILD lldb-15.0.6.ebuild 2716 BLAKE2B 88e5c97e848e7e83261c6c18c6f4857f173515b34
 EBUILD lldb-15.0.7.ebuild 2720 BLAKE2B 63570eeafcbe5de3ab65ebc7cb34d36c241650b57f0ebe3fc8c0080a852ec92ce2ffbbdd63a36af686679fdb9a5d573663ece760041e62ac81d8a52e00b79d19 SHA512 5d8412f605abe0dc9db49024ca70242d9ad161001b4c9949d998c5313f2d83c73556e6f04eebc460659302aaa75cd804875e5ccbf7d6cad1fd5a36cc85841516
 EBUILD lldb-16.0.0.9999.ebuild 2664 BLAKE2B 791938f67edd484c779b8663b1658a6c6db81d0283a2bc62b36c5499e27c61424055356511f5d4e306987fcbc4a490277d986d60ae77342021975ae89119fe14 SHA512 619c4fc08e3f0e175e97d3eeb8c37321ef5423e2d179d423c0daa586862e7ed21ceab83d36c6a6dd7cec82cc91f9f9ba34d17296bbad2b97cb4b14663796c2bb
 EBUILD lldb-16.0.0_pre20230107.ebuild 2664 BLAKE2B 791938f67edd484c779b8663b1658a6c6db81d0283a2bc62b36c5499e27c61424055356511f5d4e306987fcbc4a490277d986d60ae77342021975ae89119fe14 SHA512 619c4fc08e3f0e175e97d3eeb8c37321ef5423e2d179d423c0daa586862e7ed21ceab83d36c6a6dd7cec82cc91f9f9ba34d17296bbad2b97cb4b14663796c2bb
+EBUILD lldb-17.0.0.9999.ebuild 2664 BLAKE2B 791938f67edd484c779b8663b1658a6c6db81d0283a2bc62b36c5499e27c61424055356511f5d4e306987fcbc4a490277d986d60ae77342021975ae89119fe14 SHA512 619c4fc08e3f0e175e97d3eeb8c37321ef5423e2d179d423c0daa586862e7ed21ceab83d36c6a6dd7cec82cc91f9f9ba34d17296bbad2b97cb4b14663796c2bb
 MISC metadata.xml 299 BLAKE2B 2feead2cd1b35b3a43335ddd7711f8181b52bc63ee7166608914260c67528add5251349063afbef4f8cf0ec09b2cd4c3ffdd90f2c14ed60bb69ebc03888f6333 SHA512 cd745c54ab18d25bdaff18582105072574103a36cfe7c175ef740f266d00e9fc6f44c332904d23b911c939cf5bdf52973b388923099d8dd5dfef3c283b5cb685
diff --git a/dev-util/lldb/lldb-17.0.0.9999.ebuild b/dev-util/lldb/lldb-17.0.0.9999.ebuild
new file mode 100644
index 000000000000..985e9ba9d42f
--- /dev/null
+++ b/dev-util/lldb/lldb-17.0.0.9999.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit cmake llvm llvm.org python-single-r1
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0/${LLVM_SOABI}"
+KEYWORDS=""
+IUSE="debug +libedit lzma ncurses +python test +xml"
+RESTRICT="test"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	lzma? ( app-arch/xz-utils:= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	xml? ( dev-libs/libxml2:= )
+	~sys-devel/clang-${PV}
+	~sys-devel/llvm-${PV}
+"
+RDEPEND="
+	${DEPEND}
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/six[${PYTHON_USEDEP}]
+		')
+		${PYTHON_DEPS}
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/cmake-3.16
+	python? (
+		>=dev-lang/swig-3.0.11
+		$(python_gen_cond_dep '
+			dev-python/six[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		$(python_gen_cond_dep "
+			~dev-python/lit-${PV}[\${PYTHON_USEDEP}]
+			dev-python/psutil[\${PYTHON_USEDEP}]
+		")
+		sys-devel/lld
+	)
+"
+
+LLVM_COMPONENTS=( lldb cmake llvm/utils )
+LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support third-party )
+llvm.org_set_globals
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${LLVM_MAJOR} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
+	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
+
+	local mycmakeargs=(
+		-DLLDB_ENABLE_CURSES=$(usex ncurses)
+		-DLLDB_ENABLE_LIBEDIT=$(usex libedit)
+		-DLLDB_ENABLE_PYTHON=$(usex python)
+		-DLLDB_ENABLE_LUA=OFF
+		-DLLDB_ENABLE_LZMA=$(usex lzma)
+		-DLLDB_ENABLE_LIBXML2=$(usex xml)
+		-DLLDB_USE_SYSTEM_SIX=1
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		-DCLANG_LINK_CLANG_DYLIB=ON
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+
+		-DLLDB_EXTERNAL_CLANG_RESOURCE_DIR="${BROOT}/usr/lib/clang/${LLVM_MAJOR}"
+
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lldb-{shell,unit}
+	# failures + hangs
+	#use python && cmake_build check-lldb-api
+}
+
+src_install() {
+	cmake_src_install
+	find "${D}" -name '*.a' -delete || die
+
+	use python && python_optimize
+}