gentoo resync : 01.08.2021

2 files changed, 103 insertions, 0 deletions

diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index 79df85ac813a..11cd0a5aa448 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -7,4 +7,5 @@ EBUILD lldb-11.1.0.ebuild 2343 BLAKE2B 7ac5a408af2ac8e74f9ca3bc7e8ea636e394a325c
 EBUILD lldb-12.0.0.ebuild 2415 BLAKE2B 72591b9369461530face31022adfedb46c27e973a05c19c55dc33c580fda116b1e8f22df0b760cbdffafc60ccee438009c7bb1175fcbfd15cb9f55c0084c34f1 SHA512 abce2969538626084d680561ca85ece8fdb999fdf9ad41487e60f6fad62bd628ccebee369b56d394588403f7a6c3a2911ac4f699d0c51b284a6ffcbcd22dff22
 EBUILD lldb-12.0.1.ebuild 2420 BLAKE2B 8fd461752260d2e7d3cde1112863d43b0681d46ad129d36056b73b03c67b13c1263656e3577ab04ec729b70af167796991d20c91cfda5643fd63c898a3f2a993 SHA512 d14631da412a5e822f98ae6bc703e66383d848ace0d705363a4d0bf8e8f4f9126a1c7a472a4805b495b185d91098748d35a7a89f4047456904edb97735f5925c
 EBUILD lldb-13.0.0.9999.ebuild 2397 BLAKE2B c1eef59c390f1d068c0d3a88a7904de48c4d4eb11d0ac24f5da867f9b615f4fad80060c4bfb5476ebacf7d30101327e1a8f458f03b8f18bf142edd7fac1ca8e0 SHA512 cc2296e0d6dc7b5174cae77a10f3f1c175d31b3aaa122e64c96ba1f1f6e970adef1d545fa021f8338a3e18c256d60f67d150c176c3e268d0636d9ce17501703a
+EBUILD lldb-14.0.0.9999.ebuild 2397 BLAKE2B c1eef59c390f1d068c0d3a88a7904de48c4d4eb11d0ac24f5da867f9b615f4fad80060c4bfb5476ebacf7d30101327e1a8f458f03b8f18bf142edd7fac1ca8e0 SHA512 cc2296e0d6dc7b5174cae77a10f3f1c175d31b3aaa122e64c96ba1f1f6e970adef1d545fa021f8338a3e18c256d60f67d150c176c3e268d0636d9ce17501703a
 MISC metadata.xml 216 BLAKE2B fe5e49887842aa513fbf1f2e09bed09a884d531fd21bdaeb2d389e8bf590b6c0e7063f0af98f66e2db129308ab0f0804ba327c3c752bbb4c900c59ac109d99aa SHA512 3485598147c953e72e1785693a489a7e7d73d59620b76054db9c0ce95d8bfa0e8ffec29da7f7a9d73a32e5b77eac07ca3306c56a972dc57fd89d477edaebf3d5
diff --git a/dev-util/lldb/lldb-14.0.0.9999.ebuild b/dev-util/lldb/lldb-14.0.0.9999.ebuild
new file mode 100644
index 000000000000..468fe7b0cf61
--- /dev/null
+++ b/dev-util/lldb/lldb-14.0.0.9999.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake llvm llvm.org python-single-r1 toolchain-funcs
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="+libedit lzma ncurses +python test"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+RESTRICT="test"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	lzma? ( app-arch/xz-utils:= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/six[${PYTHON_USEDEP}]
+		')
+		${PYTHON_DEPS}
+	)
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/cmake-3.16
+	python? ( >=dev-lang/swig-3.0.11 )
+	test? (
+		$(python_gen_cond_dep "
+			~dev-python/lit-${PV}[\${PYTHON_USEDEP}]
+			dev-python/psutil[\${PYTHON_USEDEP}]
+		")
+		sys-devel/lld
+	)
+	${PYTHON_DEPS}"
+
+LLVM_COMPONENTS=( lldb )
+LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
+llvm.org_set_globals
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLDB_ENABLE_CURSES=$(usex ncurses)
+		-DLLDB_ENABLE_LIBEDIT=$(usex libedit)
+		-DLLDB_ENABLE_PYTHON=$(usex python)
+		-DLLDB_ENABLE_LZMA=$(usex lzma)
+		-DLLDB_USE_SYSTEM_SIX=1
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		-DCLANG_LINK_CLANG_DYLIB=ON
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+
+		-DLLDB_EXTERNAL_CLANG_RESOURCE_DIR="${BROOT}/usr/lib/clang/${PV%_*}"
+
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=$(usex test)
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lldb-lit
+	# failures + hangs
+	#use python && cmake_build check-lldb
+}
+
+src_install() {
+	cmake_src_install
+	find "${D}" -name '*.a' -delete || die
+
+	use python && python_optimize
+}