gentoo resync : 21.06.2020

2 files changed, 185 insertions, 0 deletions

diff --git a/dev-util/gnome-builder/Manifest b/dev-util/gnome-builder/Manifest
index 62aee8d78ffa..981ce2fc7189 100644
--- a/dev-util/gnome-builder/Manifest
+++ b/dev-util/gnome-builder/Manifest
@@ -2,5 +2,8 @@ AUX 3.34.1-optional-vala.patch 1249 BLAKE2B dcec506c976b6438cec14d941b911cdc11fe
 AUX libgit2-1.0-compat.patch 968 BLAKE2B c17cfba66245c6dd15973a094a89b5fe23493e2f83521c80c214b0ca9edde99fe8982ff73cc779de07b8a4fd548c8a85ca7570d2828299cf7b1e9e599ff9c5cf SHA512 da367d649bf14e1a4b8d0d59e446e6198939fc25f49484eb05d0f9195cd1136d098d581781e872e80f385996a7b043fd5756fea12fd24a931bece04b8ba3698a
 DIST gnome-builder-3.34.1-patchset.tar.xz 44680 BLAKE2B 91e91ac8d0fcf6b54d32ce9f1dc209ac22db790a29d724dad20e337fe1962f3d407b59e7f976f1e88277833849c962a470346bb5a308e39b637e6e9ca1dc2c2a SHA512 a114346b093976db227087743a7bbe2ca9523b64a67c95729bfeb7c3c346b3bfb4d02f5e11d36bbbaf506bc7a7f140883bdea7c78407243287bc400dfda43b57
 DIST gnome-builder-3.34.1.tar.xz 11974748 BLAKE2B c34a31c50b327d02632ff18d48ad59f925306901e8874e0c7811b9258c56027403de0d9dc1877c696d96037bdfcdcc27f56f59a41d232e47b330382b1dbf67e9 SHA512 886c732f20563818dcf1deb96d4277fe96a9499b999cfbc7a64286e816e9a36bb978932d36a1e764b54c2d36891b7546fa058f51e036b0fa101c0872f4ce51d8
+DIST gnome-builder-3.36.0-patchset.tar.xz 136856 BLAKE2B a482f371313af4ef6a0881968846c4543d169b6bd36942ae4b72d493012d73c9705e4a7acc8f7dfc1e8cbcdeb2445b4e225f39c3a9a219e24b90be773c0768c1 SHA512 ebaec56950e0e45ba2851b13d4e1518163a291dca207bba25efe12eaaa3cd69e9bae06d2f4e5b9e9852a4305fc3933764ec9a882843f84ce58bd2246991d16fd
+DIST gnome-builder-3.36.0.tar.xz 12015980 BLAKE2B 1724c7b17e58fea08cd22894eb260236419f215c1b68d396359ce40432e8a0c08d0ead2b70e888cbb767f78362d4253395b98821fb1d1ff9a07d5881df88c8e3 SHA512 ccd6ca916ed6ad10b69e5573482e2ea48cf4227d858605825ab56989840ebbf5a6dfafc915a1f8df3a1061b37c80adfbd03fc9d616c67e08a5032069b11aa4a6
 EBUILD gnome-builder-3.34.1-r1.ebuild 7372 BLAKE2B a60c1261ab7251f3a0cfff69538f0f92bb8a197d2624e3aa62703b9e6b808e3c0793a048a61ff0b409c51c1f6467ca0f5df7d513a825103bbb4c71263fb0bd2b SHA512 e1fcba969d1a9ab368775a80cc7a0ebe35e76a11cd78d49509a2837ab5efd045f9cf1e058397ab943bcdce4eb99e71baea8d2c72f398baeca8500f40dca28bca
+EBUILD gnome-builder-3.36.0.ebuild 6904 BLAKE2B 53f8cc1b0aa6fb85a0fa208b45c68c932c264c477c256c095fdab539567a1ca5db7bc1ed81a97be58c59551902c64b0792165d0cd180b521a5bae62fb8d7d6ef SHA512 eb9469f65d67b9e582ee341a137bc1eceef75c9b37898e0d1c3c47012227f63af0bdae7f57192705fcdfb009d751f522e5e4f89752d72ef75fafd16296a98033
 MISC metadata.xml 1085 BLAKE2B 0b2bdcfec562b85e54880c819a0345c2aedf4f8b1c0bc34b7b4e3e8551697dcbb3ed93da1e016f3a164bb677459e8d628ba943252e51e842152282c3757f0232 SHA512 58890d32c2d04d63eaae8489ea68054ffc50df5bf9970af6b159b2dfbc99b8ed2d2db80aa29907463c137caf5eb8aa129c1470d1e19ccbf398ff8789f7f63987
diff --git a/dev-util/gnome-builder/gnome-builder-3.36.0.ebuild b/dev-util/gnome-builder/gnome-builder-3.36.0.ebuild
new file mode 100644
index 000000000000..af7182a070d1
--- /dev/null
+++ b/dev-util/gnome-builder/gnome-builder-3.36.0.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISABLE_AUTOFORMATTING=1
+FORCE_PRINT_ELOG=1
+
+inherit gnome.org gnome2-utils llvm meson python-single-r1 readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="An IDE for writing GNOME-based software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+# FIXME: Review licenses at some point
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clang +devhelp doc +git +glade gtk-doc spell sysprof test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# When bumping, pay attention to all the included plugins/*/meson.build (and other) build files and the requirements within.
+# `grep -rI dependency * --include='meson.build'` can give a good initial idea for external deps and their double checking.
+# The listed RDEPEND order shold roughly match that output as well, with toplevel one first then sorted by file path.
+# Most plugins have no extra requirements and default to enabled; we need to handle the ones with extra requirements. Many of
+# them have optional runtime dependencies, for which we try to at least notify the user via DOC_CONTENTS (but not all small
+# things); `grep -rI -e 'command-pattern.*=' -e 'push_arg'` can give a (spammy) idea, plus python imports in try/except.
+
+# FIXME: plugin_flatpak needs flatpak.pc >=0.8.0, ostree-1, libsoup-2.4.pc >=2.52.0 and git plugin enabled
+# Editorconfig needs old pcre, with vte migrating away, might want it optional or ported to pcre2?
+# An introspection USE flag of a dep is required if any introspection based language plugin wants to use it (grep for gi.repository). Last full check at 3.28.4
+
+# TODO: Handle llvm slots via llvm.eclass; see plugins/clang/meson.build
+RDEPEND="
+	>=dev-libs/libdazzle-3.33.90[introspection]
+	>=dev-libs/glib-2.61.2:2
+	>=x11-libs/gtk+-3.22.26:3[introspection]
+	>=x11-libs/gtksourceview-4.0.0:4[introspection]
+	>=dev-libs/json-glib-1.2.0
+	>=dev-libs/jsonrpc-glib-3.19.91
+	>=x11-libs/pango-1.38.0
+	>=dev-libs/libpeas-1.22.0[python,${PYTHON_SINGLE_USEDEP}]
+	>=dev-libs/template-glib-3.28.0[introspection]
+	>=x11-libs/vte-0.40.2:2.91[introspection]
+	>=net-libs/webkit-gtk-2.12.0:4=[introspection]
+	>=dev-libs/libxml2-2.9.0
+	git? ( dev-libs/libgit2[ssh,threads]
+		>=dev-libs/libgit2-glib-0.28.0.1[ssh]
+	)
+	dev-libs/libpcre:3
+	dev-libs/libpcre2
+
+	>=dev-libs/gobject-introspection-1.54.0:=
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.22.0:3[${PYTHON_USEDEP}]
+	')
+	${PYTHON_DEPS}
+	clang? ( sys-devel/clang:= )
+	devhelp? ( >=dev-util/devhelp-3.25.1:= )
+	glade? ( >=dev-util/glade-3.22.0:3.10 )
+	spell? ( >=app-text/gspell-1.8:0=
+		app-text/enchant:2 )
+	>=dev-util/sysprof-capture-3.33.1:3
+	sysprof? ( >=dev-util/sysprof-3.33.4:0/3[gtk] )
+"
+DEPEND="${RDEPEND}"
+# TODO: runtime ctags path finding..
+
+# desktop-file-utils required for tests, but we have it in deptree for xdg update-desktop-database anyway, so be explicit and unconditional
+# appstream-glib needed for validation with appstream-util with FEATURES=test
+BDEPEND="
+	doc? ( $(python_gen_cond_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	') )
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	test? (
+		dev-libs/appstream-glib
+		sys-apps/dbus )
+	dev-util/desktop-file-utils
+	dev-util/glib-utils
+	>=dev-util/meson-0.49.2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
+extra capabilities beyond these expressed via USE flags. Some of these
+that are currently available with packages include:
+
+* dev-util/uncrustify and dev-python/autopep8 for various Code Beautifier
+  plugin out of the box functionality.
+* dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
+  C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
+  highlighting and symbol resolving support.
+* dev-python/jedi and dev-python/lxml for more accurate Python
+  autocompletion support.
+* dev-util/valgrind for integration with valgrind.
+* dev-util/meson for integration with the Meson build system.
+* dev-util/cargo for integration with the Rust Cargo build system.
+* dev-util/cmake for integration with the CMake build system.
+* net-libs/nodejs[npm] for integration with the NPM package system.
+'
+# FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
+# eslint for additional diagnostics in JavaScript files (what package has this? At least something via NPM..)
+# jhbuild support
+# rust language server via rls; Go via go-langserver
+# autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
+# gjs/gettext/mono/PHPize stuff, but most of these are probably installed for other reasons anyways, when needed inside IDE
+# stylelint for stylesheet (CSS and co) linting
+# gvls for vala language-server integration
+
+PATCHES=(
+	"${WORKDIR}/patches" # gnome-builder-3-36 branch 2020-06-17 (commit f9a82f62ce6c8)
+)
+
+llvm_check_deps() {
+	has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	use clang && llvm_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dtracing=false
+		-Dprofiling=false # not passing -pg to CFLAGS
+		-Dtcmalloc=false
+		-Dchannel=other
+
+		$(meson_use doc help)
+		$(meson_use gtk-doc docs)
+
+		-Dnetwork_tests=false
+		$(meson_use clang plugin_clang)
+		$(meson_use devhelp plugin_devhelp)
+		-Dplugin_deviced=false
+		-Dplugin_editorconfig=true # needs libpcre
+		-Dplugin_flatpak=false
+		$(meson_use git plugin_git)
+		$(meson_use glade plugin_glade)
+		-Dplugin_podman=false
+		$(meson_use spell plugin_spellcheck)
+		$(meson_use sysprof plugin_sysprof)
+		-Dplugin_update_manager=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	if use doc; then
+		rm "${ED}"/usr/share/doc/gnome-builder/en/.buildinfo || die
+		rm "${ED}"/usr/share/doc/gnome-builder/en/objects.inv || die
+		rm -r "${ED}"/usr/share/doc/gnome-builder/en/.doctrees || die
+		# custom docdir in build system, blocked by https://github.com/mesonbuild/meson/issues/825
+		mv "${ED}"/usr/share/doc/gnome-builder/en "${ED}"/usr/share/doc/${PF}/html || die
+		# _sources subdir left in on purpose, as HTML links to the rst files as "View page source". Additionally default docompress exclusion of /html/ already ensures they aren't compressed, thus linkable as-is.
+		rmdir "${ED}"/usr/share/doc/gnome-builder/ || die
+	fi
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
+
+src_test() {
+	# FIXME: can't run meson_src_test together with virtx or dbus-run-session
+	virtx dbus-run-session meson test -C "${BUILD_DIR}"
+}