gentoo resync : 18.11.2018

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-util/drone/drone-0.8.9.ebuild b/dev-util/drone/drone-0.8.9.ebuild
new file mode 100644
index 000000000000..c39a14f61765
--- /dev/null
+++ b/dev-util/drone/drone-0.8.9.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGO_PN="github.com/drone/drone"
+EGIT_COMMIT="768ed784bd74b0e0c2d8d49c4c8b6dca99b25e96"
+EGO_VENDOR=( "github.com/drone/drone-ui e7597b5234814a2c2f2a7f489b631a76649c335a"
+	"github.com/golang/protobuf aa810b61a9c79d51363740d207bb46cf8e620ed5"
+	"golang.org/x/net 9b4f9f5ad5197c79fd623a3638e70d8b26cef344 github.com/golang/net"
+	)
+
+inherit golang-build golang-vcs-snapshot user
+
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="A Continuous Delivery platform built on Docker, written in Go"
+HOMEPAGE="https://github.com/drone/drone"
+SRC_URI="${ARCHIVE_URI}
+	${EGO_VENDOR_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-go/go-bindata
+	dev-go/go-bindata-assetfs:="
+
+RESTRICT="test"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/drone ${PN}
+}
+
+src_compile() {
+	pushd src || die
+	GOPATH="${WORKDIR}/${P}:$(get_golibdir_gopath)" go build -v -ldflags "-extldflags '-static' -X github.com/drone/drone/version.VersionDev=build.${PV}.${EGIT_COMMIT:0:7}" -o release/drone-server ${EGO_PN}/cmd/drone-server || die
+	GOPATH="${WORKDIR}/${P}" go build -v -ldflags "-X github.com/drone/drone/version.VersionDev=build.${PV}.${EGIT_COMMIT:0:7}" -o release/drone-agent ${EGO_PN}/cmd/drone-agent || die
+	popd || die
+}
+
+src_install() {
+	dobin src/release/drone-{agent,server}
+	dodoc src/github.com/drone/drone/README.md
+	keepdir /var/log/drone /var/lib/drone
+	fowners -R ${PN}:${PN} /var/log/drone /var/lib/drone
+	newinitd "${FILESDIR}"/drone-server.initd drone-server
+	newconfd "${FILESDIR}"/drone-server.confd drone-server
+	newinitd "${FILESDIR}"/drone-agent.initd drone-agent
+	newconfd "${FILESDIR}"/drone-agent.confd drone-agent
+}