reinit the tree, so we can have metadata

3 files changed, 109 insertions, 0 deletions

diff --git a/dev-util/distro-info/Manifest b/dev-util/distro-info/Manifest
new file mode 100644
index 000000000000..57ce5d24d849
--- /dev/null
+++ b/dev-util/distro-info/Manifest
@@ -0,0 +1,4 @@
+DIST distro-info_0.14.tar.xz 26460 SHA256 73b7912107157cdad96a52b10a050292c9bdb049c52fb3a70b6dbf21a4965204 SHA512 aa0055f21523e30fc7e9c94c92f87cbd05fc5d082ddc109d092e94dabafac7533ced984197797252eb698232b3d8f512b3c345ed6abef0ae074bf2770224955e WHIRLPOOL 166cc73ad6fecf35ef422a4ff842030f5769ecfa8a247aec199c1886c8b310aba8ce7b39da93aabc92a975673100def1b9d37ea6a822f8ecf47c66c3d062ca91
+EBUILD distro-info-0.14.ebuild 1918 SHA256 64a4c9b3675202d0fd4ec9732b8d1380ace41e8a54bcec220b75f25bbbbc77c1 SHA512 4326d6dec91095416d8c674e409111aed71449f41a9db75ab17561a31786573648b0433531589cf68fa9c058a71f2820f2dda2c833f8c3e215478cb99d4044b3 WHIRLPOOL 6addc08b0a37c73cc0808ad127add3e697edf792f67d4bc751b76e3b4cb1b5f0f361e5d7c0d2b05a8ceec6656e9f4b6bfd7b50db6987447fe1e7dbba2ae5ea46
+MISC ChangeLog 636 SHA256 c0326197eaaedaf2e9eada95bcec36d2df1a48ccfbc9d0a3e3c60927f1e9647f SHA512 48b0a615b9d64b344e5fa5697169a4754972ab93f6af1bd4a1e2135a87aafbaf6340d21ebc52c5b13402d9ef0949caf19eab394f0d1e2596f9f81f4739c15035 WHIRLPOOL e41b2c1862b9c23db442e3bd0f2ecd5e532988f5e3a18bc8d098299677b179a039b06d8b19f4a51b8f51b3a92ced7fdbcac3420cdd51450ac12c0c4676877557
+MISC metadata.xml 367 SHA256 a6532d9789a502b07fbf191f834bc47f985cfdfbc958ceef56d2f8771015ef90 SHA512 3eb0be47e7eb6bfb6d8eecee66a25183da436c38272e226e7819c8748774f3aae620eab7227414cb862734d4baf8fa060290c1b2371233141abcffd7b489c7b8 WHIRLPOOL 50d7cf1180badf8d37fc470d42c4e0ea7bfed8d6b73e0c058b8f743f0fc8966e48fe6cfdbd2aa862ca76b0ef88cff0c20db679a0395934abc1cb97e7e99d6c71
diff --git a/dev-util/distro-info/distro-info-0.14.ebuild b/dev-util/distro-info/distro-info-0.14.ebuild
new file mode 100644
index 000000000000..ebcfaf5ea72f
--- /dev/null
+++ b/dev-util/distro-info/distro-info-0.14.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+DISTUTILS_OPTIONAL=true
+
+inherit distutils-r1
+
+DESCRIPTION="Provides information about the Debian distributions' releases"
+HOMEPAGE="https://debian.org"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="python test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+CDEPEND="dev-lang/perl:=
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${CDEPEND}
+	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+	test? (
+		dev-util/shunit2
+		dev-python/pylint[${PYTHON_USEDEP}]
+	)"
+RDEPEND="${CDEPEND}
+	dev-util/distro-info-data"
+
+src_prepare() {
+	default
+
+	# 1. Gentoo do not provides dpkg vendor information
+	# 2. Strip *FLAGS
+	# 3. Strip predefined CFLAGS
+	# 4. Point to correct perl's vendorlib
+	# 5. Remove python tests - python eclass will be used instead
+	sed -e "/cd python && python/d" \
+		-e "/VENDOR/d" \
+		-e "/dpkg-buildflags/d" \
+		-e "s/-g -O2//g" \
+		-e "s:\$(PREFIX)/share/perl5/Debian:\$(PERL_VENDORLIB)/Debian:g" \
+		-e "/pyversions/d" \
+		-i "${S}"/Makefile || die
+}
+
+src_configure() {
+	default
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_configure
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	emake PERL_VENDORLIB=$(perl -e 'require Config; print "$Config::Config{'vendorlib'}\n";') \
+		DESTDIR="${D}" install
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+}
+
+src_test() {
+	TZ=UTC default
+
+	if use python; then
+		python_test() {
+			esetup.py test
+		}
+
+		pushd ./python > /dev/null || die
+		distutils-r1_src_test
+		popd > /dev/null || die
+	fi
+}
diff --git a/dev-util/distro-info/metadata.xml b/dev-util/distro-info/metadata.xml
new file mode 100644
index 000000000000..425c7b2eae49
--- /dev/null
+++ b/dev-util/distro-info/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ykonotopov@gnome.org</email>
+		<name>Yuri Konotopov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+</pkgmetadata>