gentoo auto-resync : 02:09:2023 - 16:16:36

2 files changed, 128 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 2be40ea6ce33..ed43a6301b87 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,5 @@
 DIST diffoscope-247.tar.bz2 3091118 BLAKE2B cb41b98d439c123b5ee5f458d635f08afebde1dad724f53a8227826a509bca5e94204855fcd4f220567552abc0a3ea93e1c4a6e16dea0ed32ce7587c15d4976c SHA512 ceaa55512373e9283e6a18a9c5c814cd5b3ee8a9e9721f69b924ee55644640ea28302029232a310fca4d92e53fb37886d3d5ce2c6b577742261c86df24f52740
+DIST diffoscope-249.tar.bz2 3093688 BLAKE2B 8b74748a850c86a39e65b42538372af4c2cda50581f991f5e9afa8a4e69c76de11d9ba94f7a4e41e4ea5a550148587f4e711335139fb0ba53c3e0987ac6f0752 SHA512 7150e308560f08b1d2e0a90472e27a6b4f3497606ef6c1c0ef2dccfa9bcb1fef1e0b0cf4052c72896d5df4cd1c9bf6755d8a4f537f2b433abf71b61bb687ed6d
 EBUILD diffoscope-247.ebuild 4035 BLAKE2B 95aac565c6f708ea5738484b9e1e272eff126c36b9a06e20cf7a67db66993bcd27de9d3fd06c3fb3d68bd12e3b4ad38b0a6d91e51a48301f1f171484ee37d9dd SHA512 3cc46b1b638d6f9ead72e354dccd4c4f19284e4f730b808111b77a2849f899f5845e1cde5e8fcac106f298092caf6e58dd2bc04324d50e640d5a829b7b110db3
+EBUILD diffoscope-249.ebuild 4036 BLAKE2B b997b6c76b2783d696d5f57c36a4d33733033ab5f9d8b3a6387adf1dd23e2df6fa773d61e91fa56dac6225bb2c9ead0c69d26fa540bd6bca2dc1337ce16d5383 SHA512 4f2f5617dc12c7ad7c6fc7d24fd6aafba15f75a21a2e55a0abc2b5aa8eadf6f03e5875c519dfb676200704fb3dda0e2b4039888a844ceba91923d1b15e26bc69
 MISC metadata.xml 2078 BLAKE2B 3bb126836e45e8d4e5b6170a12219ec9cceb1a12dca4658211b1971cb16fa5593622642ade363904cf24df16de0749b957d0fc03838d2a9a004484d0b551c886 SHA512 382cefe0478282000b74e404cdd9d636a0323fceb55b97fd8545190628c319e0c5e213c7d082198e4b8b1fc693a52ce85c52b3ad831778e6fadbe6ba401782f5
diff --git a/dev-util/diffoscope/diffoscope-249.ebuild b/dev-util/diffoscope/diffoscope-249.ebuild
new file mode 100644
index 000000000000..b2232c7029e9
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-249.ebuild
@@ -0,0 +1,126 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+# No 3.12 yet as these two tests fail:
+# ERROR tests/comparators/test_elf.py::test_differences_with_dbgsym - TypeError: sequence item 1: expected str instance, bytes found
+# ERROR tests/comparators/test_elf.py::test_original_gnu_debuglink - TypeError: sequence item 1: expected str instance, bytes found
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence of filemagic's magic.py breaks imports
+# of dev-python/python-magic: bug #716482
+RDEPEND+=" !dev-python/filemagic"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	#tests/comparators/test_macho.py::test_llvm_diff
+	#tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest