reinit the tree, so we can have metadata

4 files changed, 125 insertions, 0 deletions

diff --git a/dev-util/cunit/Manifest b/dev-util/cunit/Manifest
new file mode 100644
index 000000000000..4d9dfbc98e65
--- /dev/null
+++ b/dev-util/cunit/Manifest
@@ -0,0 +1,7 @@
+DIST CUnit-2.1-2-src.tar.bz2 349037 SHA256 1f705f30b36fe1dadb5494989d1d663241603f456b468c81f606a1bdbc168bea SHA512 c0af37b9f3a00fd7bb971f33e94373699d0380c28fad12f6db860739990a9ffffe0bb0a71c0e3531529b9952128c11248b8f365875d0315c16637a0b7e91642d WHIRLPOOL a5617aa10baf617e7165c04c66e4fffb25d2d8d396d8aff8ed5f67183154d79514d2c426c88bc02d02440f4c53bbe2b6025bbd0165fa3a6008e2b19e0317498b
+DIST CUnit-2.1-3.tar.bz2 514500 SHA256 f5b29137f845bb08b77ec60584fdb728b4e58f1023e6f249a464efa49a40f214 SHA512 547b417109332446dfab8fda17bf4ccd2da841dc93f824dc90a20635bcf1fb80fb2176500d8a0906940f3f3d3e2f77b2d70a71090c9ab84ad9af43f3582bc487 WHIRLPOOL 621af4703fcaee5a222a55d735ac252ceed61dffa1d3d57e235ca952c13edfcd2d3dd3ef62623af40c57ae1e225868b8148d8268254fa724ddf936c85e4eadfa
+EBUILD cunit-2.1_p2-r1.ebuild 1374 SHA256 48714a8b2d2d3b8a052f99e395e1deb253e12f79b1c52c1d52a8cddb1bcb4754 SHA512 68bce364c4a817e0f16c84b9aebc26119c1ea078af1b42e95327898629d78278292d5cfb966a3a3c9b83ce077b2a5629107f7a294e00f746950f00c4663340d2 WHIRLPOOL fe839ae2ea42a2d7386db15ef7c7be18e3d2fbc9e3fc516f0c78059c52abcf136edc1daececda8ca24a8c801c666b01ad52c9e7fea12d296fe69ceb63d8146a4
+EBUILD cunit-2.1_p3.ebuild 1384 SHA256 50048fe1f7caaf4a0cd36a3c53d76e40be004f05463d790bd4675570c0df75de SHA512 62a6c3d04d65a41fdb3f9546c0455666411674548d63335be1e427f56471647dc5e956d26ca7116370dca804ddf8dc1e6fc301c7c40017a36c644a324805428a WHIRLPOOL b5a8033ff5b9a4698c5d97d6791bb28e13c1f63878f6b532597437c07f16c8314abf02a35679f9a157269e3eedf2d7587402a425d5cc7ceaec39626f02d38544
+MISC ChangeLog 2889 SHA256 b12a260c109547774c1b3881ffe6a1313d04f5d7b4b3c9bc9c2275f2d9614a56 SHA512 dcb9b853b97a2dcea35baa15e0bb33902e632da5f92469cedd4d96124e91a26dfe8bf2ef760ce5d7ab429f84950082b3f75b90c9e108fa5b27a132831c1be3fe WHIRLPOOL 87535be1851b164bd1c81ef0880ec0a0dc85820e230e0e78ad40d348e67cf50f267618b5e6109b07a074d44f13b3e5fb84e1c7693c055019f55f7b0e370210cf
+MISC ChangeLog-2015 6279 SHA256 f6279ba03e385c237c97c702ea890fd0b254c7982af146740cb145b633652eb0 SHA512 915b0a9c67ee50bbc01d119080e33df5f22f8b4a006ee7f83d750347e537a733872398a7e63939943dd3f43961c018cd5dad191b08045cbbedf3a207c950ebdf WHIRLPOOL 308088324044f4bd17fbf7fec2f4af8529617aa59f86308b0c76d85da65d3aa3f79993ad694e3cc34d17181ec83d0fa26e47ac5a2ea4ffbd865b772363c5c6b0
+MISC metadata.xml 242 SHA256 92ac1b0351dbb1d815d4fe2d850f407d4dec4a1ebd1a0be9f09bd2451d44d05b SHA512 3171a680f18023cbeeb73331a33942ddf076e0b8abc2c40284e4a4cb1803ad7264f8e38ffaf182d1f38ba28ad60e65a0ddf96c66a60e0f9a935aa941c49df87d WHIRLPOOL 20367f735f455bd6eb1345b5761647a27046914775eeee621359c159397ecafc4bbe323d5118bf2c8b5f1090d152755a1ee3d7530ba110eac2bd03f2b33942f3
diff --git a/dev-util/cunit/cunit-2.1_p2-r1.ebuild b/dev-util/cunit/cunit-2.1_p2-r1.ebuild
new file mode 100644
index 000000000000..1522a3e14122
--- /dev/null
+++ b/dev-util/cunit/cunit-2.1_p2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit autotools eutils flag-o-matic multilib-minimal toolchain-funcs
+
+MY_PN='CUnit'
+MY_PV="${PV/_p*}-2"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="CUnit - C Unit Test Framework"
+SRC_URI="mirror://sourceforge/cunit/${MY_P}-src.tar.bz2"
+HOMEPAGE="http://cunit.sourceforge.net"
+
+SLOT="0"
+LICENSE="LGPL-2"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="ncurses static-libs"
+
+RDEPEND="ncurses? ( >=sys-libs/ncurses-5.9-r3[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS NEWS README ChangeLog )
+
+src_prepare() {
+	sed -e "/^docdir/d" -i doc/Makefile.am || die
+	sed -e '/^dochdrdir/{s:$(prefix)/doc/@PACKAGE@:$(docdir):}' \
+		-i doc/headers/Makefile.am || die
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
+	eautoreconf
+
+	append-cppflags -D_BSD_SOURCE
+
+	# unable to find headers otherwise
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local LIBS=${LIBS}
+	append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
+
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable static-libs static) \
+		--disable-debug \
+		$(use_enable ncurses curses)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
diff --git a/dev-util/cunit/cunit-2.1_p3.ebuild b/dev-util/cunit/cunit-2.1_p3.ebuild
new file mode 100644
index 000000000000..297393113af6
--- /dev/null
+++ b/dev-util/cunit/cunit-2.1_p3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils flag-o-matic multilib-minimal toolchain-funcs
+
+MY_PN="CUnit"
+MY_PV="${PV/_p*}-3"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="C Unit Test Framework"
+SRC_URI="mirror://sourceforge/cunit/${MY_P}.tar.bz2"
+HOMEPAGE="http://cunit.sourceforge.net"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="ncurses static-libs"
+
+RDEPEND="ncurses? ( >=sys-libs/ncurses-5.9-r3:0=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS NEWS README ChangeLog )
+
+src_prepare() {
+	default
+
+	sed -e "/^docdir/d" -i doc/Makefile.am || die
+	sed -e '/^dochdrdir/{s:$(prefix)/doc/@PACKAGE@:$(docdir):}' \
+		-i doc/headers/Makefile.am || die
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
+	eautoreconf
+
+	append-cppflags -D_BSD_SOURCE
+
+	# unable to find headers otherwise
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local LIBS=${LIBS}
+	append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
+
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable static-libs static) \
+		--disable-debug \
+		$(use_enable ncurses curses)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
diff --git a/dev-util/cunit/metadata.xml b/dev-util/cunit/metadata.xml
new file mode 100644
index 000000000000..4d2f287374f8
--- /dev/null
+++ b/dev-util/cunit/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+	<upstream>
+		<remote-id type="sourceforge">cunit</remote-id>
+	</upstream>
+</pkgmetadata>