gentoo resync : 14.07.2018

6 files changed, 259 insertions, 0 deletions

diff --git a/dev-util/codeblocks/Manifest b/dev-util/codeblocks/Manifest
new file mode 100644
index 000000000000..187f5c15dce4
--- /dev/null
+++ b/dev-util/codeblocks/Manifest
@@ -0,0 +1,7 @@
+AUX codeblocks-17.12-nodebug.diff 611 BLAKE2B 03de6a604b0971e7b91702fd9a1f66aee6d87538177947762ce7b112bf6e81e75349c76415f1a18ac4ee0b41fa4f1257085af1031988c3346a45402b7bfebe73 SHA512 d5332803a0d9cbcbcafa5fa18d90bea07ff43d8ff93922d577b3b2dddc6349a7b01c9100f6198905d531e31edd0f5ba0b5a88db38df981c567644f8e7e11022a
+DIST codeblocks-17.12-fortran.tar.xz 3048 BLAKE2B 58fd3b95cea3303a41da31f5cffe08698fa51ff896c456224edd63d17ddfe8dd54b0c058bd2a68920cf15789bfe5e412054e4e603b1d644034d8cb43d3de3224 SHA512 78534706b6433ae93b680740b2e6c0b747119f6ac62477b901ceeb1900692465615e29f2837ceca48d127181fc6b653d6d49a85fdb8d2fb873ad5a915527936c
+DIST codeblocks_17.12.tar.xz 15725976 BLAKE2B 871427b5d8a2296e04d640c35d9129deebf1bb35cd1573652099c02ad4495c4c1369ed382ba714848d6bd75304195a25f6a91bece398bedaffbee8ae3547c46b SHA512 f90e756ca6f532656eeed34c6259c6a96ae85d172fc11e39f696ded9189cab7171d0cead18524fbab50dd782f21adbc7d52e2ea90535a3ed0aef5946b8a476e1
+EBUILD codeblocks-17.12-r300.ebuild 2014 BLAKE2B 6b99be334575d995d4537c192b90785c3628a6ee0c377957519d200ae7a931bea5e0ebd2cabed7d0fde9808bea95795d0fbd85c3417999197800db57c70be329 SHA512 a6bcd96a13095c3e31357d94cdd76fba0f7161120261750edbffd81b243b9323f089bb91a4929f317e79fde85c7579ef72fe5dcbd241a0cc7eef6dd385599b83
+EBUILD codeblocks-17.12.ebuild 2009 BLAKE2B a2266b73e5b75e95173240f01929146cb81d9313c570589899142c4631660bf214384fdbb73522bca1bf33d7a40cc0217eb5beb78d1b1998bf2e483ace970bdb SHA512 43d790abbd465566cf5aa18ca86133e7835c51643a570d23b43ac8df74e74a764079077e1e40c1a7b5d30c19d28cf4f9377f6b689f5618bac4e9e8539b57d132
+EBUILD codeblocks-9999.ebuild 1249 BLAKE2B 143412cd2c6b0652612cbb89e0385803ccadfd34fda6df4a0bbf8a4628f5dfedc5480f890b57e814778768cfe7b728fddd0e8119086c61b0a1b5b6433cd5d053 SHA512 f2d31b7ef1d77d92d388c9a2c89114d14cc0c5bd7e1e29f120cf9ad12bd43d14d04adacd0f63e0bdc340c2b229477a41f43cd36f0e489a8e85a1f0601338808d
+MISC metadata.xml 673 BLAKE2B 2868f0b98e33bfa54b217038a440d01d7f289093a6d31873b33f9eb3570c9f83c57476d2aaeabfbbdc180ec00fbdb300ec68cbb45ee95ddf99b3ddf7e92681f6 SHA512 54996828105be8435499880af88e1bb48eb746787f4838e691ddf740c86c3ca84a09973a9925ff160308ba1a28a5e746f58d2d1b646f922a2949368dc3a016fc
diff --git a/dev-util/codeblocks/codeblocks-17.12-r300.ebuild b/dev-util/codeblocks/codeblocks-17.12-r300.ebuild
new file mode 100644
index 000000000000..3b627ef7a238
--- /dev/null
+++ b/dev-util/codeblocks/codeblocks-17.12-r300.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WX_GTK_VER="3.0-gtk3"
+
+inherit autotools flag-o-matic gnome2-utils wxwidgets xdg-utils
+
+DESCRIPTION="The open source, cross platform, free C++ IDE"
+HOMEPAGE="http://www.codeblocks.org/"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+SRC_URI="mirror://sourceforge/${PN}/${P/-/_}.tar.xz https://dev.gentoo.org/~leio/distfiles/${P}-fortran.tar.xz"
+
+# USE="fortran" enables FortranProject plugin (v1.5)
+# that is delivered with Code::Blocks 17.12 source code.
+# https://sourceforge.net/projects/fortranproject
+# http://cbfortran.sourceforge.net
+
+IUSE="contrib debug fortran pch"
+
+RDEPEND="app-arch/zip
+	x11-libs/wxGTK:${WX_GTK_VER}[X]
+	contrib? (
+		app-text/hunspell
+		dev-libs/boost:=
+		dev-libs/libgamin
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/codeblocks-17.12-nodebug.diff
+	"${WORKDIR}"/patches/
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	setup-wxwidgets
+
+	append-cxxflags $(test-flags-CXX -fno-delete-null-pointer-checks)
+
+	# USE="contrib -fortran" setup:
+	use fortran || CONF_WITH_LST=$(use_with contrib contrib-plugins all,-FortranProject)
+	# USE="contrib fortran" setup:
+	use fortran && CONF_WITH_LST=$(use_with contrib contrib-plugins all)
+	# USE="-contrib fortran" setup:
+	use contrib || CONF_WITH_LST=$(use_with fortran contrib-plugins FortranProject)
+
+	econf \
+		--with-wx-config="${WX_CONFIG}" \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable pch) \
+		${CONF_WITH_LST}
+}
+
+pkg_postinst() {
+	if [[ ${WX_GTK_VER} == "3.0" || ${WX_GTK_VER} == "3.0-gtk3" ]]; then
+		elog "The symbols browser is disabled due to it causing crashes."
+		elog "For more information see https://sourceforge.net/p/codeblocks/tickets/225/"
+	fi
+
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
diff --git a/dev-util/codeblocks/codeblocks-17.12.ebuild b/dev-util/codeblocks/codeblocks-17.12.ebuild
new file mode 100644
index 000000000000..ed606b14c4af
--- /dev/null
+++ b/dev-util/codeblocks/codeblocks-17.12.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WX_GTK_VER="3.0"
+
+inherit autotools flag-o-matic gnome2-utils wxwidgets xdg-utils
+
+DESCRIPTION="The open source, cross platform, free C++ IDE"
+HOMEPAGE="http://www.codeblocks.org/"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+SRC_URI="mirror://sourceforge/${PN}/${P/-/_}.tar.xz https://dev.gentoo.org/~leio/distfiles/${P}-fortran.tar.xz"
+
+# USE="fortran" enables FortranProject plugin (v1.5)
+# that is delivered with Code::Blocks 17.12 source code.
+# https://sourceforge.net/projects/fortranproject
+# http://cbfortran.sourceforge.net
+
+IUSE="contrib debug fortran pch"
+
+RDEPEND="app-arch/zip
+	x11-libs/wxGTK:${WX_GTK_VER}[X]
+	contrib? (
+		app-text/hunspell
+		dev-libs/boost:=
+		dev-libs/libgamin
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/codeblocks-17.12-nodebug.diff
+	"${WORKDIR}"/patches/
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	setup-wxwidgets
+
+	append-cxxflags $(test-flags-CXX -fno-delete-null-pointer-checks)
+
+	# USE="contrib -fortran" setup:
+	use fortran || CONF_WITH_LST=$(use_with contrib contrib-plugins all,-FortranProject)
+	# USE="contrib fortran" setup:
+	use fortran && CONF_WITH_LST=$(use_with contrib contrib-plugins all)
+	# USE="-contrib fortran" setup:
+	use contrib || CONF_WITH_LST=$(use_with fortran contrib-plugins FortranProject)
+
+	econf \
+		--with-wx-config="${WX_CONFIG}" \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable pch) \
+		${CONF_WITH_LST}
+}
+
+pkg_postinst() {
+	if [[ ${WX_GTK_VER} == "3.0" || ${WX_GTK_VER} == "3.0-gtk3" ]]; then
+		elog "The symbols browser is disabled due to it causing crashes."
+		elog "For more information see https://sourceforge.net/p/codeblocks/tickets/225/"
+	fi
+
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
diff --git a/dev-util/codeblocks/codeblocks-9999.ebuild b/dev-util/codeblocks/codeblocks-9999.ebuild
new file mode 100644
index 000000000000..9296cc13443b
--- /dev/null
+++ b/dev-util/codeblocks/codeblocks-9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+WX_GTK_VER="3.0"
+
+inherit autotools eutils subversion wxwidgets
+
+DESCRIPTION="The open source, cross platform, free C++ IDE"
+HOMEPAGE="http://www.codeblocks.org/"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+SRC_URI=""
+ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}/code/trunk"
+
+IUSE="contrib debug pch static-libs"
+
+RDEPEND="app-arch/zip
+	x11-libs/wxGTK:${WX_GTK_VER}[X]
+	contrib? (
+		app-text/hunspell
+		dev-libs/boost:=
+		dev-libs/libgamin
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_unpack() {
+	subversion_src_unpack
+}
+
+src_prepare() {
+	# Let's make the autorevision work.
+	subversion_wc_info
+	CB_LCD=$(LC_ALL=C svn info "${ESVN_WC_PATH}" | grep "^Last Changed Date:" | cut -d" " -f4,5)
+	echo "m4_define([SVN_REV], ${ESVN_WC_REVISION})" > revision.m4
+	echo "m4_define([SVN_DATE], ${CB_LCD})" >> revision.m4
+	eautoreconf
+}
+
+src_configure() {
+	need-wxwidgets unicode
+	econf \
+		--with-wx-config="${WX_CONFIG}" \
+		$(use_enable debug) \
+		$(use_enable pch) \
+		$(use_enable static-libs static) \
+		$(use_with contrib contrib-plugins all)
+}
+
+src_compile() {
+	emake clean-zipfiles
+	emake
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
diff --git a/dev-util/codeblocks/files/codeblocks-17.12-nodebug.diff b/dev-util/codeblocks/files/codeblocks-17.12-nodebug.diff
new file mode 100644
index 000000000000..7cbb678dda6a
--- /dev/null
+++ b/dev-util/codeblocks/files/codeblocks-17.12-nodebug.diff
@@ -0,0 +1,13 @@
+# Remove adding of "-g" to CFLAGS and CXXFLAGS if "./configure --enable-debug"
+diff -Naur old/m4/acinclude.m4 new/m4/acinclude.m4
+--- old/m4/acinclude.m4	2017-11-01 02:32:37.000000000 +0300
++++ new/m4/acinclude.m4	2018-05-04 11:08:33.000000000 +0300
+@@ -91,8 +91,6 @@
+ AC_ARG_ENABLE(debug, [AC_HELP_STRING([--enable-debug], [turn on debugging (default is OFF)])],,
+                        enable_debug=$debug_default)
+     if test "x$enable_debug" = "xyes"; then
+-        CFLAGS="-g $CFLAGS"
+-        CXXFLAGS="-g $CXXFLAGS"
+         CPPFLAGS="-DDEBUG -DcbDEBUG $CPPFLAGS"
+         AC_MSG_RESULT(yes)
+     else
diff --git a/dev-util/codeblocks/metadata.xml b/dev-util/codeblocks/metadata.xml
new file mode 100644
index 000000000000..4d0690ce374b
--- /dev/null
+++ b/dev-util/codeblocks/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>torokhov_s_a@mail.ru</email>
+    <name>Sergey Torokhov</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>wxwidgets@gentoo.org</email>
+    <name>Gentoo wxWidgets Project</name>
+  </maintainer>
+  <use>
+    <flag name="contrib">Build additional contrib components</flag>
+    <flag name="fortran">Build FortranProject plugin which enables to use Code::Blocks IDE for Fortran language</flag>
+  </use>
+  <upstream>
+    <remote-id type="sourceforge">codeblocks</remote-id>
+  </upstream>
+</pkgmetadata>