gentoo resync : 21.06.2021

2 files changed, 202 insertions, 0 deletions

diff --git a/dev-util/buildbot/Manifest b/dev-util/buildbot/Manifest
index 106a5c46bfed..621445635ca6 100644
--- a/dev-util/buildbot/Manifest
+++ b/dev-util/buildbot/Manifest
@@ -12,6 +12,7 @@ DIST buildbot-2.8.4.tar.gz 3134447 BLAKE2B 67052a060c9951e584a5e94f36b92262b9a19
 DIST buildbot-3.0.2.tar.gz 2221373 BLAKE2B 7f7e08375f0eb6eb0187dc734f0eefda5bc24c9bdce543cc6d094d67a211e909bff93d3a956b57cb14e800c52b7f05a2f823173becac37bd0a52790dfe158e1a SHA512 137ac6fdb7e1b67542c0a5b1d5c4736ebf9b6b7ffd5a2c18795eeec3a132abcad972252baabbf585efc3ed4bb14e61d8552c4d21ceff9c71823cca42613c6f5b
 DIST buildbot-3.1.0.tar.gz 2229027 BLAKE2B 27eaed470f18c4fe8cae1730ca92918352518263a5cc7c3affea070dc3c9890e88db81e2f0d70b1071da89a4df7fd34091ac9dd08b8d6933e568365859640c4e SHA512 2eb08af4c59b5268fb9d5dd3e5c6c4889542c39b7034aee7bb6151d4e24ce99a9c0a83ec303ca4110a55e8f7daa562ddc0debee83499984a3d9fa0fad965740c
 DIST buildbot-3.1.1.tar.gz 2229124 BLAKE2B c384b897a5f8816b7d6a52070cb1cce7e9b70d41a5837990af3474d3063a4906600f82c1bc6e6c48d826ac1f95dc36dcc15ebca10c9249615d25f547e0216dad SHA512 4f4194fab83bb80cff15366fb6461624b75c5a2d0e473ac9cb6a8abb372ccd7ee9208a944f198d874e8cd1a87358239ba3e8314d54ef35a641ff83510c48de37
+DIST buildbot-3.2.0.tar.gz 2245261 BLAKE2B ccb1dc5e6a6bf5c9e06a7b05cc1baa605b09cf65ad4f9beff2a40e9f52a3065363960a990c288ed181cc5cc5cf5af1ce06dd4df561ddfe9819165ebe32760887 SHA512 5730126786880eb48da140cbbaaac2df95e6d04d22268fb305c1a228969bd096cd18959779f6101af73c41fecb07a7c1e2bb276271bede53989323a46fb06962
 EBUILD buildbot-2.10.0.ebuild 7097 BLAKE2B ec93bddfc15ff763693dfc1602e4e6687fd28b00aa2e69bce95ea37a7efeedc828958d55c2995e5b7f522909bc4894bf06f6133e14a108fcb1ca8823f304a7a1 SHA512 39e7cb03d27b32432d45637d3a976c49f4fc01f5ed8e2c104329acf52b2763bc3f5cba9dd86317f031b0bee654a80bd3b3a52a0b7407ce6e394821f2ff4d9a1b
 EBUILD buildbot-2.10.1.ebuild 7097 BLAKE2B ec93bddfc15ff763693dfc1602e4e6687fd28b00aa2e69bce95ea37a7efeedc828958d55c2995e5b7f522909bc4894bf06f6133e14a108fcb1ca8823f304a7a1 SHA512 39e7cb03d27b32432d45637d3a976c49f4fc01f5ed8e2c104329acf52b2763bc3f5cba9dd86317f031b0bee654a80bd3b3a52a0b7407ce6e394821f2ff4d9a1b
 EBUILD buildbot-2.8.2-r1.ebuild 7162 BLAKE2B d01e229b6927cd16b5b852db5758146e4a284e21a915459c140c023da215e5ab40da1cfb9a7f78baaa0d0c792cdd0bfd9caae5ccab408c6ca5caf70218a3bef5 SHA512 767eab00ef736e04bde1ca898b3f21224b89bc756175d1ca769bd947872fa90c204258d4a9dae4ec69bfd623e74533107c1ab14232940471e4901983039b6f37
@@ -19,5 +20,6 @@ EBUILD buildbot-2.8.4.ebuild 7225 BLAKE2B 2b549d7cb6e8e7d90356fc9d648a0dd466f049
 EBUILD buildbot-3.0.2.ebuild 7184 BLAKE2B 8b980199ed250d0675e3d99b93bc685466090841702af32277275e5a816d124d41636a6cb3ee319e8dd03c641f2880233b7bc9bb438b6f72b2008c99eb9c98a0 SHA512 6de57aec13afb5b5174851f25098b49d21a935244bde5960c2fc45c215fbacbc31816f485cec5fca6f2734241fe5eb5500effa8f06d0263d5a1428ac30a03e12
 EBUILD buildbot-3.1.0.ebuild 7229 BLAKE2B 4bb723ce898a5718529a171fa2391223b57b6713e0b20a44bd852f45aeac959367f4013d2bd59563a5b3d639f8ac8bbd57ecc4f4643cbbaf9953eba986fe0aff SHA512 d72650d98d9690d5012681eb78437030963987791d891eeaf80b444c5cde34148771d023d342fde63178f9cfc594bff1af3721911b7b6f1db518dd945857de57
 EBUILD buildbot-3.1.1.ebuild 7229 BLAKE2B 4bb723ce898a5718529a171fa2391223b57b6713e0b20a44bd852f45aeac959367f4013d2bd59563a5b3d639f8ac8bbd57ecc4f4643cbbaf9953eba986fe0aff SHA512 d72650d98d9690d5012681eb78437030963987791d891eeaf80b444c5cde34148771d023d342fde63178f9cfc594bff1af3721911b7b6f1db518dd945857de57
+EBUILD buildbot-3.2.0.ebuild 7158 BLAKE2B bd352fecf2ab837715d553304a48484a770b5e252d94159ab22cd29e402a55b73edaa1b18a14b3cb0ff8a8bcffbe086af2d07df29079e824cbb3b1bf2ff90ac5 SHA512 bb6127a7b9cd8e8aa5c49bed56fa5df61eee7ee7b524472deabb50083e89983a3decb8514b7917569b48398830fbc974a3468af4b14d058c3bef20f5357e985f
 EBUILD buildbot-9999.ebuild 7179 BLAKE2B b82966f31a9783597485fc92271a916762bb2bbcf2af5a5c1bfbf48e321b90d2e10b1a4e4575086454b194083f59402eb73bf859cf2ce3e641dfecfa29ea157a SHA512 e979841f2dd909452ec11cf6723d74728a2fcb8bf9b87bd2aeef3381674930dde15e23454622069fd482e65c6f7933a5087333ec3c2072195034621d053be8ad
 MISC metadata.xml 1359 BLAKE2B 33a6b0f21ad4255f28bc527fb18a384889eb34b2ddc5df5cfa03cc4b1960712b91c787706b95913154300b8e82a5879703dd90d0bf4d796cd6b8bb2a7c4b71cd SHA512 ded6f9cd25bef2df1431b71d5ffc9f0aa3efe9d2f7433cee7800fc27e1f6f76ad64cda9bbc4d3eb3fe0f44dbd7414c75b029f78307925dab5ed06df3d52d86e7
diff --git a/dev-util/buildbot/buildbot-3.2.0.ebuild b/dev-util/buildbot/buildbot-3.2.0.ebuild
new file mode 100644
index 000000000000..dfef67930503
--- /dev/null
+++ b/dev-util/buildbot/buildbot-3.2.0.ebuild
@@ -0,0 +1,200 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_REQ_USE="sqlite"
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+DISTUTILS_USE_SETUPTOOLS="rdepend"
+
+inherit readme.gentoo-r1 systemd distutils-r1
+
+MY_PV="${PV/_p/.post}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="BuildBot build automation system"
+HOMEPAGE="https://buildbot.net/ https://github.com/buildbot/buildbot https://pypi.org/project/buildbot/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~amd64-linux ~x86-linux"
+
+IUSE="crypt doc docker examples irc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/buildbot
+	>=dev-python/jinja-2.1[${PYTHON_USEDEP}]
+	>=dev-python/twisted-17.9.0[${PYTHON_USEDEP},crypt?]
+	>=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.2.0[${PYTHON_USEDEP}]
+	<dev-python/sqlalchemy-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-migrate-0.13[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+	>=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/unidiff[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.1.1[${PYTHON_USEDEP}]
+	~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+	)
+	irc? (
+		dev-python/txrequests[${PYTHON_USEDEP}]
+	)
+	docker? (
+		>=dev-python/docker-py-2.2.0[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	doc? (
+		>=dev-python/sphinx-3.2.0[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-blockdiag[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		dev-python/pyenchant[${PYTHON_USEDEP}]
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/sphinx-jinja[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/ldap3[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.12.48[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/pypugjs[${PYTHON_USEDEP}]
+		dev-python/txrequests[${PYTHON_USEDEP}]
+		dev-python/lz4[${PYTHON_USEDEP}]
+		dev-python/treq[${PYTHON_USEDEP}]
+		dev-python/setuptools_trial[${PYTHON_USEDEP}]
+		~dev-util/buildbot-pkg-${PV}[${PYTHON_USEDEP}]
+		~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
+		~dev-util/buildbot-www-${PV}[${PYTHON_USEDEP}]
+	)"
+
+S=${WORKDIR}/${MY_P}
+
+distutils_enable_tests setup.py
+
+pkg_setup() {
+	DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
+		to support starting buildbot through Gentoo's init system. To use this,
+		execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
+		The scripts can	run as a different user if desired."
+}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	# missing files, so skip building
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null || die
+		#'man' target is currently broken
+		emake html
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman docs/buildbot.1
+
+	if use doc; then
+		HTML_DOCS=( docs/_build/html/ )
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r docs/examples
+	fi
+
+	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
+	newinitd "${FILESDIR}/buildmaster.initd" buildmaster
+	systemd_dounit "${FILESDIR}/buildmaster.target"
+	systemd_newunit "${FILESDIR}/buildmaster_at.service" "buildmaster@.service"
+	systemd_install_serviced "${FILESDIR}/buildmaster_at.service.conf" "buildmaster@.service"
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	if [[ -n ${REPLACING_VERSIONS} ]]; then
+		ewarn
+		ewarn "Starting with buildbot-0.8.12-r2, more than one instance of buildmaster"
+		ewarn "can be run simultaneously. Note that \"BASEDIR\" in the buildbot configuration file"
+		ewarn "is now the common base directory for all instances. If you are migrating from an older"
+		ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
+		ewarn "The name of the subdirectory corresponds to the name of the buildmaster instance."
+		ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
+		ewarn "    ln --symbolic --relative /etc/init.d/buildmaster /etc/init.d/buildmaster.myinstance"
+		ewarn "    rc-update add buildmaster.myinstance default"
+		ewarn "    /etc/init.d/buildmaster.myinstance start"
+		ewarn "Systems using systemd can do the following:"
+		ewarn "    systemctl enable buildmaster@myinstance.service"
+		ewarn "    systemctl enable buildmaster.target"
+		ewarn "    systemctl start buildmaster.target"
+		elog
+		elog "Upstream recommends the following when upgrading:"
+		elog "Each time you install a new version of Buildbot, you should run the"
+		elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
+		elog "This will add files and fix (or at least detect) incompatibilities between"
+		elog "your old config and the new code."
+	fi
+	elog
+	elog "In order to create a new instance of buildmaster, execute:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_config() {
+	local buildmaster_path="/var/lib/buildmaster"
+	local log_path="/var/log/buildmaster"
+
+	einfo "This will prepare a new buildmaster instance in ${buildmaster_path}."
+	einfo "Press Control-C to abort."
+
+	einfo "Enter the name for the new instance: "
+	read instance_name
+	[[ -z "${instance_name}" ]] && die "Invalid instance name"
+
+	local instance_path="${buildmaster_path}/${instance_name}"
+	local instance_log_path="${log_path}/${instance_name}"
+
+	if [[ -e "${instance_path}" ]]; then
+		eerror "The instance with the specified name already exists:"
+		eerror "${instance_path}"
+		die "Instance already exists"
+	fi
+
+	local buildbot="/usr/bin/buildbot"
+	if [[ ! -d "${buildmaster_path}" ]]; then
+		mkdir --parents "${buildmaster_path}" || die "Unable to create directory ${buildmaster_path}"
+	fi
+	"${buildbot}" create-master "${instance_path}" &>/dev/null || die "Creating instance failed"
+	chown --recursive buildbot:buildbot "${instance_path}" || die "Setting permissions for instance failed"
+	mv "${instance_path}/master.cfg.sample" "${instance_path}/master.cfg" \
+		|| die "Moving sample configuration failed"
+	ln --symbolic --relative "/etc/init.d/buildmaster" "/etc/init.d/buildmaster.${instance_name}" \
+		|| die "Unable to create link to init file"
+
+	if [[ ! -d "${instance_log_path}" ]]; then
+		mkdir --parents "${instance_log_path}" || die "Unable to create directory ${instance_log_path}"
+		chown --recursive buildbot:buildbot "${instance_log_path}" \
+			|| die "Setting permissions for instance failed"
+	fi
+	ln --symbolic --relative "${instance_log_path}/twistd.log" "${instance_path}/twistd.log" \
+		|| die "Unable to create link to log file"
+
+	einfo "Successfully created a buildmaster instance at ${instance_path}."
+	einfo "To change the default settings edit the master.cfg file in this directory."
+}