gentoo auto-resync : 11:10:2024 - 04:04:14

5 files changed, 402 insertions, 0 deletions

diff --git a/dev-scheme/Manifest.gz b/dev-scheme/Manifest.gz
index 736e445f1afa..c99101de698f 100644
--- a/dev-scheme/Manifest.gz
+++ b/dev-scheme/Manifest.gz
diff --git a/dev-scheme/guile/Manifest b/dev-scheme/guile/Manifest
index 6d2f4ccfebcd..78ad1a27fae6 100644
--- a/dev-scheme/guile/Manifest
+++ b/dev-scheme/guile/Manifest
@@ -16,11 +16,14 @@ DIST guile-2.2.7.tar.xz 10881984 BLAKE2B e2b1fe7cb010371beaaf32f8f173397c90fd291
 DIST guile-3.0.10.tar.xz 5802280 BLAKE2B 2b41f1afb282eb4672f5aca5b044f47a12509745f5580fc4a621e7555c8b884f92dc76bc78fbdf8a64d59cf1de65b230ce03b0a34bbcb77307a7c9453a277ac6 SHA512 8b58e6c70cd48af85a0b346fcdf488fd5ac8d8678181c9c469895bf6ddab909c415e471776fdcda3c234e00fae80bdd4518c17ff16cf8107a36d2990a4face1d
 DIST guile-3.0.9.tar.xz 5750636 BLAKE2B 693f189bda52468d989f27c9482b515b8a14ed814d6e4a9a988d7a03d9789903a568b41c5e3ae524b3a51cc635693cd20245b2017efabb9774be59c298823083 SHA512 a1e47a60a654f26edc57b3a34d943e15a055fc85c3cc764e912be23a80d56534b16f3512d7c7bc426f24a0cac1fcc9556802ac248f10c1fbdde51cd1e24afaf2
 EBUILD guile-1.8.8-r101.ebuild 4102 BLAKE2B 31e19061dd08c4a9b88ee17068ba84991f1ccbcd8635d81110a7e27c44ba1a4cfb57956d43624d70203c4909214bec41c72a263325d9c225d74d3d27a2c45e4a SHA512 d7a6826f37e3c486369b74fa063e5da2428ce1e5a2e14f9ceb1bc7de0d3be70b5867fbbb8ed283efcaf0fcf08fed32876907c88027c68790a1708878d1d3e104
+EBUILD guile-1.8.8-r102.ebuild 4655 BLAKE2B 17d13e89124f1e62c5dad3efec376587eb2ce898bf3e2fd981d8a9a0e8a9500a95df2bd452dcf3cc680972c190b4cece033d23048257ce8fe069072933c8aa41 SHA512 b2e378dcb097d60d21550ed28e8b9c03719582a03e6eeb9d12f4ca257416e040872b55ffca5b77a9a88b409949f465363bec4a87cc4a877b059778034886e880
 EBUILD guile-1.8.8-r5.ebuild 3207 BLAKE2B b695c0c7ce46a476750c5dbbfc5d49a270e297e134861f752f80c0b23b1ef5ec914078364ace4e2a3c4e22eb50c8b6bf13c795390a55e6018111f0bcf99768dd SHA512 1ea32491976d1da2212b66022e3c72d1d1fce6e106a22563e27b1482b22d9ae899351be86c808715f5fb1f8133292541f9866c51cc6a76510b53b6da4fadf690
 EBUILD guile-2.2.7-r1.ebuild 2147 BLAKE2B f745559bbd9cc6ea8f489f974351159792478de2fe001533f950098625e67620d750eaff498bb14f56f8854586b030be0936d61a65c94c00de90e5f3c145db33 SHA512 391cc24ba1c3855b7a4bea2bed6820a66e644b2613e0c49587a19fc759fe801b4863f90110f2a244d10945bdb151d86e8e43685282e9bac85db3f1d2fc36e1a4
 EBUILD guile-2.2.7-r100.ebuild 2566 BLAKE2B 158823448117723e28e96a2facd622dac06b6855efc8660e5d49ad194440955050185a6ddc9e15f51def6a497f78227920baf9be3b1795b822ac190f3e417562 SHA512 76fd991bbbe91da19347049a2b8301bfcabc8bb6e56208acbb75eb65ce19b26fda597cd3646ff09199ed5aa0e8fc917717b40ec0e9c75c4e5047b7461c307607
+EBUILD guile-2.2.7-r101.ebuild 3157 BLAKE2B a7d8c1fa57239d5b9d259f49cf286d01fe88d099181e7f5b5a812d1cf4625e39895f81e5c631b7599bb59659418f722727a90c9906b279094df10119f122faf1 SHA512 fa44a6d979053d59c0961452c5c184540da4a33452ce5a5f0c5df490e0b60aa8b79c823bb20ccd55e16ca380a55cb150f63b389857efd1d33132cb1ac9ba1167
 EBUILD guile-2.2.7-r2.ebuild 2300 BLAKE2B 5b8582730cab705ed219468469550ac73657008f6980752d5813955dbffb0955fbc74ad69da106b1e5d052cc553e3bce4a51a6c21bb9e65616b3b1ad895c54db SHA512 4109d875e65aa81601632f19b76e5bd83a6a34381cc28bb72a2217f3b47a1e81a752e4547ecbea0e4644b1323266067dae9703e0fde59b0a89fcb0133eeecfe2
 EBUILD guile-3.0.10-r100.ebuild 2481 BLAKE2B 4991446f833ef45ee944638af26500b5eb317c0e438c3e143590a7000906647da580e9ef91787d866c0476efece8e5e298e4ac47d0a08c3161c9c437aa8367a7 SHA512 fec6a49cbf2f22f8c80fe1e353114148ae2701bf98505d6266080125a678feb87b6884367ff467aca7103bfdda7db99f34948861d29fe31888676b0075954004
+EBUILD guile-3.0.10-r101.ebuild 3006 BLAKE2B fbfe8bb49fcd81933f6a610d014c838dcf186407afadb244a2046353bceac19021963db5d2658e73c5cefff5a6a6e1433fa388569d5781f9c4a5a41be13a86a7 SHA512 35a3d059f3a231e53fde545333bee56fb22d7ac261f2ca9f483e1dcd416ed6f95bac04beafca9a1cc2df01205b24c3f7e05554745fc2c23a247a3b62f0eea45b
 EBUILD guile-3.0.10.ebuild 2153 BLAKE2B 03c876db0a07d574bb0576129c366db97bff78eb3bd98e94d4e889c347109f61680eac1a4627847ba7954cae4acd5be96755a272b8f6463d6ad3f35477d8eeb6 SHA512 2dc8ca60d39c8839b4ebc5a7af7a92fe17423e8b2897415adc5089afc6646c5240f5cae2626907bb9ef8eae8c407c825560c429142c288db83f1ad45a24e5e8c
 EBUILD guile-3.0.9.ebuild 2151 BLAKE2B a2d3a1626657a2824201837ab46f86e280cb719bd5a14fc7afb2f1c8a09ed10d7d3039973d9d1788c1475cdd64bfd1ebef8fa55d1461ba9ac249033f789082c7 SHA512 5d41585f1dcc2560aa9af56b2023acbc232f6c3d8e757a6dcc44c4821c1e8bf20b72ad65975543a79271184e9c86d8331e9770963ff293208f7a63fcd3951392
 MISC metadata.xml 1423 BLAKE2B 1e1d2bc292338c5cab820a087f22fd4bd9517b85a6a1d52175cc666f329a2ce1f9cfcea6da01a02328395e15b0dbcb91e755fa8dde6709d1bbc47a0b34bb1e22 SHA512 013db66fb8ed106d739faad36c5b2014917526791839ea1e9bb9d4f588de666eb9a662dd5550be7f781a3346314d885742586ce9382d6745b3f7a9c1e9c37cc7
diff --git a/dev-scheme/guile/guile-1.8.8-r102.ebuild b/dev-scheme/guile/guile-1.8.8-r102.ebuild
new file mode 100644
index 000000000000..79fc61a11397
--- /dev/null
+++ b/dev-scheme/guile/guile-1.8.8-r102.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic elisp-common
+
+DESCRIPTION="GNU Ubiquitous Intelligent Language for Extensions"
+HOMEPAGE="https://www.gnu.org/software/guile/"
+SRC_URI="mirror://gnu/guile/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="debug debug-freelist debug-malloc +deprecated discouraged emacs networking nls readline +regex +threads"
+RESTRICT="!regex? ( test )"
+
+RDEPEND="
+	>=dev-libs/gmp-4.1:0=
+	dev-libs/libltdl:0=
+	sys-devel/gettext
+	sys-libs/ncurses:0=
+	virtual/libcrypt:=
+	readline? ( sys-libs/readline:0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-apps/texinfo
+	dev-build/libtool
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fix_guile-config.patch
+	"${FILESDIR}"/${P}-gcc46.patch
+	"${FILESDIR}"/${P}-gcc5.patch
+	"${FILESDIR}"/${P}-makeinfo-5.patch
+	"${FILESDIR}"/${P}-gtexinfo-5.patch
+	"${FILESDIR}"/${P}-readline.patch
+	"${FILESDIR}"/${P}-tinfo.patch
+	"${FILESDIR}"/${P}-sandbox.patch
+	"${FILESDIR}"/${P}-mkdir-mask.patch
+	"${FILESDIR}"/${PN}-1.8.8-texinfo-6.7.patch
+)
+
+DOCS=( AUTHORS ChangeLog GUILE-VERSION HACKING NEWS README THANKS )
+
+# Where to install data files.
+GUILE_DATA="${EPREFIX}/usr/share/guile-data/${SLOT}"
+GUILE_PCDIR="${EPREFIX}/usr/share/guile-data/${SLOT}/pkgconfig"
+GUILE_INFODIR="${EPREFIX}"/usr/share/guile-data/"${SLOT}"/info
+
+src_prepare() {
+	default
+
+	sed \
+		-e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g" \
+		-e "/AM_PROG_CC_STDC/d" \
+		-i guile-readline/configure.in || die
+
+	mv "${S}"/configure.{in,ac} || die
+	mv "${S}"/guile-readline/configure.{in,ac} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# See bug #178499.  filter-flags no longer works since the compiler
+	# will vectorize by default when optimizing.
+	append-flags -fno-tree-vectorize -fno-strict-aliasing
+
+	#will fail for me if posix is disabled or without modules -- hkBst
+	myconf=(
+		--program-suffix="-${SLOT}"
+		--infodir="${GUILE_INFODIR}"
+		--includedir="${EPREFIX}/usr/include/guile/${SLOT}"
+
+		--disable-error-on-warning
+		--disable-static
+		--enable-posix
+		$(use_enable networking)
+		$(use_enable readline)
+		$(use_enable regex)
+		$(use deprecated || use_enable discouraged)
+		$(use_enable deprecated)
+		$(use_enable emacs elisp)
+		$(use_enable nls)
+		--disable-rpath
+		$(use_enable debug-freelist)
+		$(use_enable debug-malloc)
+		$(use_enable debug guile-debug)
+		$(use_with threads)
+		--with-modules
+	)
+	econf "${myconf[@]}" EMACS=no
+}
+
+src_compile() {
+	emake
+
+	# Above we have disabled the build system's Emacs support;
+	# for USE=emacs we compile (and install) the files manually
+	if use emacs; then
+		cd emacs || die
+		elisp-compile *.el || die
+	fi
+}
+
+# Akin to (and taken from) toolchain-autoconfs eclass
+guile_slot_info() {
+	rm -f dir || die
+
+	pushd "${D}/${GUILE_INFODIR}" >/dev/null || die
+	for f in *.info*; do
+		# Install convenience aliases for versioned Guile pages.
+		ln -s "$f" "${f/./-${SLOT}.}" || die
+	done
+	popd >/dev/null || die
+
+	docompress "${GUILE_INFODIR}"
+}
+
+src_install() {
+	default
+
+	dodir "${GUILE_PCDIR}"
+	sed -e "/libdir/i bindir=${ESYSROOT}/usr/bin" \
+		-e "/libguileinterface/a guile=\${bindir}/guile-${SLOT}" \
+		-i "${ED}"/usr/$(get_libdir)/pkgconfig/guile-1.8.pc || die
+	mv "${ED}"/usr/$(get_libdir)/pkgconfig/guile-1.8.pc "${D}/${GUILE_PCDIR}"/guile-1.8.pc || die
+
+	sed -i "1s/guile/guile-1.8/" "${ED}"/usr/bin/guile-config-1.8 || die
+
+	for script in PROGRAM autofrisk doc-snarf generate-autoload punify \
+				  read-scheme-source scan-api snarf-guile-m4-docs use2dot \
+				  api-diff  display-commentary frisk lint read-rfc822 \
+				  read-text-outline snarf-check-and-output-texi summarize-guile-TODO; do
+		sed "s/GUILE-guile/GUILE-guile-1.8/" \
+			-i "${ED}"/usr/share/guile/1.8/scripts/${script}-1.8 || die
+		mv "${ED}"/usr/share/guile/1.8/scripts/${script}{-1.8,} || die
+	done
+
+	mv "${ED}"/usr/share/aclocal/guile{,-"${SLOT}"}.m4 || die
+	find "${ED}" -name '*.la' -delete || die
+
+	guile_slot_info
+
+	local major="$(ver_cut 1 "${SLOT}")"
+	local minor="$(ver_cut 2 "${SLOT}")"
+	local idx="$((99999-(major*1000+minor)))"
+	newenvd - "50guile${idx}" <<-EOF
+	PKG_CONFIG_PATH="${GUILE_PCDIR}"
+	INFOPATH="${GUILE_INFODIR}"
+	EOF
+
+	# necessary for registering slib, see bug 206896
+	keepdir /usr/share/guile/site
+
+	if use emacs; then
+		elisp-install ${PN}-${SLOT} emacs/*.{el,elc}
+		elisp-make-site-file "50${PN}-${SLOT}-gentoo.el"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/dev-scheme/guile/guile-2.2.7-r101.ebuild b/dev-scheme/guile/guile-2.2.7-r101.ebuild
new file mode 100644
index 000000000000..5943491ede3e
--- /dev/null
+++ b/dev-scheme/guile/guile-2.2.7-r101.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="GNU Ubiquitous Intelligent Language for Extensions"
+HOMEPAGE="https://www.gnu.org/software/guile/"
+SRC_URI="mirror://gnu/guile/${P}.tar.xz"
+
+LICENSE="LGPL-3+"
+SLOT="$(ver_cut 1-2)"  # See (guile)Parallel Installations.
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="debug debug-malloc +deprecated +networking +nls +regex +threads" # upstream recommended +networking +nls
+REQUIRED_USE="regex" # workaround for bug 596322
+RESTRICT="strip"
+
+RDEPEND="
+	>=dev-libs/boehm-gc-7.0:=[threads?]
+	dev-libs/gmp:=
+	dev-libs/libffi:=
+	dev-libs/libltdl:=
+	dev-libs/libunistring:0=
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	virtual/libcrypt:=
+	!dev-scheme/guile:12
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-build/libtool
+	sys-devel/gettext
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.2.3-gentoo-sandbox.patch"
+	"${FILESDIR}/${PN}-2.2.7-stack-up.patch"
+)
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+GUILE_INFODIR="${EPREFIX}"/usr/share/guile-data/"${SLOT}"/info
+
+DOCS=( GUILE-VERSION HACKING README )
+
+src_configure() {
+	# see bug #676468
+	mv prebuilt/32-bit-big-endian{,.broken} || die
+
+	econf \
+		--infodir="${GUILE_INFODIR}" \
+		--program-suffix="-${SLOT}" \
+		--disable-error-on-warning \
+		--disable-rpath \
+		--disable-static \
+		--enable-posix \
+		--without-libgmp-prefix \
+		--without-libiconv-prefix \
+		--without-libintl-prefix \
+		--without-libltdl-prefix \
+		--without-libreadline-prefix \
+		--without-libunistring-prefix \
+		$(use_enable debug guile-debug) \
+		$(use_enable debug-malloc) \
+		$(use_enable deprecated) \
+		$(use_enable networking) \
+		$(use_enable nls) \
+		$(use_enable regex) \
+		$(use_with threads)
+}
+
+# Akin to (and taken from) toolchain-autoconfs eclass
+guile_slot_info() {
+	rm -f dir || die
+
+	pushd "${D}/${GUILE_INFODIR}" >/dev/null || die
+	for f in *.info*; do
+		# Install convenience aliases for versioned Guile pages.
+		ln -s "$f" "${f/./-${SLOT}.}" || die
+	done
+	popd >/dev/null || die
+
+	docompress "${GUILE_INFODIR}"
+}
+
+src_install() {
+	default
+
+	# From Novell
+	# https://bugzilla.novell.com/show_bug.cgi?id=874028#c0
+	dodir /usr/share/gdb/auto-load/$(get_libdir)
+	mv "${ED}"/usr/$(get_libdir)/libguile-*-gdb.scm "${ED}"/usr/share/gdb/auto-load/$(get_libdir) || die
+
+	find "${D}" -name '*.la' -delete || die
+
+	# Move the pkg-config files to guile-data.  In future versions, this
+	# should be handled by --with-pkgconfigdir (patch waiting on
+	# upstream).
+	local pcdir=/usr/share/guile-data/"${SLOT}"
+	mkdir -p "${ED}${pcdir}" || die
+	mv "${ED}"/usr/share/aclocal/guile{,-"${SLOT}"}.m4 || die
+	mv "${ED}"/usr/$(get_libdir)/pkgconfig/ \
+	   "${ED}/${pcdir}" || die
+
+	guile_slot_info
+
+	local major="$(ver_cut 1 "${SLOT}")"
+	local minor="$(ver_cut 2 "${SLOT}")"
+	local idx="$((99999-(major*1000+minor)))"
+	newenvd - "50guile${idx}" <<-EOF
+	PKG_CONFIG_PATH="${datadir}/pkgconfig"
+	INFOPATH="${GUILE_INFODIR}"
+	EOF
+}
diff --git a/dev-scheme/guile/guile-3.0.10-r101.ebuild b/dev-scheme/guile/guile-3.0.10-r101.ebuild
new file mode 100644
index 000000000000..3f491dcc2e19
--- /dev/null
+++ b/dev-scheme/guile/guile-3.0.10-r101.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="GNU Ubiquitous Intelligent Language for Extensions"
+HOMEPAGE="https://www.gnu.org/software/guile/"
+SRC_URI="mirror://gnu/guile/${P}.tar.xz"
+
+LICENSE="LGPL-3+"
+SLOT="$(ver_cut 1-2)"  # See (guile)Parallel Installations.
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos"
+
+IUSE="debug debug-malloc +deprecated +jit +networking +nls +regex +threads" # upstream recommended +networking +nls
+REQUIRED_USE="regex" # workaround for bug #596322
+RESTRICT="strip"
+
+RDEPEND="
+	>=dev-libs/boehm-gc-7.0[threads?]
+	dev-libs/gmp:=
+	dev-libs/libffi:=
+	dev-libs/libatomic_ops
+	dev-libs/libunistring:=
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+	virtual/libcrypt:=
+	!dev-scheme/guile:12
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-build/libtool
+	sys-devel/gettext
+"
+
+# guile generates ELF files without use of C or machine code
+# It's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+DOCS=( ABOUT-NLS AUTHORS ChangeLog GUILE-VERSION HACKING NEWS README THANKS )
+
+PATCHES=( "${FILESDIR}"/${PN}-2.2.3-gentoo-sandbox.patch )
+
+# Where to install data files.
+GUILE_DATA="${EPREFIX}/usr/share/guile-data/${SLOT}"
+GUILE_PCDIR="${EPREFIX}/usr/share/guile-data/${SLOT}/pkgconfig"
+GUILE_INFODIR="${GUILE_DATA}"/info
+
+src_configure() {
+	# see bug #676468
+	mv prebuilt/32-bit-big-endian{,.broken} || die
+
+	local -a myconf=(
+		--program-suffix="-${SLOT}"
+		--infodir="${GUILE_INFODIR}"
+		--with-pkgconfigdir="${GUILE_PCDIR}"
+
+		--disable-error-on-warning
+		--disable-rpath
+		--disable-lto
+		--enable-posix
+		--without-libgmp-prefix
+		--without-libiconv-prefix
+		--without-libintl-prefix
+		--without-libreadline-prefix
+		--without-libunistring-prefix
+		$(use_enable debug guile-debug)
+		$(use_enable debug-malloc)
+		$(use_enable deprecated)
+		$(use_enable jit)
+		$(use_enable networking)
+		$(use_enable nls)
+		$(use_enable regex)
+		$(use_with threads)
+	)
+	econf "${myconf[@]}"
+}
+
+# Akin to (and taken from) toolchain-autoconfs eclass
+guile_slot_info() {
+	rm -f dir || die
+
+	pushd "${D}/${GUILE_INFODIR}" >/dev/null || die
+	for f in *.info*; do
+		# Install convenience aliases for versioned Guile pages.
+		ln -s "$f" "${f/./-${SLOT}.}" || die
+	done
+	popd >/dev/null || die
+
+	docompress "${GUILE_INFODIR}"
+}
+
+src_install() {
+	default
+
+	# From Novell https://bugzilla.novell.com/show_bug.cgi?id=874028#c0
+	dodir /usr/share/gdb/auto-load/$(get_libdir)
+	mv "${ED}"/usr/$(get_libdir)/libguile-*-gdb.scm "${ED}"/usr/share/gdb/auto-load/$(get_libdir) || die
+
+	mv "${ED}"/usr/share/aclocal/guile{,-"${SLOT}"}.m4 || die
+	find "${ED}" -name '*.la' -delete || die
+
+	guile_slot_info
+
+	local major="$(ver_cut 1 "${SLOT}")"
+	local minor="$(ver_cut 2 "${SLOT}")"
+	local idx="$((99999-(major*1000+minor)))"
+	newenvd - "50guile${idx}" <<-EOF
+	PKG_CONFIG_PATH="${GUILE_PCDIR}"
+	INFOPATH="${GUILE_INFODIR}"
+	EOF
+}