gentoo auto-resync : 28:02:2024 - 23:41:01

3 files changed, 59 insertions, 58 deletions

diff --git a/dev-scheme/guile-zstd/Manifest b/dev-scheme/guile-zstd/Manifest
index a4c93b1f2ff1..44154c5fc2d5 100644
--- a/dev-scheme/guile-zstd/Manifest
+++ b/dev-scheme/guile-zstd/Manifest
@@ -1,3 +1,3 @@
 DIST guile-zstd-0.1.1.tar.gz 21402 BLAKE2B 995034f977649b31308690a5a53372cb80274b6457b6b0344bc31f4451d00e61cc33b6ef890e8b7a75cb6a656e8db506a2390bc2c5d29552af7c68788a6388ee SHA512 23bd4b201a427eb02ae32bcd81d05adefcac3b4446dcb8a91d8ad2bed389d4ea92ffd81dfb6b3e7427b891fd25b7466ca53a97b1a943e390f13de977986fcad0
-EBUILD guile-zstd-0.1.1-r1.ebuild 1611 BLAKE2B e6e27493fc6385725e00ca1760740108a326343fec3de01bb8bbbe197a56bfd6a02b5a138c66ee557dce5b6e4ee1c7a221271ecc9f66b4328a5cf8a78f1dd7cb SHA512 dd4ceff67e1bdc71c7b3153f0400552e3fd21def0deefbb2929d2c6ca6fb7cc4b996737e4a856e19e8f2b0c5d62fdb6cd1d990a211bdb6d21ced2bfc3df5ae04
+EBUILD guile-zstd-0.1.1-r3.ebuild 1200 BLAKE2B ab4e1dd1d686ba8bbd7d268d0b39243ff81347860965bd0fad9221656116bb74817205f2b8e90243e1ff7a8f46c4c33744c3ab5c4fa1a7c31e2b55dbf8a4d6fd SHA512 691bb2aed5c243ad1b734e7f3decf34398c8758a7aef7db3f10482b85e718401e21b77dcdf98ae76c28e4865707f973bfb770d52f498d5095af92d65e4641822
 MISC metadata.xml 356 BLAKE2B 3976b42db1d89d5cb88ef463628a6636f15075b069d3189ee4f5132fec86f2dbc137d0f213dcc0acb2300f213338b9e1922da72d24b3c96c73278d8883c57e8d SHA512 5874174dd23fd3039132fca418e6f5bd6910884f93c7364afe8bf930559e60cc881761b48710f475366c65b76e1d254e2cb1389fda037e907a58deb222dfac0a
diff --git a/dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild b/dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild
deleted file mode 100644
index 7d00f87e4450..000000000000
--- a/dev-scheme/guile-zstd/guile-zstd-0.1.1-r1.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="GNU Guile bindings to the zstd compression library"
-HOMEPAGE="https://notabug.org/guile-zstd/guile-zstd/"
-SRC_URI="https://notabug.org/${PN}/${PN}/archive/v${PV}.tar.gz
-	-> ${P}.tar.gz"
-S="${WORKDIR}"/${PN}
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-# In zstd-1.5.2-r2 library was moved from /usr/lib to /lib
-RDEPEND="
-	>=dev-scheme/guile-2.0.0:=
-	>=app-arch/zstd-1.5.2-r2
-"
-DEPEND="${RDEPEND}"
-
-DOCS=( AUTHORS ChangeLog NEWS README )
-
-# guile generates ELF files without use of C or machine code
-# It's a portage's false positive. bug #677600
-QA_PREBUILT='*[.]go'
-
-src_prepare() {
-	default
-
-	# Workaround gentoo-specific deviation where
-	# /usr/lib64/libzstd.so is a linker script that points to:
-	#   GROUP ( /lib64/libzstd.so.1 )
-	# This confuses guile-zstd and fails to open the library:
-	#   substitute: ice-9/boot-9.scm:1685:16: In procedure raise-exception:
-	#   substitute: In procedure load-foreign-library: file: "/usr/lib64/libzstd.so.1",
-	#     message: "file not found"
-	#   guix environment: error: `/usr/bin/guix substitute' died unexpectedly
-	sed "s|@ZSTD_LIBDIR@/libzstd.so.1|/$(get_libdir)/libzstd.so.1|" \
-		-i "${S}"/zstd/config.scm.in || die
-
-	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
-	find "${S}" -name "*.scm" -exec touch {} + || die
-
-	eautoreconf
-}
-
-src_install() {
-	default
-
-	# Workaround llvm-strip problem of mangling guile ELF debug
-	# sections: https://bugs.gentoo.org/905898
-	dostrip -x "/usr/$(get_libdir)/guile"
-}
diff --git a/dev-scheme/guile-zstd/guile-zstd-0.1.1-r3.ebuild b/dev-scheme/guile-zstd/guile-zstd-0.1.1-r3.ebuild
new file mode 100644
index 000000000000..72aca48dc92f
--- /dev/null
+++ b/dev-scheme/guile-zstd/guile-zstd-0.1.1-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="GNU Guile bindings to the zstd compression library"
+HOMEPAGE="https://notabug.org/guile-zstd/guile-zstd/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://notabug.org/${PN}/${PN}.git"
+else
+	SRC_URI="https://notabug.org/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+# In zstd-1.5.5-r1 library was moved back from "/lib" to "/usr/lib".
+RDEPEND="
+	>=app-arch/zstd-1.5.5-r1
+	>=dev-scheme/guile-2.0.0:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_install() {
+	default
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}