gentoo resync : 22.06.2019

8 files changed, 291 insertions, 0 deletions

diff --git a/dev-ruby/equatable/equatable-0.6.0.ebuild b/dev-ruby/equatable/equatable-0.6.0.ebuild
new file mode 100644
index 000000000000..b5520ce3dab7
--- /dev/null
+++ b/dev-ruby/equatable/equatable-0.6.0.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Allows ruby objects to implement equality comparison and inspection methods"
+HOMEPAGE="https://github.com/piotrmurach/equatable"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+all_ruby_prepare() {
+	echo "-rspec_helper" > .rspec || die
+}
diff --git a/dev-ruby/mocha/mocha-1.9.0.ebuild b/dev-ruby/mocha/mocha-1.9.0.ebuild
new file mode 100644
index 000000000000..8faa3063b986
--- /dev/null
+++ b/dev-ruby/mocha/mocha-1.9.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_TASK_TEST="test:units test:acceptance"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="README.md RELEASE.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="init.rb"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Mocking and stubbing using a syntax like that of JMock and SchMock"
+HOMEPAGE="https://mocha.jamesmead.org/"
+
+LICENSE="MIT"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+ruby_add_bdepend "
+	test? ( >=dev-ruby/test-unit-2.5.1-r1 dev-ruby/introspection )"
+
+ruby_add_rdepend "=dev-ruby/metaclass-0.0*"
+
+all_ruby_prepare() {
+	sed -i -e '/[Bb]undler/ s:^:#:' -e '1iload "lib/mocha/version.rb"' Rakefile || die
+}
+
+each_ruby_test() {
+	export MOCHA_NO_DOCS=true
+	each_fakegem_test
+}
diff --git a/dev-ruby/msgpack/msgpack-1.3.0.ebuild b/dev-ruby/msgpack/msgpack-1.3.0.ebuild
new file mode 100644
index 000000000000..822d7d1185dd
--- /dev/null
+++ b/dev-ruby/msgpack/msgpack-1.3.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Binary-based efficient data interchange format for ruby binding"
+HOMEPAGE="https://msgpack.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~x86-fbsd"
+IUSE="doc"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+
+	# Remove jruby-specific specs that are run also for other rubies.
+	rm -rf spec/jruby || die
+
+	sed -i -e '/git ls-files/d' msgpack.gemspec || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die "Configuration of extension failed."
+
+	# rb_num2int is not inlined on 32 bit arches but also not explicitly
+	# defined, bug 582968
+	sed -i -e 's:-Wl,--no-undefined::' ext/${PN}/Makefile || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/msgpack$(get_modname) lib/${PN} || die "Unable to install msgpack library."
+}
diff --git a/dev-ruby/pastel/pastel-0.7.3.ebuild b/dev-ruby/pastel/pastel-0.7.3.ebuild
new file mode 100644
index 000000000000..e76bba5ba9fa
--- /dev/null
+++ b/dev-ruby/pastel/pastel-0.7.3.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Terminal strings styling with intuitive and clean API"
+HOMEPAGE="https://github.com/piotrmurach/pastel"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/equatable-0.6:0
+	>=dev-ruby/tty-color-0.5:0
+"
+
+all_ruby_prepare() {
+	echo '-rspec_helper' > .rspec || die
+}
diff --git a/dev-ruby/rmagick/rmagick-3.2.0.ebuild b/dev-ruby/rmagick/rmagick-3.2.0.ebuild
new file mode 100644
index 000000000000..f496880e396f
--- /dev/null
+++ b/dev-ruby/rmagick/rmagick-3.2.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.textile"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="An interface between Ruby and the ImageMagick(TM) image processing library"
+HOMEPAGE="https://github.com/gemhome/rmagick"
+
+LICENSE="Artistic"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-macos"
+IUSE="doc"
+
+RDEPEND+=" >=media-gfx/imagemagick-6.9.0:= =media-gfx/imagemagick-6*"
+DEPEND+=" >=media-gfx/imagemagick-6.9.0:=[jpeg] =media-gfx/imagemagick-6*"
+
+ruby_add_bdepend "test? ( dev-ruby/rspec:3 )"
+
+all_ruby_prepare() {
+	# Avoid unused dependency on rake-compiler. This also avoids an
+	# extra compile during tests.
+	sed -i -e '/extensiontask/ s:^:#:' \
+		-e '/ExtensionTask/,/end/ s:^:#:' \
+		-e '/compile/ s:^:#:' Rakefile || die
+
+	# Avoid simplecov dependency
+	sed -i -e '/simplecov/ s:^:#:' Rakefile test/test_all_basic.rb || die
+
+	# Squelch harmless warning about imagemagick installation.
+	sed -i -e '/prefix/ s:ImageMagick:ImageMagick-6:' ext/RMagick/extconf.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/RMagick extconf.rb || die "extconf.rb failed"
+}
+
+each_ruby_compile() {
+	emake -Cext/RMagick V=1
+	cp ext/RMagick/RMagick2$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	${RUBY} -S rake test || die
+	RSPEC_VERSION=3 ruby-ng_rspec spec || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/*
+
+	if use doc ; then
+		docinto .
+		dodoc -r doc
+	fi
+}
diff --git a/dev-ruby/sassc-rails/sassc-rails-2.1.2.ebuild b/dev-ruby/sassc-rails/sassc-rails-2.1.2.ebuild
new file mode 100644
index 000000000000..ca9443f56d99
--- /dev/null
+++ b/dev-ruby/sassc-rails/sassc-rails-2.1.2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem eapi7-ver
+
+DESCRIPTION="Integrate SassC-Ruby with Rails"
+HOMEPAGE="https://github.com/sass/sassc-rails"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64"
+
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/sassc-2.0
+	dev-ruby/tilt:*
+	>=dev-ruby/railties-4:*
+	>=dev-ruby/sprockets-3.0:*
+	dev-ruby/sprockets-rails:*
+"
+
+ruby_add_bdepend "
+	test? ( dev-ruby/bundler dev-ruby/mocha )"
+
+all_ruby_prepare() {
+	sed -i -e '/rake/ s/,.*$//' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_test() {
+	${RUBY} -S bundle exec rake test || die
+}
diff --git a/dev-ruby/tty-platform/tty-platform-0.2.1.ebuild b/dev-ruby/tty-platform/tty-platform-0.2.1.ebuild
new file mode 100644
index 000000000000..e30b88aa6f9c
--- /dev/null
+++ b/dev-ruby/tty-platform/tty-platform-0.2.1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Query methods for detecting different operating systems"
+HOMEPAGE="https://github.com/piotrmurach/tty-platform"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+all_ruby_prepare() {
+	echo '-rspec_helper' > .rspec || die
+}
diff --git a/dev-ruby/tty-reader/tty-reader-0.6.0-r1.ebuild b/dev-ruby/tty-reader/tty-reader-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..3bcd1faf6603
--- /dev/null
+++ b/dev-ruby/tty-reader/tty-reader-0.6.0-r1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Methods for processing keyboard input in character, line and multiline modes"
+HOMEPAGE="https://github.com/piotrmurach/tty-reader"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/tty-cursor-0.7:0
+	>=dev-ruby/tty-screen-0.7:0
+	=dev-ruby/wisper-2.0*
+"
+
+all_ruby_prepare() {
+	echo '-rspec_helper' > .rspec || die
+}