gentoo auto-resync : 13:07:2022 - 13:36:46

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-ruby/actionview/actionview-5.2.8.1.ebuild b/dev-ruby/actionview/actionview-5.2.8.1.ebuild
new file mode 100644
index 000000000000..e1a811f6d6d9
--- /dev/null
+++ b/dev-ruby/actionview/actionview-5.2.8.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+RUBY_FAKEGEM_EXTRAINSTALL="app"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Simple, battle-tested conventions and helpers for building web pages"
+HOMEPAGE="https://github.com/rails/rails/"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	>=dev-ruby/builder-3.1:* =dev-ruby/builder-3*:*
+	>=dev-ruby/erubi-1.4:0
+	>=dev-ruby/rails-html-sanitizer-1.0.3:1
+	dev-ruby/rails-dom-testing:2
+"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/mocha
+		~dev-ruby/actionpack-${PV}
+		~dev-ruby/activemodel-${PV}
+		~dev-ruby/railties-${PV}
+	)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|'mysql'\|journey\|rack-cache\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|redcarpet\|bcrypt\|uglifier\|mime-types\|minitest\|sprockets\|stackprof\)/ s:^:#:" \
+		-e '/:job/,/end/ s:^:#:' \
+		-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
+	rm ../Gemfile.lock || die
+
+	# Avoid activerecord integration tests because they are very sensitive to the specifics
+	# of the environment.
+	sed -i -e 's/, "test:integration:active_record"//' Rakefile || die
+
+	sed -e '2igem "actionpack", "~> 5.2.0"' \
+		-e '2igem "activemodel", "~> 5.2.0"' \
+		-e '2igem "railties", "~> 5.2.0"' \
+		-e '/active_record/ s:^:#:' \
+		-i test/abstract_unit.rb || die
+}