gentoo auto-resync : 18:11:2022 - 00:57:34

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/zope-hookable/zope-hookable-5.4.ebuild b/dev-python/zope-hookable/zope-hookable-5.4.ebuild
new file mode 100644
index 000000000000..e6323fc9044f
--- /dev/null
+++ b/dev-python/zope-hookable/zope-hookable-5.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Efficient creation of 'hookable' objects"
+HOMEPAGE="
+	https://pypi.org/project/zope.hookable/
+	https://github.com/zopefoundation/zope.hookable/
+"
+SRC_URI="
+	https://github.com/zopefoundation/zope.hookable/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${P/-/.}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	eunittest -s "${BUILD_DIR}/install$(python_get_sitedir)/zope/hookable/tests"
+}