gentoo resync : 03.07.2021

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/zipp/zipp-3.5.0.ebuild b/dev-python/zipp/zipp-3.5.0.ebuild
new file mode 100644
index 000000000000..4ceef32cedf6
--- /dev/null
+++ b/dev-python/zipp/zipp-3.5.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
+HOMEPAGE="https://github.com/jaraco/zipp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.2[${PYTHON_USEDEP}]
+	test? ( dev-python/jaraco-itertools[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Skip a potentially flaky performance test
+	sed -i -e '/^import func_timeout\|^ *@func_timeout\.func_set_timeout/d' \
+		-e 's/test_implied_dirs_performance/_&/' test_zipp.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Ignoring zipp.py from ${S} avoids ImportPathMismatchError with Python < 3.8
+	# by ensuring only zipp from ${BUILD_DIR} is loaded
+	epytest --ignore zipp.py
+}