gentoo auto-resync : 27:12:2024 - 06:30:34

2 files changed, 101 insertions, 0 deletions

diff --git a/dev-python/urllib3/Manifest b/dev-python/urllib3/Manifest
index 9a91ee01b552..0c02754e0752 100644
--- a/dev-python/urllib3/Manifest
+++ b/dev-python/urllib3/Manifest
@@ -1,4 +1,6 @@
 DIST hypercorn-d1719f8c1570cbd8e6a3719ffdb14a4d72880abb.gh.tar.gz 156216 BLAKE2B fcb5f49653401e6e4079e1c770d3cd407602d4d6764437b735bd4ec04191dec59cdc930822fa2aff726ee25cddd0f71fd457dedf31026bff1da121d93af8b768 SHA512 62d6787d88a2e716f0ac04fc49f6cdc586e473a660ee754ff66961922ae78bcc75d1f78b091e78557dd60f006e8e480114738c7b4ff71beac804e4fc9603240b
 DIST urllib3-2.2.3.tar.gz 300677 BLAKE2B 7eb17ab324bf210fb52b1012bf9d37c1a7f3b742aafe7e49adf2dde1678089e94683feedaa2301dd510944da0a5afc331ded13d0631af3efe4dbd576d0dee0ec SHA512 f461cc959d675b8b13c2f40f4b021cab01ccb3a5033143f5c3eae3fce7486115994d198c78db9ef353fce47c17b25e0ecb010fbdebc1b8731d4fd708054b39cc
+DIST urllib3-2.3.0.tar.gz 307268 BLAKE2B 516c3b8b538682bf7b37324568757cf033df0d6a785f5fe0cdb3eaa81c68532958dd0801a007508523ca9674ec2b8ea3c9130c44b6742f6e05e9dc929ba41d01 SHA512 cf33a9082c304d8782fa054412686f9fac65fa860404243b72c75374f7459bf6c7668297b37b5fadc978f9a85b3e7653ddc7b2c415903f7eee5a70fe9ae281cb
 EBUILD urllib3-2.2.3.ebuild 2967 BLAKE2B 761d10299177e4a711e5732a9714dbe58896ed2f14dc3305b83f95a4adc019d48cbc79f582c7d3f1878b874705207b8d5e2560338988b665b725fcb440fdd8ba SHA512 7c031d490822d1c5b56eb9bfbbe50095bf2b02734ef1dc3a52e6b3cb1a89bff070c6439e152ad41534fca3e01bc842391b47b1b262f58a9e3d2b3f4fa91aacdc
+EBUILD urllib3-2.3.0.ebuild 3375 BLAKE2B 69a430ea7aba70fc37a878d56e57c74b23798b570587a7958ca7ae815ac7aec6cddd4d216d5cb702b2b63accf2c23a0f49fe9e0c9ebdb214d15898dfb25bc17c SHA512 5d00044eb718beb208f318f073babf720fb5c3ea45c64412bf63231ff04dcb207837d9632fe0f8592e2be952af5cd0979434ede9fe5f1b11d574d649bae6f991
 MISC metadata.xml 449 BLAKE2B 45df5a0e80d7b229058be52fd8feb3ba2efe8d981b5b34216e4b9cb35d332588c4b3efade8e8d06bdf1f13159dfcd937458e5cf4d0cea5e07b6c1011cc8592cb SHA512 312b41031a9cbf6341f537fef94137420ca49ab609e7d4c325a998e328be415b381aa50e7b5600483d1a7583b72675a044b5dd80cb84a52539ab23271f1b096c
diff --git a/dev-python/urllib3/urllib3-2.3.0.ebuild b/dev-python/urllib3/urllib3-2.3.0.ebuild
new file mode 100644
index 000000000000..491feb6fc739
--- /dev/null
+++ b/dev-python/urllib3/urllib3-2.3.0.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1 pypi
+
+# The package has a test dependency on their own hypercorn fork.
+HYPERCORN_COMMIT=d1719f8c1570cbd8e6a3719ffdb14a4d72880abb
+DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
+HOMEPAGE="
+	https://github.com/urllib3/urllib3/
+	https://pypi.org/project/urllib3/
+"
+SRC_URI+="
+	test? (
+		https://github.com/urllib3/hypercorn/archive/${HYPERCORN_COMMIT}.tar.gz
+			-> hypercorn-${HYPERCORN_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="brotli http2 test zstd"
+RESTRICT="!test? ( test )"
+
+# [secure] extra is deprecated and slated for removal, we don't need it:
+# https://github.com/urllib3/urllib3/issues/2680
+RDEPEND="
+	>=dev-python/pysocks-1.5.8[${PYTHON_USEDEP}]
+	<dev-python/pysocks-2.0[${PYTHON_USEDEP}]
+	brotli? ( >=dev-python/brotlicffi-0.8.0[${PYTHON_USEDEP}] )
+	http2? (
+		<dev-python/h2-5[${PYTHON_USEDEP}]
+		>=dev-python/h2-4[${PYTHON_USEDEP}]
+	)
+	zstd? ( >=dev-python/zstandard-0.18.0[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep "
+			${RDEPEND}
+			dev-python/brotlicffi[\${PYTHON_USEDEP}]
+			dev-python/freezegun[\${PYTHON_USEDEP}]
+			dev-python/h2[\${PYTHON_USEDEP}]
+			dev-python/httpx[\${PYTHON_USEDEP}]
+			dev-python/pytest[\${PYTHON_USEDEP}]
+			dev-python/pytest-rerunfailures[\${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[\${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[\${PYTHON_USEDEP}]
+			dev-python/quart[\${PYTHON_USEDEP}]
+			dev-python/quart-trio[\${PYTHON_USEDEP}]
+			dev-python/trio[\${PYTHON_USEDEP}]
+			>=dev-python/tornado-4.2.1[\${PYTHON_USEDEP}]
+			>=dev-python/trustme-0.5.3[\${PYTHON_USEDEP}]
+			>=dev-python/zstandard-0.18.0[\${PYTHON_USEDEP}]
+		" "${PYTHON_TESTED[@]}")
+	)
+"
+
+src_prepare() {
+	# upstream considers 0.5 s to be "long" for a timeout
+	# we get tons of test failures on *fast* systems because of that
+	sed -i -e '/LONG_TIMEOUT/s:0.5:5:' test/__init__.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTHONPATH=${WORKDIR}/hypercorn-${HYPERCORN_COMMIT}/src
+	local -x CI=1
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# TODO: timeouts
+		test/contrib/test_pyopenssl.py::TestSocketClosing::test_timeout_errors_cause_retries
+		test/with_dummyserver/test_socketlevel.py::TestSocketClosing::test_timeout_errors_cause_retries
+		# TODO
+		test/contrib/test_pyopenssl.py::TestSocketClosing::test_socket_shutdown_stops_recv
+		test/with_dummyserver/test_socketlevel.py::TestSocketClosing::test_socket_shutdown_stops_recv
+		# hangs randomly
+		test/contrib/test_pyopenssl.py::TestHTTPS_TLSv1_{2,3}::test_http2_probe_blocked_per_thread
+		test/with_dummyserver/test_https.py::TestHTTPS_TLSv1_{2,3}::test_http2_probe_blocked_per_thread
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local EPYTEST_XDIST=1
+	epytest -p timeout -p rerunfailures --reruns=10 --reruns-delay=2
+}