gentoo resync : 14.07.2018

5 files changed, 157 insertions, 0 deletions

diff --git a/dev-python/txAMQP/Manifest b/dev-python/txAMQP/Manifest
new file mode 100644
index 000000000000..0ad2cbe2125e
--- /dev/null
+++ b/dev-python/txAMQP/Manifest
@@ -0,0 +1,7 @@
+DIST txAMQP-0.6.2.tar.gz 20749 BLAKE2B 697271755e2f736424cbbaecd6a009b875326c0da9fe4c06f03da9c7b662ecd263c5ac4c770debc0c8c65098e2d01bf9ca74509972b5be56da8572a43260cd0a SHA512 676797a5ae4e013d3cbf42e94f2a3e0421c9db0056e2abaee7bfacbb2b31b50948b5ac51d389ba6f8c609207a294c35ee9359813f3151f37d049092bd1aed78a
+DIST txamqp-0.7.0.tar.gz 117964 BLAKE2B 0ad4c0e9606b6a333ee55f8717d8ead587e5980274d84f1c04652461fddca2f8202485c0f13cba8507ecd7049a1a414166d685326ef146f4d14d1734f0634065 SHA512 8af8dee44885fce6a8015fc3763ff1fd6a3effb8cc954b5ee2baed7c652a34440df4c6d8360b22930dc5b488e9965c3f8ad4ff8d49604ad80e31b6de70c233c5
+DIST txamqp-0.8.2.tar.gz 118560 BLAKE2B 6e60cc0785462b92d046a620cc09eda8b7783bd09186a60299eba11c8f6f5780fc38b094ea974e4f1e443d3d30ee1428f30ad25fdb43554d25db17f36d323527 SHA512 4a5e468482433e684dc690abddeba3e0a6c77630055afe44487de72feecad9c750d179c43dee4e781d09c9c21259cecd615dc9f6eaa7d9ff7ca0796248ad5a02
+EBUILD txAMQP-0.6.2.ebuild 515 BLAKE2B 9b305128a5cd4338a05a614015af3789f22a7a292f8e5da3cbf3a07f6882879e176c8f077bc35603a8eb806684cb1ef6074ef8defb74e512fe475ca4b445c270 SHA512 f1c5418b953c91d1f6ee56d51d9e07e2c013e54e5fb463e8d2b35cfdd06ae82bda5d4415273d5c11f53bae1b42b531e549097d922b20a5c5dc1a7fddc0f1036f
+EBUILD txAMQP-0.7.0.ebuild 1333 BLAKE2B c644f85fedc7edc8d3c643fb744cef4776694dffa44467223758163c6d9b2dd22bd196b15895deb52e0525c856349260d18d4a6bb3bf95a6e8e442c7714b54ce SHA512 d92469eb0a1415bc70f0d8eb3fd5116b2315bd2b0bfb392acb7e0a0f69278492157d9f6b56002a69d45f9a33ea68de78d9a2143e220402e9036669a0c678a8b0
+EBUILD txAMQP-0.8.2.ebuild 1437 BLAKE2B 3b91de97dba19924595515648f13ba59c7008330eb86d64070f9680d63c50d595e463992af94748827fb550969ebafe94d937f415a36da8770f9e825d5be85d9 SHA512 294a64d1b439b9132ccef7918d2a478f8b0f5bc4a311a327ffbdb46caf083577e5f2d8e0174268462ddc26cbb20318e7e8e56a90bd8222e8f303e99655307267
+MISC metadata.xml 423 BLAKE2B 507dec1a447659fd4b519d029b63840460fcf93e9c5cc1d97e7eb0ae1278488c7f4dfaeabe53510da3c07cd079ca9e083a39586ba8e0b99a4e54e44efc27d3e5 SHA512 e80129432dd18c5d4e08d25d560a7144b6589feffe3c0bb6dae249868932fbd8290426531140bd4b0d124b1b06d198527d1a225cf454454f195a20699482a09d
diff --git a/dev-python/txAMQP/metadata.xml b/dev-python/txAMQP/metadata.xml
new file mode 100644
index 000000000000..8a4e48b4fcf9
--- /dev/null
+++ b/dev-python/txAMQP/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">txAMQP</remote-id>
+		<remote-id type="github">txamqp/txamqp</remote-id>
+		<bugs-to>https://github.com/txamqp/txamqp/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/txAMQP/txAMQP-0.6.2.ebuild b/dev-python/txAMQP/txAMQP-0.6.2.ebuild
new file mode 100644
index 000000000000..8feb2695f495
--- /dev/null
+++ b/dev-python/txAMQP/txAMQP-0.6.2.ebuild
@@ -0,0 +1,18 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1
+
+DESCRIPTION="Python library for communicating with AMQP peers using Twisted"
+HOMEPAGE="https://github.com/txamqp/txamqp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+KEYWORDS="amd64 x86 ~x64-solaris"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/twisted-core[${PYTHON_USEDEP}]"
diff --git a/dev-python/txAMQP/txAMQP-0.7.0.ebuild b/dev-python/txAMQP/txAMQP-0.7.0.ebuild
new file mode 100644
index 000000000000..7220086d7f04
--- /dev/null
+++ b/dev-python/txAMQP/txAMQP-0.7.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1
+
+MY_P=${PN,,}-${PV}
+DESCRIPTION="Python library for communicating with AMQP peers using Twisted"
+HOMEPAGE="https://github.com/txamqp/txamqp"
+# pypi tarball misses necessary test files
+SRC_URI="https://github.com/txamqp/txamqp/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+KEYWORDS="~amd64 ~x86 ~x64-solaris"
+SLOT="0"
+IUSE="test"
+
+# TODO: split twisted-core gives minor test failure, get rid of it
+# when we port revdeps
+RDEPEND="
+	|| (
+		dev-python/twisted[${PYTHON_USEDEP}]
+		dev-python/twisted-core[${PYTHON_USEDEP}]
+	)"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		net-misc/rabbitmq-server
+	)"
+
+S=${WORKDIR}/${MY_P}
+
+# Tests connect to the system rabbitmq server
+# TODO: figure out how to start an isolated instance
+RESTRICT="test"
+
+python_test() {
+	cd src || die
+	# tests look for those files relatively to modules
+	cp -r specs "${BUILD_DIR}"/lib || die
+
+	TXAMQP_BROKER=RABBITMQ trial txamqp
+	local ret=${?}
+
+	# avoid installing spec files
+	rm -r "${BUILD_DIR}"/lib/specs || die
+
+	[[ ${ret} == 0 ]] || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( doc/* )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/txAMQP/txAMQP-0.8.2.ebuild b/dev-python/txAMQP/txAMQP-0.8.2.ebuild
new file mode 100644
index 000000000000..2c1e1f260f11
--- /dev/null
+++ b/dev-python/txAMQP/txAMQP-0.8.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+MY_P=${PN,,}-${PV}
+DESCRIPTION="Python library for communicating with AMQP peers using Twisted"
+HOMEPAGE="https://github.com/txamqp/txamqp"
+# pypi tarball misses doc files
+# https://github.com/txamqp/txamqp/pull/10
+SRC_URI="https://github.com/txamqp/txamqp/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+KEYWORDS="~amd64 ~x86 ~x64-solaris"
+SLOT="0"
+IUSE="test"
+
+# TODO: split twisted-core gives minor test failure, get rid of it
+# when we port revdeps
+RDEPEND="
+	|| (
+		dev-python/twisted[${PYTHON_USEDEP}]
+		dev-python/twisted-core[${PYTHON_USEDEP}]
+	)
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		net-misc/rabbitmq-server
+	)"
+
+S=${WORKDIR}/${MY_P}
+
+# Tests connect to the system rabbitmq server
+# TODO: figure out how to start an isolated instance
+RESTRICT="test"
+
+python_test() {
+	cd src || die
+	# tests look for those files relatively to modules
+	cp -r specs "${BUILD_DIR}"/lib || die
+
+	TXAMQP_BROKER=RABBITMQ trial txamqp
+	local ret=${?}
+
+	# avoid installing spec files
+	rm -r "${BUILD_DIR}"/lib/specs || die
+
+	[[ ${ret} == 0 ]] || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( doc/* )
+
+	distutils-r1_python_install_all
+}